派生类型数组：选择条目

Posted 2023-03-31

【中文标题】派生类型数组：选择条目

【英文标题】：Array of derived type: select entry

【发布时间】：2012-04-08 11:31:45

【问题描述】：

目前在我的代码中我有一个二维数组

integer, allocatable :: elements(:,:)

并定义一些常量

integer, parameter :: TYP = 1
integer, parameter :: WIDTH = 2
integer, parameter :: HEIGHT = 3
! ...
integer, parameter :: NUM_ENTRIES = 10

并分配类似的东西

allocate(elements(NUM_ENTRIES,10000))

所以我可以访问像

这样的元素

write(*,*) elements(WIDTH,100) ! gives the width of the 100th element

现在，我希望每个元素不仅有整数，而且有多种类型。 所以我定义了一个派生类型

type Element
    logical active
    integer type
    real width
    ! etc
end type

并使用元素数组

type(Element), allocatable :: elements(:)

使用二维数组版本，我可以调用一个子例程来告诉它使用哪个条目。 例如

subroutine find_average(entry, avg)
    integer, intent(in) :: entry   
    real, intent(out) :: avg
    integer i, 
    real s

    s = 0
    do i = lbound(elements,1), ubound(elements,1)
        if (elements(TYP,i) .gt. 0) s = s + elements(entry,i)
    end do
    avg = s/(ubound(elements,1)-lbound(elements,1))
end subroutine       

所以我可以通过call find_average(HEIGHT) 找到平均高度或通过WIDTH 获得平均宽度。 （而且我的子程序做的事情比求平均高度或宽度更高级，这只是一个例子。）

问题：我怎样才能使用不同的类型（与派生类型一样），同时又可以重用我的函数来处理不同的条目（如在示例子例程中）？

【参考方案1】：

对于数组情况，您可以传入单个参数数组 (i)，而不是传入参数数组和索引 i。当您切换到派生类型时，类似地，您可以传入 variable_of_type % 元素，而不是传入整个 variable_of_type 并以某种方式指示程序应该处理哪个子元素。如果不同类型的元素（例如，逻辑、整数、实数）的代码需要不同，那么您可以为每个元素编写特定的过程，然后通过通用接口块使用通用名称调用。编译器必须能够通过参数的某些特征（这里是它们的类型）来区分通用接口块的过程。对于区分特征是数组等级的代码示例，请参阅how to write wrapper for 'allocate'

编辑：示例代码。这是你想要的吗？

module my_subs

   implicit none

   interface my_sum
      module procedure sum_real, sum_int
   end interface my_sum

contains

subroutine sum_real (array, tot)
   real, dimension(:), intent (in) :: array
   real, intent (out) :: tot
   integer :: i

   tot = 1.0
   do i=1, size (array)
      tot = tot * array (i)
   end do
end subroutine sum_real

subroutine sum_int (array, tot)
   integer, dimension(:), intent (in) :: array
   integer, intent (out) :: tot
   integer :: i

   tot = 0
   do i=1, size (array)
      tot = tot + array (i)
   end do
end subroutine sum_int

end module my_subs


program test_dt

use my_subs

implicit none

type my_type
   integer weight
   real length
end type my_type

type (my_type), dimension (:), allocatable :: people
type (my_type) :: answer

allocate (people (2))

people (1) % weight = 1
people (1) % length = 1.0
people (2) % weight = 2
people (2) % length = 2.0

call my_sum ( people (:) % weight, answer % weight )
write (*, *)  answer % weight

call my_sum ( people (:) % length, answer % length )
write (*, *)  answer % length

end program test_dt

【讨论】：

entry 将始终指向相同类型的条目（例如总是real），所以幸运的是我不会遇到这个问题。但是前两句话对我来说不是很清楚。对于数组的情况，你的意思是我可以给函数切片elements(WIDTH,:)？对于派生类型的情况，我不想要一个元素，我需要所有元素。您能否附加我的示例函数的修改版本，以便我理解您的意思？谢谢

它正在传递用户定义类型的给定子项的所有元素。如果需要，Fortran 可以根据子项的类型选择不同的程序。这与您想要做的有什么不同？

对不起，我的错，它确实解决了我的问题。 （我可以发誓昨天它是一个不同的代码，但编辑历史表明它不是 g）。所以主要的技巧是在type_array(:)%member 中使用(:) 给出成员类型的数组。好的！感谢您的帮助！