使用 XSLT 以字符串替换的形式对 HTML 文档应用编辑
Posted
技术标签:
【中文标题】使用 XSLT 以字符串替换的形式对 HTML 文档应用编辑【英文标题】：Applying redactions in the form of string substitutions to HTML documents using XSLT 【发布时间】：2020-07-03 19:24:27 【问题描述】： 【参考方案1】：第一个问题是找到一个真正支持字符串替换的 XSLT 处理器。 replace() 函数在 XSLT 2.0+ 中是标准的，但在 XSLT 1.0 中不存在。一些 XSLT 1.0 处理器在不同的命名空间中支持扩展函数 str:replace()，但至少，您需要将命名空间声明 xmlns:str="http://exslt.org/strings" 添加到样式表中才能找到该函数。我不知道这是否可行（我不知道是否有任何方法可以将此函数与 xsltproc 一起使用）；我的建议是改用 XSLT 2.0+ 处理器。
下一个问题是调用函数的方式。通常，正确的调用应该是
replace(., "John Doe", "[Person A]")
尽管您将不得不再跳几圈才能在同一个字符串上进行多次替换。
我不知道你想用<xsl:attribute name="matchesPattern"> 指令实现什么。
【讨论】：
【参考方案2】：xsltproc 基于 libxslt，支持各种 EXSLT 函数，如 str:replace，要使用它，您需要声明命名空间
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:str="http://exslt.org/strings"
exclude-result-prefixes="str"
version="1.0">
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="p//text()">
<xsl:value-of select="str:replace(., 'John Doe', '[Person A]')"/>
</xsl:template>
</xsl:stylesheet>
【讨论】：
libxslt 不支持str:replace。
我有xsltproc“针对libxml 20904、libxslt 10129和libexslt 817编译”，它支持str:replace，源代码github.com/GNOME/libxslt/blob/mainline/libexslt/strings.c#L597也表明它是支持的。因此，我不确定您的评论是否旨在区分 libxslt 和 libexslt，或者您是否在谈论旧版本中缺乏对 str:replace 的支持。
非常感谢。这是手头问题的解决方案。【参考方案3】：
在 XSLT 1.0 中没有简单的方法来对同一个字符串执行多个替换。您需要使用递归命名模板，一次执行一个替换操作，然后移至当前查找字符串的下一个实例，或者 - 当不存在下一个实例时 - 移至下一个查找/替换对。
考虑以下示例：
输入
<html>
<head>
<title>John Doe and Henry Fluebottom</title>
</head>
<body>
<p>John Doe is a person. John Doe on 9. fux 2057 together with Henry Fluebottom formed the company Doe & Fluebottom Widgets Inc. Henry Fluebottom is also a person.</p>
</body>
</html>
XSLT 1.0（+ EXSLT node-set() 函数）
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:variable name="dictionary">
<entry find="John Doe" replace="[Person A]"/>
<entry find="Henry Fluebottom" replace="[Person B]"/>
</xsl:variable>
<xsl:template match="text()">
<xsl:call-template name="multi-replace">
<xsl:with-param name="string" select="normalize-space(.)"/>
<xsl:with-param name="entries" select="exsl:node-set($dictionary)/entry"/>"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="multi-replace">
<xsl:param name="string"/>
<xsl:param name="entries"/>
<xsl:choose>
<xsl:when test="$entries">
<xsl:call-template name="multi-replace">
<xsl:with-param name="string">
<xsl:call-template name="replace">
<xsl:with-param name="string" select="$string"/>
<xsl:with-param name="search-string" select="$entries[1]/@find"/>
<xsl:with-param name="replace-string" select="$entries[1]/@replace"/>
</xsl:call-template>
</xsl:with-param>
<xsl:with-param name="entries" select="$entries[position() > 1]"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$string"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="replace">
<xsl:param name="string"/>
<xsl:param name="search-string"/>
<xsl:param name="replace-string"/>
<xsl:choose>
<xsl:when test="contains($string, $search-string)">
<xsl:value-of select="substring-before($string, $search-string)"/>
<xsl:value-of select="$replace-string"/>
<xsl:call-template name="replace">
<xsl:with-param name="string" select="substring-after($string, $search-string)"/>
<xsl:with-param name="search-string" select="$search-string"/>
<xsl:with-param name="replace-string" select="$replace-string"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$string"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
结果
<html>
<head>
<title>[Person A] and [Person B]</title>
</head>
<body>
<p>[Person A] is a person. [Person A] on 9. fux 2057 together with [Person B] formed the company Doe & Fluebottom Widgets Inc. [Person B] is also a person.</p>
</body>
</html>
如您所见，这将替换输入文档中任何位置的搜索字符串的所有实例（属性除外），同时保留文档的结构。
请注意，示例中的输入实际上并不包含 "Henry Fluebottom" 搜索字符串。你可能想通过调用第一个模板来解决这个问题：
<xsl:with-param name="string" select="normalize-space(.)"/>
代替：
<xsl:with-param name="string" select="."/>
【讨论】：
非常感谢。这是手头问题的解决方案。以上是关于使用 XSLT 以字符串替换的形式对 HTML 文档应用编辑的主要内容，如果未能解决你的问题，请参考以下文章