For Each 循环：循环通过 Outlook 邮箱删除项目时，某些项目会被跳过

Posted 2023-02-24

【中文标题】For Each 循环：循环通过 Outlook 邮箱删除项目时，某些项目会被跳过

【英文标题】：For Each loop: Some items get skipped when looping through Outlook mailbox to delete items

【发布时间】：2012-05-30 07:17:35

【问题描述】：

我想开发 VBA 代码：

遍历邮箱中的所有电子邮件项目 如果有任何类型的其他项目，请说“日历邀请”会跳过该项目。 找出带有附件的电子邮件 如果附件具有“.xml”扩展名和特定标题，则将其保存到目录中，否则继续搜索 在执行第 4 步后，将所有包含 .xml 附件的电子邮件放入“已删除邮件”文件夹，并通过循环删除该文件夹中的所有电子邮件。

代码完美运行，除了； 例如

在您的邮箱中收到了 8 封电子邮件，每封都附有“.xml”文件。 运行代码 您将看到 8 个项目中只有 4 个已成功处理，其他 4 个保留在其位置。 如果您再次运行代码，现在将成功处理 2 个项目，另外 2 个保留在您的邮箱中。

问题：运行代码后，它应该处理所有文件并将它们全部删除，而不是每次运行时删除它们的一半。我希望它一次处理所有项目。

顺便说一句，每次我打开 Outlook 时都会运行此代码。

Private Sub Application_Startup()
'Initializing Application_Startup forces the macros to be accessible from other offic apps

'Process XML emails

Dim InboxMsg As Object

Dim DeletedItems As Outlook.Folder
Dim MsgAttachment As Outlook.Attachment
Dim ns As Outlook.NameSpace
Dim Inbox As Outlook.Folder

Dim fPathTemp As String
Dim fPathXML_SEM As String
Dim fPathEmail_SEM As String
Dim i As Long
Dim xmlDoc As New MSXML2.DOMDocument60
Dim xmlTitle As MSXML2.IXMLDOMNode
Dim xmlSupNum As MSXML2.IXMLDOMNode

    'Specify the folder where the attachments will be saved
    fPathTemp = "some directory, doesn't matter"
    fPathXML_SEM = "some directory, doesn't matter"
    fPathEmail_SEM = "some directory, doesn't matter"

    'Setup Outlook
    Set ns = GetNamespace("MAPI")
    Set Inbox = ns.Folders.Item("mailbox-name").Folders("Inbox")
    Set DeletedItems = ns.Folders.Item("mailbox-name").Folders("Deleted Items")


    'Loop through all Items in Inbox, find the xml attachements and process if they are the matching reponses
    'On Error Resume Next
    For Each InboxMsg In Inbox.Items
        If InboxMsg.Class = olMail Then 'if it is a mail item

            'Check for xml attachement
            For Each MsgAttachment In InboxMsg.Attachments

                If Right(MsgAttachment.DisplayName, 3) = "xml" Then

                    'Load XML and test for the title of the file
                    MsgAttachment.SaveAsFile fPathTemp & MsgAttachment.FileName
                    xmlDoc.Load fPathTemp & MsgAttachment.FileName
                    Set xmlTitle = xmlDoc.SelectSingleNode("//title")
                    Select Case xmlTitle.Text
                        Case "specific title"
                            'Get supplier number
                            Set xmlSupNum = xmlDoc.SelectSingleNode("//supplierNum")
                            'Save the XML to the correct folder
                            MsgAttachment.SaveAsFile fPathXML_SEM & xmlSupNum.Text & "_" & Format(Date, "yyyy-mm-dd") & ".xml"
                            'Save the email to the correct folder
                            InboxMsg.SaveAs fPathEmail_SEM & xmlSupNum.Text & "_" & Format(Date, "yyyy-mm-dd") & ".msg"
                            'Delete the message
                            InboxMsg.Move DeletedItems
                        Case Else

                    End Select
                    'Delete the temp file
                    On Error Resume Next
                    Kill fPathTemp & MsgAttachment.FileName
                    On Error GoTo 0
                    'Unload xmldoc
                    Set xmlDoc = Nothing
                    Set xmlTitle = Nothing
                    Set xmlSupNum = Nothing
                End If
            Next
        End If
    Next

    'Loop through deleted items and delete
    For Each InboxMsg In DeletedItems.Items
        InboxMsg.Delete
    Next

    'Clean-up
    Set InboxMsg = Nothing
    Set DeletedItems = Nothing
    Set MsgAttachment = Nothing
    Set ns = Nothing
    Set Inbox = Nothing
    i = 0

End Sub

【问题讨论】：

您也可以使用Items.Restrict Method 来过滤您的收件箱。这将返回过滤后的 Items 集合，该集合仅包含带有附件的项目。通过避免没有附件的项目，这将在一定程度上加快您的代码速度。

***.com/a/29910853/4539709

【参考方案1】：

在循环访问一组（子）项时修改它们的内容通常不是一个好主意。您可以修改您的代码，使其首先识别所有需要处理的项目，然后将它们添加到Collection。然后处理该集合中的所有项目。

基本上，您不应该在循环浏览收件箱的内容时从收件箱中删除项目。首先收集您要处理的所有项目（在您的收件箱循环中），然后当您完成循环时，处理该项目集合。

这里有一些演示这个的伪代码：

Private Sub Application_Startup()

    Dim collItems As New Collection

    'Start by identifying messages of interest and add them to a collection
    For Each InboxMsg In Inbox.Items
        If InboxMsg.Class = olMail Then 'if it is a mail item
            For Each MsgAttachment In InboxMsg.Attachments
                If Right(MsgAttachment.DisplayName, 3) = "xml" Then
                    collItems.Add InboxMsg
                    Exit For
                End If
            Next
        End If
    Next

    'now deal with the identified messages
    For Each InboxMsg In collItems
        ProcessMessage InboxMsg
    Next InboxMsg

    'Loop through deleted items and delete
    For Each InboxMsg In DeletedItems.Items
        InboxMsg.Delete
    Next

End Sub

Sub ProcessMessage(InboxMsg As Object)
    'deal with attachment(s) and delete message
End Sub

【参考方案2】：

可能的原因：当您这样做InboxMsg.Move 时，收件箱中的所有邮件在被移动的邮件之后都会在列表中上升一位。所以你最终会跳过其中的一些。这是 VBA 的 For Each 构造的一个主要烦恼（而且它似乎也不一致）。

可能的解决方案：替换

For Each InboxMsg In Inbox.Items

与

For i = Inbox.Items.Count To 1 Step -1 'Iterates from the end backwards
    Set InboxMsg = Inbox.Items(i)

这样你从列表的末尾向后迭代。当您将消息移动到已删除的项目时，列表中的以下项目何时增加一个并不重要，因为您已经处理了它们。