如何在 Oracle 上使用 AUTO_INCREMENT 创建 id？

Posted

技术标签:

【中文标题】如何在 Oracle 上使用 AUTO_INCREMENT 创建 id？【英文标题】：How to create id with AUTO_INCREMENT on Oracle? 【发布时间】：2012-07-03 00:37:29 【问题描述】：

在 Oracle 中似乎没有 AUTO_INCREMENT 的概念，直到并包括版本 11g。

如何在 Oracle 11g 中创建一个行为类似于自动增量的列？

【问题讨论】：

您可以在表上创建BEFORE INSERT 触发器并从序列中提取值以创建自动增量 标识列现在在 Oracle 12c 中可用 docs.oracle.com/cd/E16655_01/gateways.121/e22508/… 见IDENTITY column autoincrement functionality in Oracle 12c和Auto-increment primary key in Pre 12c releases。 您在使用 Oracle RAC 吗？在语句末尾使用 CACHED 可以提高性能。如果您在短时间内执行大量插入（并且顺序对您来说并不重要），请考虑使用交错序列插入触发器以获得额外的性能优势。见：dba-oracle.com/t_rac_proper_sequence_usage.htm 【参考方案1】：

在 oracle 中创建自动增量的查询。在下面的查询中，每当插入新行时，incrmnt 列的值都会自动递增

CREATE TABLE table1(
id RAW(16) NOT NULL ENABLE,
incrmnt NUMBER(10,0) GENERATED ALWAYS AS IDENTITY
MINVALUE 1 MAXVALUE 999999999999999999999999999 INCREMENT BY 1 START WITH 1 NOORDER NOCYCLE NOT NULL ENABLE,
CONSTRAINT PK_table1 PRIMARY KEY (id) ENABLE);

【讨论】：

【参考方案2】：

从 Oracle 11g 开始，Oracle 中没有“auto_increment”或“identity”列。但是，您可以使用序列和触发器轻松建模：

表定义：

CREATE TABLE departments (
  ID           NUMBER(10)    NOT NULL,
  DESCRIPTION  VARCHAR2(50)  NOT NULL);

ALTER TABLE departments ADD (
  CONSTRAINT dept_pk PRIMARY KEY (ID));

CREATE SEQUENCE dept_seq START WITH 1;

触发器定义：

CREATE OR REPLACE TRIGGER dept_bir 
BEFORE INSERT ON departments 
FOR EACH ROW

BEGIN
  SELECT dept_seq.NEXTVAL
  INTO   :new.id
  FROM   dual;
END;
/

更新：

IDENTITY 列现已在 Oracle 12c 上可用：

create table t1 (
    c1 NUMBER GENERATED by default on null as IDENTITY,
    c2 VARCHAR2(10)
    );

或指定起始值和增量值，同时防止任何插入标识列 (GENERATED ALWAYS)（同样，仅限 Oracle 12c+）

create table t1 (
    c1 NUMBER GENERATED ALWAYS as IDENTITY(START with 1 INCREMENT by 1),
    c2 VARCHAR2(10)
    );

或者，Oracle 12 还允许使用序列作为默认值：

CREATE SEQUENCE dept_seq START WITH 1;

CREATE TABLE departments (
  ID           NUMBER(10)    DEFAULT dept_seq.nextval NOT NULL,
  DESCRIPTION  VARCHAR2(50)  NOT NULL);

ALTER TABLE departments ADD (
  CONSTRAINT dept_pk PRIMARY KEY (ID));

【讨论】：

我是n00b，你能告诉我dept_seq来自哪里！ 创建序列 dept_seq;创建 dept_seq ... 像一个表 .. 但在这种情况下，它只是一个可以使用 dept_seq.NEXTVAL 增加的数字 ... 查看触发器。 如前所述，当遇到指定 ID 的行时，原始代码会失败。但是这种情况如何：只有在 INSERT 中没有明确指定 id 时，触发器才会（自动）分配 id。这会失败，对吧？这样做的正确方法是什么？ 对于像我这样的oracle新手，'new.id'的'id'部分是指上表中的'id'列。 'new' 是一个保留字，指的是创建的新行 您不需要在触发器中使用SELECT .. INTO，您可以使用:new.id := dept_seq.NEXTVAL;。【参考方案3】：

