如何通过 EmbeddedWB.FillForm 设置复选框的值？ (德尔福)

Posted 2023-02-22

【中文标题】如何通过 EmbeddedWB.FillForm 设置复选框的值？ (德尔福)

【英文标题】：How to set value for checkbox via EmbeddedWB.FillForm ? (Delphi)

【发布时间】：2010-08-19 19:57:51

【问题描述】：

如何通过 FillForm 方法为复选框设置值？ 我尝试了这些但不起作用：

  W.FillForm('Chkname', 'True');
  W.FillForm('Chkname', '1');
  W.FillForm('Chkname', '', 1);

【问题讨论】：

你的FillForm来自哪里？我不记得这是标准的 Delphi 功能。它在哪个附加单元/库中？

嵌入式网页浏览器：bsalsa.com

【参考方案1】：

我知道已经很晚了，但我会尝试回答这个问题，因为这是一个很好的问题，而且即使是当前版本的 TEmbeddedWB 也没有实现此功能。

但是您可以添加自己的函数来执行此操作；在下面的示例中，我使用了 TEmbeddedWB 的插入类，其中我使用支持复选框和单选按钮填充的版本重载了 FillForm 函数。

如果你想设置复选框或选择一些单选按钮调用这个版本的函数，其中：

FieldName (string) - 是元素的名称 Value (string) - 元素的值（可以为空，但在这种情况下将设置 FieldName 的第一个元素；Web 开发人员应使用名称值对恕我直言） 选择（布尔） - 如果为 True，则选中复选框或选择单选按钮

代码如下：

uses
  EmbeddedWB, MShtml;

type
  TEmbeddedWB = class(EmbeddedWB.TEmbeddedWB)
  public
    function FillForm(const FieldName, Value: string;
      Select: Boolean): Boolean; overload;
  end;

implementation

function TEmbeddedWB.FillForm(const FieldName, Value: string;
  Select: Boolean): Boolean;
var
  I: Integer;
  Element: IHTMLElement;
  InputElement: IHTMLInputElement;
  ElementCollection: IHTMLElementCollection;
begin
  Result := False;
  ElementCollection := (Document as IHTMLDocument3).getElementsByName(FieldName);
  if Assigned(ElementCollection) then
    for I := 0 to ElementCollection.length - 1 do
    begin
      Element := ElementCollection.item(I, '') as IHTMLElement;
      if Assigned(Element) then
      begin
        if UpperCase(Element.tagName) = 'INPUT' then
        begin
          InputElement := (Element as IHTMLInputElement);
          if ((InputElement.type_ = 'checkbox') or (InputElement.type_ = 'radio')) and
            ((Value = '') or (InputElement.value = Value)) then
          begin
            Result := True;
            InputElement.checked := Select;
            Break;
          end;
        end;
      end;
    end;
end;

这里是一个基本的用法示例：

procedure TForm1.Button1Click(Sender: TObject);
var
  WebBrowser: TEmbeddedWB;
begin
  WebBrowser := TEmbeddedWB.Create(Self);
  WebBrowser.Parent := Self;
  WebBrowser.Align := alClient;
  WebBrowser.Navigate('http://www.w3schools.com/html/html_forms.asp');

  if WebBrowser.WaitWhileBusy(15000) then
  begin
    if not WebBrowser.FillForm('sex', 'male', True) then
      ShowMessage('Error while form filling occured...');
    if not WebBrowser.FillForm('vehicle', 'Bike', True) then
      ShowMessage('Error while form filling occured...');
    if not WebBrowser.FillForm('vehicle', 'Car', True) then
      ShowMessage('Error while form filling occured...');
  end;
end;

【讨论】：

这篇文章的主要观点是你不能按原样使用TEmbeddedWB.FillForm，因为它设置了元素的value属性你不应该做的事情，因为元素喜欢复选框和单选按钮具有用于在发送表单时构建名称值对的值。