使用特定链接器进行CMake交叉编译不会将参数传递给armlink

Posted 2021-04-19

我正在尝试交叉编译嵌入式ARM Cortex构建的项目，但我无法使链接器正常工作。我想使用armlink，但没有文件传递给armlink，因此没有生成.elf文件。

我的CMakeLists.txt非常简单，如下所示。之后显示失败，表明makefile在没有任何参数的情况下调用了armlink。

任何指针都会有所帮助 - 我搜索并阅读了很多帖子，但他们似乎都有更多的参与要求。

cmake_minimum_required(VERSION 2.8)

project(test_arm)
enable_language(C ASM)

# Cross-compilation for ARM
SET(CMAKE_C_COMPILER armcc)
SET(CMAKE_LINKER armlink)
SET(CMAKE_C_LINK_EXECUTABLE armlink)

SET(CMAKE_C_FLAGS "--cpu=Cortex-M3")
SET(LINK_FLAGS "--map --ro-base=0x0 --rw-base=0x0008000 --first='boot.o(RESET)' --datacompressor=off")
SET(CMAKE_EXE_LINKER_FLAGS "--map --ro-base=0x0 --rw-base=0x0008000 --first='boot.o(RESET)' --datacompressor=off")

include_directories(../include)

add_executable(blinky blinky.c)
set_target_properties(blinky PROPERTIES LINKER_LANGUAGE C)

失败如下，但我想对于我的CMakeLists中有一些愚蠢问题的人来说很明显：

$ make VERBOSE=1
[100%] Building C object CMakeFiles/blinky.dir/blinky.c.o
/usr/bin/cmake -E cmake_link_script CMakeFiles/blinky.dir/link.txt --verbose=1
armlink
Linking C executable blinky
Product: DS-5 Professional 5.21.0 [5210017]
Component: ARM Compiler 5.05 update 1 (build 106)
Tool: armlink [4d0efa]
For support see http://www.arm.com/support/
Software supplied by: ARM Limited
Usage: armlink option-list input-file-list
where
....

我期待CMake生成的Makefile用以下内容调用armlink：

armlink --map --ro-base=0x0 --rw-base=0x0008000 
  --first='boot.o(RESET)' --datacompressor=off 
  CMakeFiles/blinky.dir/blinky.c.o -o blinky.elf

答案

从CMake v3.5开始，您不再需要Keil ARM C / C ++编译工具的工具链：

为编译器ID为ARMCC的ARM编译器（arm.com）添加了支持。

只需相应地设置C / CXX编译器变量即可

cmake -DCMAKE_C_COMPILER:PATH="C:Program Files (x86)DS-5inarmcc.exe"
      -DCMAKE_CXX_COMPILER:PATH="C:Program Files (x86)DS-5inarmcc.exe"
      ...

参考

• ARMCC toolchain support
• Add support for the ARM Compiler (arm.com)
• CMake Error at CMakeLists.txt:30 (project): No CMAKE_C_COMPILER could be found

另一答案

根据我的经验，您无法在CMakeLists.txt文件中设置CMAKE_EXE_LINKER_FLAGS。当第一次在构建目录中调用CMake时，必须通过CMAKE_TOOLCHAIN_FILE传递它。

我没有找到有关此问题的任何文档，但是如果您进行交叉编译，则应该使用cross-compilation with CMake页面。

首先，只需将set调用放入工具链文件中即可运行

cmake -DCMAKE_TOOLCHAIN_FILE=<yourfile.toolchain>

在一个干净的构建目录中。

另一答案

工具链文件可能是个好主意。这是我上次使用DS-5工具链尝试使用CMake 2.8.10时所出现的内容（它仍然可以进行优化，但它应该为您提供一个起点）：

INCLUDE(CMakeForceCompiler)

# This one is important
SET(CMAKE_SYSTEM_NAME Generic)
SET(CMAKE_SYSTEM_PROCESSOR arm)

# Specify the cross compiler
SET(CMAKE_C_COMPILER "C:/Program Files (x86)/DS-5/bin/armcc.exe")
SET(CMAKE_CXX_COMPILER "C:/Program Files (x86)/DS-5/bin/armcc.exe")
SET(CMAKE_AR "C:/Program Files (x86)/DS-5/bin/armar.exe" CACHE FILEPATH "Archiver")