在 Oracle 12c 以后，您可以执行类似的操作，

CREATE TABLE MAPS
(
  MAP_ID INTEGER GENERATED ALWAYS AS IDENTITY (START WITH 1 INCREMENT BY 1) NOT NULL,
  MAP_NAME VARCHAR(24) NOT NULL,
  UNIQUE (MAP_ID, MAP_NAME)
);

在 Oracle 中（Pre 12c）。

-- create table
CREATE TABLE MAPS
(
  MAP_ID INTEGER NOT NULL ,
  MAP_NAME VARCHAR(24) NOT NULL,
  UNIQUE (MAP_ID, MAP_NAME)
);

-- create sequence
CREATE SEQUENCE MAPS_SEQ;

-- create tigger using the sequence
CREATE OR REPLACE TRIGGER MAPS_TRG 
BEFORE INSERT ON MAPS 
FOR EACH ROW
WHEN (new.MAP_ID IS NULL)
BEGIN
  SELECT MAPS_SEQ.NEXTVAL
  INTO   :new.MAP_ID
  FROM   dual;
END;
/

【讨论】：

@JonHeller 我个人说IDENTITY 的例子在这个答案中更加清晰。 WHEN (new.MAP_ID IS NULL) 不在接受的答案中。赞成。 @dcsohl，WHEN ( new.MAP_ID is null) 在这种情况下不是一个好的代码，@A.B.Cade 在接受的答案下已经在评论部分进行了解释.. 阅读;) 当我从CREATE OR REPLACE TRIGGER 运行到END; 时，我得到一个“输入绑定”窗口。如果我单击“应用”并且不在该窗口中执行任何其他操作，然后运行ALTER TRIGGER 命令，一切都很好，但希望有一种方法可以以编程方式摆脱该弹出窗口并一起运行所有内容。如果你完全尝试，你会得到PLS-00103: Encountered the symbol 'ALTER'，它也不喜欢EXECUTE IMMEDIATE（同样的错误，只是说Encountered the symbol 'EXECUTE'）。 在运行 Oracle 12c 以后的版本时，我得到了[42000][907] ORA-00907: missing right parenthesis。有什么想法吗？【参考方案4】： 
FUNCTION UNIQUE2(
 seq IN NUMBER
) RETURN VARCHAR2
AS
 i NUMBER := seq;
 s VARCHAR2(9);
 r NUMBER(2,0);
BEGIN
  WHILE i > 0 LOOP
    r := MOD( i, 36 );
    i := ( i - r ) / 36;
    IF ( r < 10 ) THEN
      s := TO_CHAR(r) || s;
    ELSE
      s := CHR( 55 + r ) || s;
    END IF;
  END LOOP;
  RETURN 'ID'||LPAD( s, 14, '0' );
END;

【讨论】：

描述一下这个函数应该做什么会很有帮助；我无法想象它对于传入的任何可能的NUMBER 都能正常工作。【参考方案5】： 
FUNCTION GETUNIQUEID_2 RETURN VARCHAR2
AS
v_curr_id NUMBER;
v_inc NUMBER;
v_next_val NUMBER;
pragma autonomous_transaction;
begin 
CREATE SEQUENCE sequnce
START WITH YYMMDD0000000001
INCREMENT BY 1
NOCACHE
select sequence.nextval into v_curr_id from dual;
if(substr(v_curr_id,0,6)= to_char(sysdate,'yymmdd')) then
v_next_val := to_number(to_char(SYSDATE+1, 'yymmdd') || '0000000000');
v_inc := v_next_val - v_curr_id;
execute immediate ' alter sequence sequence increment by ' || v_inc ;
select sequence.nextval into v_curr_id from dual;
execute immediate ' alter sequence sequence increment by 1';
else
dbms_output.put_line('exception : file not found');
end if;
RETURN 'ID'||v_curr_id;
END;

