运行vb代码计算相似度时定义首字母缩写词

Posted 2023-05-08

【中文标题】运行vb代码计算相似度时定义首字母缩写词

【英文标题】：Define acronyms when running vb code calculating similarity

【发布时间】：2017-07-04 14:36:24

【问题描述】：

我在 excel 中使用以下 vb 代码来计算 A 列和 B 列之间的相似度。它运行得很好。

对我来说，下一步是定义首字母缩略词，这样计算的相似度就不会受到影响。 IE：如果我在 A 列“ABC LLC”和 B 列“ABC 有限责任公司”中有，当前的 vb 代码将返回两列不太相似。但是，我希望他们通过定义“有限责任公司”和“有限责任公司”实际上是同一件事来返回 100% 相似。我能做什么，我可以把它放在代码中的什么地方来完成这个？谢谢！

免责声明 - 是的，我知道有插件可以做到这一点。但是，我的数据集太大而无法使用它们。

Public Function Similarity(ByVal String1 As String, _
                           ByVal String2 As String, _
                           Optional ByRef RetMatch As String, _
                           Optional min_match = 1) As Single

'Returns percentile of similarity between 2 strings (ignores case)

'"RetMatch"  returns the characters that match(in order)
'"min_match" specifies minimum number af char's in a row to match


Dim b1() As Byte, b2() As Byte
Dim lngLen1 As Long, lngLen2 As Long
Dim lngResult As Long

  If UCase(String1) = UCase(String2) Then       '..Exactly the same
    Similarity = 1

  Else                                          '..one string is empty
    lngLen1 = Len(String1)
    lngLen2 = Len(String2)
    If (lngLen1 = 0) Or (lngLen2 = 0) Then
      Similarity = 0

    Else                                        '..otherwise find similarity
      b1() = StrConv(UCase(String1), vbFromUnicode)
      b2() = StrConv(UCase(String2), vbFromUnicode)
      lngResult = Similarity_sub(0, lngLen1 - 1, _
                                 0, lngLen2 - 1, _
                                 b1, b2, _
                                 String1, _
                                 RetMatch, _
                                 min_match)
      Erase b1
      Erase b2
      If lngLen1 >= lngLen2 Then
        Similarity = lngResult / lngLen1
      Else
        Similarity = lngResult / lngLen2
      End If
    End If
  End If

End Function

Private Function Similarity_sub(ByVal start1 As Long, ByVal end1 As Long, _
                                ByVal start2 As Long, ByVal end2 As Long, _
                                ByRef b1() As Byte, ByRef b2() As Byte, _
                                ByVal FirstString As String, _
                                ByRef RetMatch As String, _
                                ByVal min_match As Long, _
                                Optional recur_level As Integer = 0) As Long
'* CALLED BY: Similarity *  (RECURSIVE)

Dim lngCurr1 As Long, lngCurr2 As Long
Dim lngMatchAt1 As Long, lngMatchAt2 As Long
Dim i As Long
Dim lngLongestMatch As Long, lngLocalLongestMatch As Long
Dim strRetMatch1 As String, strRetMatch2 As String

  If (start1 > end1) Or (start1 < 0) Or (end1 - start1 + 1 < min_match) _
  Or (start2 > end2) Or (start2 < 0) Or (end2 - start2 + 1 < min_match) Then
    Exit Function     '(exit if start/end is out of string, or length is too short)
  End If

  For lngCurr1 = start1 To end1        '(for each char of first string)
    For lngCurr2 = start2 To end2        '(for each char of second string)
      i = 0
      Do Until b1(lngCurr1 + i) <> b2(lngCurr2 + i)   'as long as chars DO match..
        i = i + 1
        If i > lngLongestMatch Then     '..if longer than previous best, store starts & length
          lngMatchAt1 = lngCurr1
          lngMatchAt2 = lngCurr2
          lngLongestMatch = i
        End If
        If (lngCurr1 + i) > end1 Or (lngCurr2 + i) > end2 Then Exit Do
      Loop
    Next lngCurr2
  Next lngCurr1

  If lngLongestMatch < min_match Then Exit Function 'no matches at all, so no point checking for sub-matches!

  lngLocalLongestMatch = lngLongestMatch                   'call again for BEFORE + AFTER
  RetMatch = ""
                              'Find longest match BEFORE the current position
  lngLongestMatch = lngLongestMatch _
                  + Similarity_sub(start1, lngMatchAt1 - 1, _
                                   start2, lngMatchAt2 - 1, _
                                   b1, b2, _
                                   FirstString, _
                                   strRetMatch1, _
                                   min_match, _
                                   recur_level + 1)
  If strRetMatch1 <> "" Then
    RetMatch = RetMatch & strRetMatch1 & "*"
  Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
                              And lngLocalLongestMatch > 0 _
                              And (lngMatchAt1 > 1 Or lngMatchAt2 > 1) _
                              , "*", "")
  End If

                              'add local longest
  RetMatch = RetMatch & Mid$(FirstString, lngMatchAt1 + 1, lngLocalLongestMatch)

                              'Find longest match AFTER the current position
  lngLongestMatch = lngLongestMatch _
                  + Similarity_sub(lngMatchAt1 + lngLocalLongestMatch, end1, _
                                   lngMatchAt2 + lngLocalLongestMatch, end2, _
                                   b1, b2, _
                                   FirstString, _
                                   strRetMatch2, _
                                   min_match, _
                                   recur_level + 1)

  If strRetMatch2 <> "" Then
    RetMatch = RetMatch & "*" & strRetMatch2
  Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
                              And lngLocalLongestMatch > 0 _
                              And ((lngMatchAt1 + lngLocalLongestMatch < end1) _
                                   Or (lngMatchAt2 + lngLocalLongestMatch < end2)) _
                              , "*", "")
  End If
                             'Return result
  Similarity_sub = lngLongestMatch

