使用 xslt 2.0 合并具有相同父属性值的元素的 xml 内容

Posted 2023-02-16

【中文标题】使用 xslt 2.0 合并具有相同父属性值的元素的 xml 内容

【英文标题】：Merge xml contents of elements with same parent attribute values using xslt 2.0

【发布时间】：2020-12-05 08:56:26

【问题描述】：

我有两个 xml 文件

file1.xml

<?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000 +0000" stop="20200814050000 +0000" channel="A">
    <title>A</title>
    <sub-title>C</sub-title>
    <desc>F</desc>
  </programme>
...
  <programme start="20200814090000 +0000" stop="20200814093000 +0000" channel="A">
    <title>B</title>
    <sub-title>D</sub-title>
    <desc>E</desc>
  </programme>
...
</tv>

file2.xml

<?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000 +0000" stop="20200814050000 +0000" channel="A">
    <title>G</title>
    <sub-title>C</sub-title>
    <desc>H</desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
...
  <programme start="20200814090000 +0000" stop="20200814093000 +0000" channel="A">
    <title>K</title>
    <sub-title>L</sub-title>
    <desc>M</desc>
    <episode-num system="onscreen">S3 E2</episode-num>
  </programme>  
...
</tv>

我想要一个 xslt 2 模板来获取一个新文件

file3.xml

<?xml version="1.0" encoding="UTF-8"?>
<tv>
...
  <programme start="20200814040000 +0000" stop="20200814050000 +0000" channel="A">
    <title>A (G)</title>
    <sub-title>C</sub-title>
    <desc>F (H)</desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
...
<programme start="20200814090000 +0000" stop="20200814093000 +0000" channel="A">
    <title>B (K)</title>
    <sub-title>D (L)</sub-title>
    <desc>E (M)</desc>
    <episode-num system="onscreen">S3 E2</episode-num>
  </programme>
...
</tv>

我进行了一些实验，但无法获得预期的输出。任何帮助将不胜感激。

为精确而编辑

当每个文件的程序属性相同时：

将两个文件中存在的子元素合并到新文件中的一个元素中并且 如果节点的文本内容不同，请将第二个文件的内容放在括号中 如果两个文件中都不存在子元素，则将其包含在新文件中

【问题讨论】：

那么合并元素的规则是什么？

所以程序元素及其属性必须相同才能进行合并，并且任何相同的子元素都必须合并为一个元素，其中第二个文件的内容在括号。任何不同的子元素都包含在新文件中，没有任何更改

channel 元素的内容是否相关？

否，通道节点不相关

【参考方案1】：

我会这样做：

<xsl:variable name="file1" select="doc('file1.xml')"/>
<xsl:variable name="file2" select="doc('file2.xml')"/>

<xsl:template name="xsl:initial-template">
  <tv>
    <xsl:copy-of select="$file1/tv/channel"/>
    <xsl:for-each-group select="($file1|file2)/tv/programme"
        group-by="@stop, @start, @channel" composite="yes">
      <xsl:for-each-group select="*" group-by="node-name()">
        <xsl:element name="name()">
          <xsl:copy-of select="current-group()/@*"/> 
          <xsl:value-of select="current-group()[1]"/>
          <xsl:for-each select="current-group()[2]">
            <xsl:value-of select="'(', ., ')'"/>
          </xsl:for-each>
        </xsl:element>
      </xsl:for-each-group>
    </xsl:for-each-group>
  </tv>     
</xsl:template>

未测试。

【参考方案2】：

在 XSLT 3 中，for-each-pair 函数可能会有所帮助：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="#all"
  expand-text="yes">
  
  <xsl:param name="doc2">
<tv>
  <channel id="Discovery">
    <display-name lang="el">Discovery</display-name>
  </channel>
  <programme start="20200814040000 +0000" stop="20200814050000 +0000" channel="Discovery">
    <title lang="el">Wheeler Dealers</title>
    <sub-title lang="el">BMW Isetta</sub-title>
    <desc lang="el">Mike tracks down an Isetta Bubble. </desc>
    <episode-num system="onscreen">S9 E13</episode-num>
  </programme>