【讨论】：

【参考方案6】：

Oracle Database 12c 引入了 Identity，这是一个自动增量（系统生成）的列。 在以前的数据库版本（直到 11g）中，您通常通过创建序列和触发器来实现身份。 从 12c 开始，您可以创建自己的 Table 并将必须生成的列定义为 Identity。

以下文章解释了如何使用它：

Identity columns - A new entry in Oracle Database 12c

【讨论】：

虽然此链接可能会回答问题，但最好在此处包含答案的基本部分并提供链接以供参考。如果链接页面发生更改，仅链接的答案可能会失效。【参考方案7】：

它被称为 Identity Columns，只能从 oracle Oracle 12c 获得

CREATE TABLE identity_test_tab
(
   id            NUMBER GENERATED ALWAYS AS IDENTITY,
   description   VARCHAR2 (30)
);

插入Identity Columns的示例如下

INSERT INTO identity_test_tab (description) VALUES ('Just DESCRIPTION');

已创建 1 行。

你不能像下面这样插入

INSERT INTO identity_test_tab (id, description) VALUES (NULL, 'ID=NULL and DESCRIPTION');

第 1 行出现错误：ORA-32795：无法插入生成的始终 身份列

INSERT INTO identity_test_tab (id, description) VALUES (999, 'ID=999 and DESCRIPTION');

第 1 行出现错误：ORA-32795：无法插入生成的始终 身份列

useful link

【讨论】：

【参考方案8】：

这就是我在现有表和列（名为 id）上执行此操作的方式：

UPDATE table SET id=ROWNUM;
DECLARE
  maxval NUMBER;
BEGIN
  SELECT MAX(id) INTO maxval FROM table;
  EXECUTE IMMEDIATE 'DROP SEQUENCE table_seq';
  EXECUTE IMMEDIATE 'CREATE SEQUENCE table_seq START WITH '|| TO_CHAR(TO_NUMBER(maxval)+1) ||' INCREMENT BY 1 NOMAXVALUE';
END;
CREATE TRIGGER table_trigger
  BEFORE INSERT ON table
  FOR EACH ROW
BEGIN
  :new.id := table_seq.NEXTVAL;
END;

【讨论】：

【参考方案9】：

这里有三种口味：

    数字。简单的递增数值，例如1,2,3,.... GUID。全局通用标识符，作为 RAW 数据类型。 GUID（字符串）。与上面相同，但作为字符串在某些语言中可能更容易处理。

x 是标识列。在每个示例中，将 FOO 替换为您的表名。

-- numerical identity, e.g. 1,2,3...
create table FOO (
    x number primary key
);
create sequence  FOO_seq;

create or replace trigger FOO_trg
before insert on FOO
for each row
begin
  select FOO_seq.nextval into :new.x from dual;
end;
/

-- GUID identity, e.g. 7CFF0C304187716EE040488AA1F9749A
-- use the commented out lines if you prefer RAW over VARCHAR2.
create table FOO (
    x varchar(32) primary key        -- string version
    -- x raw(32) primary key         -- raw version
);

create or replace trigger FOO_trg
before insert on FOO
for each row
begin
  select cast(sys_guid() as varchar2(32)) into :new.x from dual;  -- string version
  -- select sys_guid() into :new.x from dual;                     -- raw version
end;
/

更新：

Oracle 12c 引入了这两种不依赖触发器的变体：

create table mytable(id number default mysequence.nextval);
create table mytable(id number generated as identity);

第一个以传统方式使用序列；第二个在内部管理值。

【讨论】：

【参考方案10】：

