Excel VBA：将变体数组返回到选定范围时需要 255 转置字符限制的解决方法

Posted 2023-04-18

【中文标题】Excel VBA：将变体数组返回到选定范围时需要 255 转置字符限制的解决方法

【英文标题】：Excel VBA: Need Workaround for 255 Transpose Character Limit When Returning Variant Array to Selected Range

【发布时间】：2016-05-25 13:28:52

【问题描述】：

我正在努力解决一个涉及明显 Excel 255 个字符限制的常见问题。尝试将变体数组从函数返回到工作表上的选定范围时遇到错误。 当函数返回数组中的每个单元格都少于 255 个字符时，它们会按应有的方式发布到工作表：在选定范围内的每个单元格中都会出现一个元素。但是，如果我返回的变量数组中的任何元素长于 255 个字符，我会得到一个值！错误。这些错误很糟糕，因为我需要长元素并希望将数据保持在一起！

这个问题的版本在许多论坛中一遍又一遍地出现，但我能够找到一个清晰简单的通用解决方案，用于将变体数组返回到所选范围（不一定包含公式）单元格超过 255 个字符。 我最大的元素大约是 1000 个，但如果解决方案可以容纳最多 2000 个字符的元素会更好。

最好是，我希望用一个函数或可以添加到我的函数（不是子例程）的附加代码行来实现它。我想要避免子例程的原因：我不想对任何范围进行硬编码。我希望这是灵活的，并且输出位置可以根据我当前的选择动态变化。

如果您能帮助找到一种方法来生成一个函数，该函数将变量数组作为输入，并保持所需的数组：单元格 1:1 关系，我将不胜感激。强>

所以这个带有短单元的功能是有效的：

Function WriteUnder255Cells()

Dim myArray(3) As Variant  'this the variant array I will attempt to write

' Here I fill each element with less than 255 characters
' it should output them if you call the function properly.
myArray(0) = "dog"
myArray(1) = "cat"
myArray(2) = "bird"
myArray(3) = "fly"

WriteUnder255Cells = Application.Transpose(myArray())

End Function

但是这个函数，超过 255 的单元格将不会输出。

Function WriteOver255Cells()

Dim myArray(3) As Variant  'this the variant array I will attempt to write

' Here I fill each element with more than 255 characters
' exceeding the 255-character limit causes the VALUE! errors when you output them
myArray(0) = "ThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelaxydog"
myArray(1) = "ThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydog"
myArray(2) = "ThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydog"
myArray(3) = "ThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydogThequickbrownfoxjumpedoverthelazydog"

WriteOver255Cells = Application.Transpose(myArray())

End Function

这是您产生输出和结果的方式：

首先您需要创建两个模块（要在每个模块中插入一个函数，将其中的代码粘贴到相应的模块中）。要运行“WriteUnder255Cells()”，请在工作表上选择一个 4 行 x 1 列的区域（返回模块的位置），然后在公式栏中键入“=WriteUnder255Cells()”（不要输入引号）。请注意，这些被称为数组公式，所以不是按 (enter) 来创建输出，您需要按 (control + shift + enter)。对 WriteOver255Cells() 重复相同的过程以产生错误。

这里有一些解决该问题的文档/论坛讨论。这些解决方案似乎过于具体或笨拙，因为它们会引发子例程（我想避免）：

https://support.microsoft.com/en-us/kb/213841

http://www.mrexcel.com/forum/excel-questions/852781-visual-basic-applications-evaluate-method-255-character-limit.html

Excel: Use formula longer that 255 characters

VBA code error when array value exceeds 255 characters

http://dailydoseofexcel.com/archives/2005/01/10/entering-long-array-formulas-in-vba/

https://forums.techguy.org/threads/solved-vba-access-to-excel-255-char-limit-issue.996495/

http://www.mrexcel.com/forum/excel-questions/494675-255-character-cell-limit-visual-basic-applications-workaround.html

Array formula with more than 255 characters

http://www.mrexcel.com/forum/excel-questions/388250-size-limit-transferring-variant-range-excel-2007-a.html

【问题讨论】：

不错的链接集合。请阅读How to create a Minimal, Complete, and Verifiable example。

好点，我更新了问题。

【参考方案1】：

这对我有用：

Function Over255()

    Dim myArray(3)  As String '<<<<< not variant

    myArray(0) = String(300, "a")
    myArray(1) = String(300, "b")
    myArray(2) = String(300, "c")
    myArray(3) = String(300, "d")

    'Over255 = Application.Transpose(myArray())
    Over255 = TR(myArray)

End Function

'like Application.Transpose...
Function TR(arrIn) As String()
    Dim arrOut() As String, r As Long, ln As Long, i As Long

    ln = (UBound(arrIn) - LBound(arrIn)) + 1
    ReDim arrOut(1 To ln, 1 To 1)
    i = 1
    For r = LBound(arrIn) To UBound(arrIn)
        arrOut(i, 1) = arrIn(r)
        i = i + 1
    Next r
    TR = arrOut

End Function

似乎您需要返回一个字符串数组，而 Application.Transpose 不这样做

【讨论】：

谢谢！！这是一个非常干净和清晰的解决方案！！！！效果很好！！！！！！