</tv>
  </xsl:param>
  
  <xsl:output indent="yes"/>
  
  <xsl:function name="mf:merge-pair">
    <xsl:param name="programme1"/>
    <xsl:param name="programme2"/>
    <xsl:if test="deep-equal($programme1/@*, $programme2/@*)">
      <xsl:copy select="$programme1">
        <xsl:apply-templates select="@*"/>
        <xsl:for-each-group select="$programme1/*, $programme2/*" composite="yes" group-by="node-name(), @*">
          <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:value-of select="head(current-group()), tail(current-group()) ! ('(' || . || ')')"/>
          </xsl:copy>
        </xsl:for-each-group>
      </xsl:copy>
    </xsl:if>
  </xsl:function>

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="tv">
    <xsl:copy>
      <xsl:apply-templates select="@*, channel"/>
      <xsl:sequence
         select="for-each-pair(programme, $doc2/tv/programme, mf:merge-pair#2)"/>      
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

在上面的示例中，为了完整性和自包含性，我已经内联了第二个文档，但当然在现实生活中的应用程序中，您可以使用例如<xsl:param name="doc2" select="doc('input2.xml')"/>.

具有 for-each-pair 的 XSLT 3 可用于 Saxon 10 所有版本或 Saxon 的商业 9.8 或 9.9 版本，或用于 Node.js 或浏览器的 Saxon-JS 2。

至于您的评论，您似乎已经编辑了示例，现在看来应该删除像 BMW Isetta (BMW Isetta) 这样的重复内容，以便您进行更改

 <xsl:value-of select="head(current-group()), tail(current-group()) ! ('(' || . || ')')"/>

到

<xsl:value-of select="let $values := distinct-values(current-group()) return (head(
        $values), tail($values)! ('(' || . || ')'))"/>

您编辑的样本和 Saxon HE 10.1 的输出是

<tv>
   <programme start="20200814040000 +0000"
              stop="20200814050000 +0000"
              channel="A">
      <title>A (G)</title>
      <sub-title>C</sub-title>
      <desc>F (H)</desc>
      <episode-num system="onscreen">S9 E13</episode-num>
   </programme>
   <programme start="20200814090000 +0000"
              stop="20200814093000 +0000"
              channel="A">
      <title>B (K)</title>
      <sub-title>D (L)</sub-title>
      <desc>E (M)</desc>
      <episode-num system="onscreen">S3 E2</episode-num>
   </programme>
</tv>

完整的样式表是

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    expand-text="yes">
    
    <xsl:param name="doc2" select="doc('file2.xml')"/>
    
    <xsl:output indent="yes"/>
    
    <xsl:function name="mf:merge-pair">
        <xsl:param name="programme1"/>
        <xsl:param name="programme2"/>
        <xsl:if test="deep-equal($programme1/@*, $programme2/@*)">
            <xsl:copy select="$programme1">
                <xsl:apply-templates select="@*"/>
                <xsl:for-each-group select="$programme1/*, $programme2/*" composite="yes" group-by="node-name(), @*">
                    <xsl:copy>
                        <xsl:apply-templates select="@*"/>
                        <xsl:value-of select="let $values := distinct-values(current-group()) return (head(
                            $values), tail($values)! ('(' || . || ')'))"/>
                    </xsl:copy>
                </xsl:for-each-group>
            </xsl:copy>
        </xsl:if>
    </xsl:function>
    
    <xsl:mode on-no-match="shallow-copy"/>
    
    <xsl:template match="tv">
        <xsl:copy>
            <xsl:apply-templates select="@*, channel"/>
            <xsl:sequence
                select="for-each-pair(programme, $doc2/tv/programme, mf:merge-pair#2)"/>      
        </xsl:copy>
    </xsl:template>
    
</xsl:stylesheet>

【讨论】：

谢谢。我执行了它，但它只是复制了每个文件的内容，即

你用的是什么工具？

saxon 10 java on linux

@apt1506，我已经编辑了答案，以便根据您对要求和示例的编辑进行更改。

您在运行时使用 -it: 选项，还是只提供 -s:file1.xml ？