从 Oracle 12c 开始，可以通过以下两种方式之一支持 Identity 列：

    Sequence + Table - 在这个解决方案中，您仍然像往常一样创建一个序列，然后使用以下 DDL：

    创建表 MyTable （ID NUMBER DEFAULT MyTable_Seq.NEXTVAL， ...)

    仅限表格 - 在此解决方案中，没有明确指定顺序。您将使用以下 DDL：

    CREATE TABLE MyTable (ID NUMBER GENERATED AS IDENTITY, ...)

如果你使用第一种方式，它向后兼容现有的做事方式。第二个更简单一些，并且更符合其他 RDMS 系统。

【讨论】：

【参考方案11】：

这是针对自动增量的异常/错误处理的完整解决方案，该解决方案向后兼容，适用于 11g 和 12c，特别是在应用程序处于生产状态时。

请将“TABLE_NAME”替换为您的相应表名

--checking if table already exisits
BEGIN
    EXECUTE IMMEDIATE 'DROP TABLE TABLE_NAME';
    EXCEPTION WHEN OTHERS THEN NULL;
END;
/

--creating table
CREATE TABLE TABLE_NAME (
       ID NUMBER(10) PRIMARY KEY NOT NULL,
       .
       .
       .
);

--checking if sequence already exists
BEGIN
    EXECUTE IMMEDIATE 'DROP SEQUENCE TABLE_NAME_SEQ';
    EXCEPTION WHEN OTHERS THEN NULL;
END;

--creating sequence
/
CREATE SEQUENCE TABLE_NAME_SEQ START WITH 1 INCREMENT BY 1 MINVALUE 1 NOMAXVALUE NOCYCLE CACHE 2;

--granting rights as per required user group
/
GRANT SELECT, INSERT, UPDATE, DELETE ON TABLE_NAME TO USER_GROUP;

-- creating trigger
/
CREATE OR REPLACE TRIGGER TABLE_NAME_TS BEFORE INSERT OR UPDATE ON TABLE_NAME FOR EACH ROW
BEGIN    
    -- auto increment column
    SELECT TABLE_NAME_SEQ.NextVal INTO :New.ID FROM dual;

    -- You can also put some other required default data as per need of your columns, for example
    SELECT SYS_CONTEXT('USERENV', 'SESSIONID') INTO :New.SessionID FROM dual;
    SELECT SYS_CONTEXT('USERENV','SERVER_HOST') INTO :New.HostName FROM dual;
    SELECT SYS_CONTEXT('USERENV','OS_USER') INTO :New.LoginID FROM dual;    
    .
    .
    .
END;
/

【讨论】：

【参考方案12】： 
  create trigger t1_trigger
  before insert on AUDITLOGS
  for each row
   begin
     select t1_seq.nextval into :new.id from dual;
   end;

只有我必须用你的表名更改表名（AUDITLOGS），用 new.column_name 更改 new.id

【讨论】：

【参考方案13】：

也许试试这个简单的脚本：

http://www.hlavaj.sk/ai.php

结果是：

CREATE SEQUENCE TABLE_PK_SEQ; 
CREATE OR REPLACE TRIGGER TR_SEQ_TABLE BEFORE INSERT ON TABLE FOR EACH ROW 

BEGIN
SELECT TABLE_PK_SEQ.NEXTVAL
INTO :new.PK
FROM dual;
END;

【讨论】：

这与 eugnio 的回答有何不同？另外：在现代 Oracle 版本中，您不需要 select。你可以简单地使用:new.pk := TABLE_PK_SEQ.NEXTVAL【参考方案14】：

Trigger 和Sequence 可以在您想要任何人都可以轻松阅读/记住/理解的序列号时使用。但是如果你不想通过这种方式管理ID Column（比如emp_id），并且该列的值不是很大，你可以在创建表时使用SYS_GUID()来获得这样的Auto Increment。

CREATE TABLE <table_name> 
(emp_id RAW(16) DEFAULT SYS_GUID() PRIMARY KEY,
name VARCHAR2(30));

现在您的emp_id 列将接受“全局唯一标识符值”。 您可以通过忽略这样的 emp_id 列在表中插入值。