End Function

【问题讨论】：

如果您可以使用首字母缩写词及其定义创建一个数组（可能在另一张表中？），您可以使用检查值是否引用表中的索引/匹配项。这可能是 Select Case 的一部分，其中第一个 Case 是您的典型检查，第二个 Case 是此索引/匹配检查，而您的第三个 Case 将是“不相似”。只是一个想法。

【参考方案1】：

无需过多参与您的解决方案，这是您自己的责任，我可以建议一些方法来合并这些缩写。然而。 请注意，此方法不能保证 100% 成功，但您已经处于模糊世界中。

假设我们有一个Dictionary，其中：

关键是长短语 这些值是缩写

在比较两个字符串之前，我们将它们最小化，将每个出现的长短语替换为其缩写。然后我们可以将它们与您的其他方法Similarity（或任何其他方法）进行比较。

' Fills an abbreviation dictionary
Sub InitializeDict(ByRef abbrev As Scripting.Dictionary)
    abbrev("limited liability company") = "LLC"
    abbrev("United Kingdom") = "U.K."
    '... Add all abbreviations into dict

    ' Instead of harcoding, you can better load the key/value
    ' pairs from a dedicated worksheet... 

End Sub

' Minimizes s by putting abbreviations
Sub Abbreviate(ByRef s As String)
    Static abbrev As Scripting.Dictionary ' <-- static, inititlized only once
    If abbrev Is Nothing Then
        Set abbrev = CreateObject("Scripting.Dictionary")
        abbrev.CompareMode = vbTextCompare
        InitializeDict abbrev
    End If

    Dim phrase
    For Each phrase In abbrev.Keys
        s = Replace(s, phrase, abbrev(phrase), vbTextCompare)
    Next
End Sub

' A small amendment to this function: abbreviate strings before comparing
Public Function Similarity(ByVal String1 As String, _
                       ByVal String2 As String, _
                       Optional ByRef RetMatch As String, _
                       Optional min_match = 1) As Single

    Abbreviate String1
    Abbreviate String2
    ' ... Rest of the routine
End Function

【讨论】：

想我明白了 - 非常感谢！

@jonv 欢迎，如果实施这个想法（这实际上是你的，我只是建议一个技术实施）显着改善了你的相似性检查器，请让我们更新。我很感兴趣;)

【参考方案2】：

检查字符串是否为Like 可能更容易。例如

If "ABC limited liability company" Like "ABC L*L*C*" Then

为真，因为* 匹配任何 0 个或多个字符。

Option Compare Text    ' makes string comparisons case insensitive

Function areLike(str1 As String, str2 As String) As Single

    If str1 = str2 Then areLike = 1: Exit Function

    Dim pattern As String, temp As String

    If LenB(str1) < LenB(str2) Then 
        pattern = str1
        temp = str2
    Else
        pattern = str2
        temp = str1
    End If

    pattern = StrConv(pattern, vbUnicode)       ' "ABC LLC" to "A␀B␀C␀ ␀L␀L␀C␀"   
    pattern = Replace(pattern, vbNullChar, "*") ' "A*B*C* *L*L*C*"
    pattern = Replace(pattern, " *", " ")       ' "A*B*C* L*L*C*"

    If temp Like pattern Then areLike = 1: Exit Function

    ' else areLike = some other similarity function

End Function