#CMAKE_FORCE_C_COMPILER("C:/Program Files (x86)/DS-5/sw/gcc/bin/arm-linux-gnueabihf-gcc.exe" GNU)
#CMAKE_FORCE_CXX_COMPILER("C:/Program Files (x86)/DS-5/sw/gcc/bin/arm-linux-gnueabihf-g++.exe" GNU)

UNSET(CMAKE_C_FLAGS CACHE)
SET(CMAKE_C_FLAGS "--cpu=Cortex-A9 --thumb -Ospace" CACHE STRING "" FORCE)
UNSET(CMAKE_CXX_FLAGS CACHE)
SET(CMAKE_CXX_FLAGS ${CMAKE_C_FLAGS} CACHE STRING "" FORCE)
UNSET(CMAKE_EXE_LINKER_FLAGS CACHE)
SET(CMAKE_EXE_LINKER_FLAGS "" CACHE STRING "" FORCE)
UNSET(CMAKE_AR_FLAGS CACHE)
SET(CMAKE_AR_FLAGS "-p -armcc,-Ospace" CACHE STRING "" FORCE)

# set(CMAKE_C_ARCHIVE_CREATE "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
SET(CMAKE_C_ARCHIVE_CREATE "<CMAKE_AR> ${CMAKE_AR_FLAGS} -o <TARGET> <OBJECTS>" CACHE STRING "C Archive Create")
# set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
SET(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> ${CMAKE_AR_FLAGS} -o <TARGET> <OBJECTS>" CACHE STRING "CXX Archive Create")

include_directories("C:/Program Files (x86)/DS-5/include")
#include_directories("C:/Program Files (x86)/DS-5/sw/gcc/arm-linux-gnueabihf/libc/usr/include/arm-linux-gnueabi")

# Where is the target environment
SET(CMAKE_FIND_ROOT_PATH "C:/Program Files (x86)/DS-5")

# Search for programs in the build host directories
SET(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)

# For libraries and headers in the target directories
SET(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
SET(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

关于你的问题

Some failure analysis

你尝试过的应该是有效的（参见例如How do I add a linker or compile flag in a CMake file?）。但在配置步骤中似乎出现了问题。

我不知道你的命令行调用CMake的配置/生成步骤，所以一些一般提示找到根本原因：

你可以尝试打电话

cmake.exe --trace ...

看看你的CMAKE_EXE_LINKER_FLAGS变量出了什么问题。这将产生大量输出，因此以下是CMake所做的一些基础知识：

• project()命令将触发编译器评估
• 这会将CMAKE_EXE_LINKER_FLAGS写入您的CMakeCache.txt
• 你用局部变量覆盖它（参见变量范围docu here）

如果你看看sharecmake-2.8ModulesCMakeCommonLanguageInclude.cmake：

set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS_INIT} $ENV{LDFLAGS}"
     CACHE STRING "Flags used by the linker.")

您可以使用CMAKE_EXE_LINKER_FLAGS_INIT，但必须在project()命令之前或工具链文件中设置它。

因为您将链接语言设置为C，请查看sharecmake-2.8ModulesCMakeCInformation.cmake：

if(NOT CMAKE_C_LINK_EXECUTABLE)
  set(CMAKE_C_LINK_EXECUTABLE
    "<CMAKE_C_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")
endif()

因此，您可以使用CMAKE_C_LINK_EXECUTABLE覆盖完整的链接器调用，或者您可以使用CMAKE_C_LINK_FLAGS来设置其他标志。

The "official" way

设置target's linker and compiler flags的官方方式是（在CMake 2.8.12之前）：

set_property(TARGET blinky APPEND_STRING PROPERTY COMPILE_FLAGS "--cpu=Cortex-M3")
set_property(TARGET blinky APPEND_STRING PROPERTIES LINK_FLAGS "--map --ro-base=0x0 --rw-base=0x0008000 --first='boot.o(RESET)' --datacompressor=off")

从CMake 2.8.12开始，它将是这样的：

add_compile_options("--cpu=Cortex-M3")