INSERT INTO <table_name> (name) VALUES ('name value');

因此，它将向您的 emp_id 列插入唯一值。

【讨论】：

删除一行时会发生什么？ SYS_GUID() 的 id 值也会吗？【参考方案15】：

SYS_GUID 返回一个 GUID——一个全球唯一的 ID。 SYS_GUID 是 RAW(16)。它不会生成递增的数值。

如果您想创建一个递增的数字键，您需要创建一个序列。 

CREATE SEQUENCE name_of_sequence
  START WITH 1
  INCREMENT BY 1
  CACHE 100;

然后，您可以在 INSERT 语句中使用该序列

INSERT INTO name_of_table( primary_key_column, <<other columns>> )
  VALUES( name_of_sequence.nextval, <<other values>> );

或者您可以定义一个触发器，使用序列自动填充主键值

CREATE OR REPLACE TRIGGER trigger_name
  BEFORE INSERT ON table_name
  FOR EACH ROW
BEGIN
  SELECT name_of_sequence.nextval
    INTO :new.primary_key_column
    FROM dual;
END;

如果您使用的是 Oracle 11.1 或更高版本，您可以稍微简化一下触发器

CREATE OR REPLACE TRIGGER trigger_name
  BEFORE INSERT ON table_name
  FOR EACH ROW
BEGIN
  :new.primary_key_column := name_of_sequence.nextval;
END;

如果你真的想用SYS_GUID

CREATE TABLE table_name (
  primary_key_column raw(16) default sys_guid() primary key,
  <<other columns>>
)

【讨论】：

CACHE 100; in CREATE SEQUENCE name_of_sequence START WITH 1 INCREMENT BY 1 CACHE 100; 是做什么的？ CACHE 100：关键字将接下来的 100 个数字提取到内存中。通常，只要 SEQUENCE 的值发生更改，就会将其保存到数据库中，如果您对其进行缓存，则只有在缓存的内容耗尽时才会保存和检索它。为您带来显着的性能提升，但如果数据库出现故障，您将丢失所有甚至没有使用的缓存值。 SYS_GUID() 是 RAW(16)，而不是 32。 @turbanoff - 很好的收获。更新了我的答案。 SYS_GUID 文档声明了 raw(32)，这让我很困惑。 @JustinCave 我在创建序列和触发器时使用了您的方法。如果我以编程方式（java）删除一行，ID（主键）是否也会得到调整？【参考方案16】：

oracle 在 12c 中有序列和身份列

http://www.oracle-base.com/articles/12c/identity-columns-in-oracle-12cr1.php#identity-columns

我找到了这个，但不确定 rdb 7 是什么 http://www.oracle.com/technetwork/products/rdb/0307-identity-columns-128126.pdf

【讨论】：

有用的信息和有趣的性能比较。使用 IDENTITY 列比对 SEQUENCE 使用 TRIGGER 更好。 @ygoe 是对的；一般来说，任何触发器都有很多开销；和序列（无论如何都隐藏在IDENTITY 列后面）非常轻量级。【参考方案17】：

假设您指的是 SQL Server 标识列之类的列？

在 Oracle 中，您使用 SEQUENCE 来实现相同的功能。我会看看能不能找到一个好的链接并在这里发布。

更新：好像是你自己找到的。无论如何，这是链接： http://www.techonthenet.com/oracle/sequences.php

【讨论】：

以上是关于如何在 Oracle 上使用 AUTO_INCREMENT 创建 id？的主要内容，如果未能解决你的问题，请参考以下文章

如何使用 pi spark 在 oracle 数据库上执行选择查询？

Oracle：如何找出函数表使用了多少空间（在 RAM 上）？

如何在 Oracle 10+ 中包含 NULL 的列上使用基于函数的索引？

在linux上如何查看oracle的表空间

如何在 Oracle 视图上添加主键？ [复制]

如何在Oracle公有云上建立IaaS私有镜像