如何使用 xslt 获取与复杂条件匹配的所有 xml 项的计数并在终止语句中使用它？

Posted 2023-02-16

技术标签:

【中文标题】如何使用 xslt 获取与复杂条件匹配的所有 xml 项的计数并在终止语句中使用它？【英文标题】：How can I can get a count of all xml items matching complex conditions using xslt and use it in a terminate statement? 【发布时间】：2021-12-24 09:26:17 【问题描述】：

我需要过滤一个项目列表，并且只保留日期元素比另一个日期元素大一天以上的项目。然后我还需要知道剩下多少过滤项目，如果没有，就终止整个事情。我已经简化了我的数据，但或多或少是这样的：

<data>
    <person>
        <name>Tyler</name>
    </person>
    <items>
        <item>
            <title>A</title>
            <start_date>10/31/2021</start_date>
            <end_date>11/01/2021</end_date>
        </item>
        <item>
            <title>B</title>
            <start_date>08/05/2021</start_date>
            <end_date>08/10/2021</end_date>
        </item>
        <item>
            <title>C</title>
            <start_date>09/04/2021</start_date>
            <end_date>09/05/2021</end_date>
        </item>
    </items>
</data>

因此，在该示例中，将仅保留 B 并发送消息。但如果 B 是

        <item>
            <title>B</title>
            <start_date>08/05/2021</start_date>
            <end_date>08/06/2021</end_date>
        </item>

消息不会发送。

到目前为止，我已经找到了一种使用here 建议的方法来转换文本日期的方法。这适用于过滤列表，但我不知道如何确定结果列表中是否有任何元素，然后如何在终止语句中使用它。任何帮助将不胜感激，并在此先感谢您！这是我在 xsl 上的位置：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/data">

        <xsl:if test="???? Whatever can figure out the number of elements left ????">
            <xsl:message terminate="yes">There are no items left</xsl:message>
        </xsl:if>
        <html>
            <head>
                <title></title>
            </head>
            <body>
                <p>
                    <xsl:text>Name: </xsl:text>
                    <xsl:value-of select="person/name"/>
                </p>
                <table>
                    <thead>
                        <tr><th>Title</th></tr>
                    </thead>

                    <xsl:for-each select="items/item">

                        <xsl:variable name="JDN_start_date">
                            <xsl:call-template name="JDN">
                                <xsl:with-param name="date" select="start_date" />
                            </xsl:call-template>
                        </xsl:variable>

                        <xsl:variable name="JDN_end_date">
                            <xsl:call-template name="JDN">
                                <xsl:with-param name="date" select="end_date" />
                            </xsl:call-template>
                        </xsl:variable>

                        <xsl:if test="($JDN_end_date - $JDN_start_date) &gt; 1">
                            <tr>
                                <td><xsl:value-of select="title"/></td>
                            </tr>
                        </xsl:if>
                    </xsl:for-each>

                </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template name="JDN">        <!-- Date string to Julian day number -->
        <xsl:param name="date"/>
        <xsl:param name="year" select="substring($date, 7, 4)"/>
        <xsl:param name="month" select="substring($date, 1, 2)"/>
        <xsl:param name="day" select="substring($date, 4, 2)"/>
        <xsl:param name="a" select="floor((14 - $month) div 12)"/>
        <xsl:param name="y" select="$year + 4800 - $a"/>
        <xsl:param name="m" select="$month + 12*$a - 3"/>
        <xsl:value-of select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />
    </xsl:template>

</xsl:stylesheet>

【问题讨论】：

你需要分两遍来做：首先，计算每对日期之间的差异；然后处理结果并计算差异大于 1 的项目。您将使用哪个 XSLT 处理器？也许一些扩展功能在这里会有所帮助。感谢您提供的信息。这一切都发生在一个用于自定义第三方平台内置电子邮件的模块中，所以我不太了解幕后的内容，但使用 <xsl:value-of select="system-property('xsl:vendor')"/> 会返回“Apache Software Foundation (Xalan XSLTC)”。我发布了一个几乎纯 XSLT 1.0 的解决方案，只使用无处不在的 node-set() 扩展函数。但是您应该知道 Xalan XSLTC 支持使用 Java 作为扩展。 【参考方案1】：

考虑以下示例：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/data">
    <!-- 1. calculate durations -->
    <xsl:variable name="items">
        <xsl:for-each select="items/item">
            <xsl:copy>
                <xsl:attribute name="duration">
                    <xsl:call-template name="date-difference">
                        <xsl:with-param name="date1" select="start_date" />
                        <xsl:with-param name="date2" select="end_date" />
                    </xsl:call-template>
                </xsl:attribute>
                <xsl:copy-of select="*"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:variable>
    <!-- 2. find items with duration > 1 -->
    <xsl:variable name="pass-items" select="exsl:node-set($items)/item[@duration > 1]" />
    <xsl:if test="not($pass-items)">
        <xsl:message terminate="yes">no items pass</xsl:message>
    </xsl:if>
    <!-- 3. output -->
    <output>
        <xsl:copy-of select="$pass-items"/>
    </output>
</xsl:template> 

<xsl:template name="date-difference">
    <xsl:param name="date1"/>
    <xsl:param name="date2"/>
    <xsl:param name="JDN1">
        <xsl:call-template name="JDN">
            <xsl:with-param name="date" select="$date1" />
        </xsl:call-template>
    </xsl:param>
    <xsl:param name="JDN2">
        <xsl:call-template name="JDN">
            <xsl:with-param name="date" select="$date2" />
        </xsl:call-template>
    </xsl:param>
    <xsl:value-of select="$JDN2 - $JDN1"/>
</xsl:template> 

<xsl:template name="JDN">
    <xsl:param name="date"/>
    <xsl:param name="year" select="substring($date, 7, 4)"/>
    <xsl:param name="month" select="substring($date, 1, 2)"/>
    <xsl:param name="day" select="substring($date, 4, 2)"/>
    <xsl:param name="a" select="floor((14 - $month) div 12)"/>
    <xsl:param name="y" select="$year + 4800 - $a"/>
    <xsl:param name="m" select="$month + 12*$a - 3"/>
    <xsl:value-of select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />
</xsl:template> 

</xsl:stylesheet>

【讨论】：

成功了！非常感谢，感谢您提供有关 Xalan XSLTC 的额外信息。

以上是关于如何使用 xslt 获取与复杂条件匹配的所有 xml 项的计数并在终止语句中使用它？的主要内容，如果未能解决你的问题，请参考以下文章

xslt2+ 如何将组与任何匹配的元素组合并删除元素的重复项

如何对适配器中的输入请求执行 xslt 转换

WiX 安装程序：将 xslt 与 heat.exe 一起使用时，如何在还使用匹配属性时找到匹配的子字符串？

使用 Python 或 XSLT 将复杂的 XML 转换为 CSV

XSLT：测试当前元素是不是匹配变量 xpath

应用所有模板