ocaml，能够在值更改时触发编译错误

Posted 2023-02-19

【中文标题】ocaml，能够在值更改时触发编译错误

【英文标题】：ocaml, ability to trigger compile error on value change

【发布时间】：2022-01-08 04:29:25

【问题描述】：

我想以编译时的方式表示，我的代码是在某个值是某个常数的假设下运行的。为简单起见，假设我有这个模块

module Lib : sig
  type t = A|B|C|D
  val default : t
  val f : t option -> unit
end = struct
  type t = A|B|C|D
  let default = B
  let f _ = ()
end

我在Lib 之外编写代码，并希望以编译时的方式断言，我需要默认为B。这意味着当 Lib.default 与 B 不同时，我想要一个编译错误，在这种情况下，我想检查我的代码是否适合不同的值。这样我就不必阅读 lib 的发行说明，编译器会回电给我。

我对@9​​87654325@ 有一些控制权，所以如果需要我可以更改它。如果这样可以使编译时断言更容易，更不用说可能了，我对其他构造它的方式很感兴趣。

我还有其他不依赖于此的代码部分，例如

let config : Lib.t option =
  match Lib.default with
  | A
  | B
  | C -> None
  | D -> Some C

我在考虑做子类型，比如在

type t = [`A|`B|`C|`D]
val default : [`B]

但随后我删除了default 可能更改为t 的其他构造函数的信息，然后这将编译错误，指出不可能匹配A。

let config : Lib.t option =
  match Lib.default with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

谢谢

【参考方案1】：

子类型可能是一个解决方案，尽管我不得不承认我没有完全理解你想要什么。但稍后，让我们首先介绍多态变体和子类型。您的尝试尚未使用子类型，因为您的类型中没有多态性，即 type t = ['A|'B|'C|'D]¹ 是基本类型。我们需要的是以下，

module Lib : sig
  type 'a t = [< `A|`B|`C|`D] as 'a
  val default : [ `B] t
  val f : 'a t option -> unit
end = struct
  type 'a t = [< `A|`B|`C|`D] as 'a
  let default = `B
  let f _ = ()
end

所以我们说'a Lib.t 是一个类型族，'a t 类型的值可以是['A] 或'B 或['A|'B] 或['A|'B|'C] 或...与[A|B|C|D]是***类型，也就是超类型。

使用default 类型我们有选项，我们可以发布它的类型为['B] t，这与['B] 相同，但更清楚地表明它是层次结构的一部分，所以用户应该期望它更改为任何其他类型。从类型系统的角度来看，这并不重要，因为 OCaml 类型系统不是名义上的，而是结构上的。

这个解决方案会在这里给你一个类型错误，

let config : _ Lib.t option =
  match Lib.default with
  | `A  (* default is not polymorphic and can be only `B *)
  | `B
  | `C -> None
  | `D -> Some `C

因为我们明确指出default 是 B，并且只有 B。

另外，我们可以说default 可以是[> 'B]，也就是说，它是一种多态类型，至少是 B，但也可以是其他任何类型。使用此解决方案，您将不会在 config 函数中遇到任何错误。例如，如果您从 [> 'B] 更改为 [> 'A]，您也不会收到任何错误。所以它可能不是你要找的，所以让我们返回并使用单态['B] 类型作为默认值，并尝试在用户端处理它。我们可以明确地说，我们希望将地面默认值向上转换为所有可能的值，例如，

module Lib : sig
  type 'a t = [< `A|`B|`C|`D] as 'a
  val default : [`B] t
  val f : 'a t option -> unit
end = struct
  type 'a t = [< `A|`B|`C|`D] as 'a
  let default = `B
  let f _ = ()
end

let config : _ Lib.t option =
  match (Lib.default : [`B] Lib.t :> [> `B] Lib.t) with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

现在，如果我们将默认值更改为 A，我们将得到所需的类型错误。唯一需要注意的是，我们需要在每个用例中指定当前验证的默认值，所以让我们将其移至 Lib，例如，

module Lib : sig
  type 'a t = [< `A|`B|`C|`D] as 'a
  type verified = [`B]
  val default : [`B] t
  val f : 'a t option -> unit
end = struct
  type 'a t = [< `A|`B|`C|`D] as 'a
  type verified = [`B] t
  let default = `B
  let f _ = ()
end

open Lib
let config : _ Lib.t option =
  match (default : verified t :> [> verified ] t) with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

所以现在，当您想尝试一个新的默认值时，您可以更改默认值的类型（当然还有值），但不要更改 verified 类型并遍历所有用例，直到您准备将新添加的类型添加到验证集。是的，设置，因为我们可以升级验证类型以接受一组变体，例如，

module Lib : sig
  type 'a t = [< `A|`B|`C|`D] as 'a
  type verified = [`A |`B]
  val default : [`B] t
  val f : 'a t option -> unit
end = struct
  type 'a t = [< `A|`B|`C|`D] as 'a
  type verified = [`A|`B] t
  let default = `B
  let f _ = ()
end

open Lib
let config : _ Lib.t option =
  match (default : [< verified] t :> [> verified ] t) with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

所以现在，如果Lib.default 有除 A 或 B 之外的任何变体，我们将收到错误消息。另外，您无需在使用站点上进行任何更改。

作为最后的改进，我建议摆脱名义（在所有意义上的）'a t 类型，只需要多态类型，一个用于经过验证的构造函数集，另一个用于所有可能的构造函数，例如，

module Lib : sig
  type 'a default = [> `A|`B|`C|`D] as 'a
  type 'a verified = [< `A |`B] as 'a
  val default : [`B]
  val f : 'a default option -> unit
end = struct
  type 'a default = [> `A|`B|`C|`D] as 'a
  type 'a verified = [< `A|`B] as 'a
  let default = `B
  let f _ = ()
end

open Lib
let config : _ option =
  match (default : _ verified :> _ default) with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

或

let config : 'b option =
  match (default : 'a verified :> 'b default) with
  | `A
  | `B
  | `C -> None
  | `D -> Some `C

---

¹⁾) 请原谅我错误的反引号，正确的反引号不适合 SO 标记

【讨论】：

哇，谢谢@ivg，这真是一本好书。动机是1。当我没有直接开发（而不是阅读提交/发行说明）的库中的（默认）值发生更改时，添加/提醒编译错误，加上 2. 还能够表达我当前的 partial i> 当该值更改为不同的值时，了解所需的行为。

(1) 很有用，因为它是生产中潜在行为变化的先兆