简单的进程间通信

Posted 2023-02-16

技术标签:

【中文标题】简单的进程间通信【英文标题】：Simple interprocess communication 【发布时间】：2019-04-08 17:00:07 【问题描述】：

我想知道 Ada 提供了哪些功能来实现两个正在运行的可执行文件（不是任务）之间的（简单）形式的进程间通信？我假设这两个可执行文件都是用 Ada 编写的。

假设一个可执行程序定期从传感器读取数据a，而另一个可执行程序有兴趣定期处理这些值b。我认为包Ada.Streams.Stream_IO 可用于序列化传感器数据并将其写入文件，但我不确定如何同步写入（第一个可执行文件）和读取（第二个可执行文件）操作。编译指示Shared_Passive 可以用来解决这类问题吗？

【问题讨论】：

更新：使用 pragma Shared_Passive 的快速实验成功。您可能会对以下有关分布式系统的文章（“Ada Gems”）感兴趣：Gem #84、Gem #85、Gem #87 和 Gem #90。这些文章提供了一些与 Ada RM 的分布式系统附件（附件 E）相关的示例。 @Marcello90 请您通过以后可以接受的答案详细说明您的解决方案。这会将问题标记为已回答，并为其他开发人员提供一种比仅仅发表评论更简单的方法来解决他们自己的问题 @FrédéricPraca 当然。 ;) 【参考方案1】：

这是我自己的问题的解决方案。我发现这个Ada Gem #20 描述了编译指示Shared_Passive 的用法。 GNAT 参考手册提供了更多detailed information。

以下源代码演示了编写器和传感器程序之间随机生成的传感器数据的交换。

文件：memory.ads

package Memory is

   pragma Shared_Passive;

   type Sensor_Storage_Type is
      record
         Sequence_Numer : Natural := 0;
         Humidity       : Float   := 0.0;
      end record;

   protected Shared is
      function Read return Sensor_Storage_Type;

      procedure Write (Humidity : Float);
   private
      Current_Value : Sensor_Storage_Type;
   end Shared;

end Memory;

文件：memory.adb

package body Memory is

   protected body Shared is
      function Read return Sensor_Storage_Type is
      begin
         return Current_Value;
      end Read;

      procedure Write (Humidity : Float) is
      begin
         Current_Value.Sequence_Numer := Current_Value.Sequence_Numer + 1;

         Current_Value.Humidity := Humidity;
      end Write;
   end Shared;

end Memory;

文件：sensor_writer.adb

with Ada.Text_IO;
with Ada.Numerics.Float_Random;

with Memory;

procedure Sensor_Writer is
   Generator : Ada.Numerics.Float_Random.Generator;

   package Float_IO is new Ada.Text_IO.Float_IO (Num => Float);

   Random_Humidity : Float;
begin
   while True loop
      Random_Humidity := Ada.Numerics.Float_Random.Random (Generator) * 100.0;

      Memory.Shared.Write (Random_Humidity);

      Ada.Text_IO.Put ("Wrote sensor value: ");
      Float_IO.Put (Random_Humidity, Exp => 0);
      Ada.Text_IO.New_Line;

      delay 5.0;
   end loop;
end Sensor_Writer;

文件：sensor_reader.adb

with Ada.Text_IO;

with Memory;

procedure Sensor_Reader is
   Sensor_Value : Memory.Sensor_Storage_Type;
begin
   while True loop
      Sensor_Value := Memory.Shared.Read;

      Ada.Text_IO.Put_Line ("Read sensor values:");
      Ada.Text_IO.Put_Line ("    Sequence number: " & Sensor_Value.Sequence_Numer'Image);
      Ada.Text_IO.Put_Line ("    Humidity: " & Sensor_Value.Humidity'Image);

      delay 1.0;
   end loop;
end Sensor_Reader;

【讨论】：

【参考方案2】：

我认为附件 E 可以帮助您，更准确地说是 E.2.3 Remote Call Interface Library Units。

请记住，并非所有编译器都实现 Annexe 规范。 GNAT 可以，但是对于其他编译器，我不知道。

【讨论】：

【参考方案3】：

在进程之间进行 IPC 的另一种解决方案是使用良好的旧 POSIX IPC，例如在 @ 中实现的 信号量、共享内存和管道 987654321@（我在 Adacore 网站上没有找到 Florist，所以我想知道这是否仍在维护）。

优点：

让两个程序在没有网络堆栈的情况下相互通信程序可以使用不同的语言 POSIX 操作系统标准

缺点：

相当低级的编程需要使用信号量手动进行同步

Florist 中要查看的包是 POSIX.Generic_Shared_Memory、POSIX.IO 和 POSIX.Semaphores .