如何在已排序的 xsl:for-each 循环中访问前一个和下一个元素的值

Posted 2023-02-16

【中文标题】如何在已排序的 xsl:for-each 循环中访问前一个和下一个元素的值

【英文标题】：How to access values from previous and next element in sorted xsl:for-each loop

【发布时间】：2019-11-18 22:22:58

【问题描述】：

我正在使用 xsl:for-each 循环根据元素的@id-attribute 对元素进行排序。我需要获取循环中上一个和下一个元素的@id-attributes。

我一直在尝试使用 previous-sibling:: 和 following-sibling 轴，但无济于事。我也试过了

<xsl:variable name="current_pos" select="position()"/>
<xsl:value-of select="(//chapter)[($current_pos - 1)]/id>

但这会返回未排序数据的属性值。

示例 XML 数据：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <chapter id="t19"/>
    <chapter id="a23"/>
    <chapter id="c-0"/>
    <chapter id="d42"/>
    <chapter id="c-1"/>
</root>

XSLT 样式表示例：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="3.0">

    <xsl:template match="/root">
        <xsl:for-each select="chapter">
            <xsl:sort select="@id"/>
            <xsl:variable name="current_id" select="@id"/>
            Chapter id: <xsl:value-of select="$current_id"/>
            Sorted position: <xsl:value-of select="position()"/>
            Sorted predecessor chapter id: ? <!-- no idea but most important -->
            Sorted follower chapter id: ? <!-- no idea but most important -->
            <xsl:text>&#xa;</xsl:text>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

我需要的结果：

Chapter id: a23
Sorted position: 1
Sorted predecessor chapter id: none 
Sorted follower chapter id: c-0

Chapter id: c-0
Sorted position: 2
Sorted predecessor chapter id: a23 
Sorted follower chapter id: c-1     

Chapter id: c-1
Sorted position: 3
Sorted predecessor chapter id: c-0 
Sorted follower chapter id: d42

Chapter id: d42
Sorted position: 4
Sorted predecessor chapter id: c-1 
Sorted follower chapter id: t19

Chapter id: t19
Sorted position: 5
Sorted predecessor chapter id: d42 
Sorted follower chapter id: none

【问题讨论】：

好吧，首先排序，然后从排序序列中选择项目，如您所显示的version="3.0"，如果支持高阶函数，您可以使用sort(chapter, (), function($c) $c/@id ) 进行排序序列甚至@ 987654328@ 有一个排序的字符串序列。输出所有值可以在 XQuery 中通过tumbling window 子句和start 和end 子句存储您感兴趣的值来优雅地完成：xqueryfiddle.liberty-development.net/eiQZDbt

【参考方案1】：

您无法在 xsl:for-each 循环中获取前面和/或后面的元素，因为严格来说 xsl:for-each 不是循环，而是映射构造。

您可以将排序结果保存在变量中，就像这样......

<xsl:variable name="chapters" as="element()*">
     <xsl:perform-sort select="chapter">
        <xsl:sort select="@id"/>
    </xsl:perform-sort>
</xsl:variable>

然后您可以对此使用xsl:for-each，并访问chapters 变量本身中的上一个和下一个值。

<xsl:value-of select="$chapters[position() = $current_pos - 1]/@id" />

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="3.0">

    <xsl:template match="/root">
        <xsl:variable name="chapters" as="element()*">
            <xsl:perform-sort select="chapter">
                <xsl:sort select="@id"/>
            </xsl:perform-sort>
        </xsl:variable>
        <xsl:for-each select="$chapters">
            <xsl:variable name="current_id" select="@id"/>
            <xsl:variable name="current_pos" select="position()"/>
            Chapter id: <xsl:value-of select="$current_id"/>
            Sorted position: <xsl:value-of select="position()"/>
            Sorted predecessor chapter id: <xsl:value-of select="$chapters[position() = $current_pos - 1]/@id" />
            Sorted follower chapter id: ? <xsl:value-of select="$chapters[position() = $current_pos + 1]/@id" />
            <xsl:text>&#xa;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

【讨论】：

@martin-hinze - 请考虑accepting this answer。另请参阅***.com/help/someone-answers 了解更多信息。