具有 haskell GLUT 绑定的透明度/Alpha

Posted 2023-02-16

【中文标题】具有 haskell GLUT 绑定的透明度/Alpha

【英文标题】：Transparency/Alpha with haskell GLUT bindings

【发布时间】：2017-11-11 23:59:44

【问题描述】：

使用Haskell GLUT binding，我通过两种方式修改了Hello World example：

已将WithAlphaComponent 添加到initialDisplayMode。 将颜色更改为 Color4 和 0.5 不透明度。

我希望它显示一个半透明的白色方块，背景为红色。相反，它显示一个纯白色方块，好像不透明度被忽略了。我不明白为什么这不起作用？

import Graphics.UI.GLUT

display :: DisplayCallback
display = do
   -- clear all pixels
   clear [ ColorBuffer ]

   -- draw white polygon (rectangle) with corners at
   -- (0.25, 0.25, 0.0) and (0.75, 0.75, 0.0)

   -- CHANGE #2
   color (Color4 1.0 1.0 (1.0 :: GLfloat) 0.5)

   -- resolve overloading, not needed in "real" programs
   let vertex3f = vertex :: Vertex3 GLfloat -> IO ()
   renderPrimitive Polygon $ mapM_ vertex3f [
      Vertex3 0.25 0.25 0.0,
      Vertex3 0.75 0.25 0.0,
      Vertex3 0.75 0.75 0.0,
      Vertex3 0.25 0.75 0.0]

   -- don't wait!
   -- start processing buffered OpenGL routines
   flush

myInit :: IO ()
myInit = do
   -- select clearing color
   clearColor $= Color4 0.7 0 0 0

   -- initialize viewing values
   matrixMode $= Projection
   loadIdentity
   ortho 0 1 0 1 (-1) 1

-- Declare initial window size, position, and display mode (single buffer and
-- RGBA). Open window with "hello" in its title bar. Call initialization
-- routines. Register callback function to display graphics. Enter main loop and
-- process events.
main :: IO ()
main = do
   _ <- getArgsAndInitialize
   -- CHANGE #1
   initialDisplayMode $= [ SingleBuffered, RGBMode, WithAlphaComponent ]
   initialWindowSize $= Size 250 250
   initialWindowPosition $= Position 100 100
   _ <- createWindow "hello"
   myInit
   displayCallback $= display
   mainLoop

【问题讨论】：

您可能需要启用 Alpha 混合。在 C 中，这是通过 glEnable(GL_BLEND) 完成的。不确定，你如何在 Haskell 中做到这一点。

【参考方案1】：

取自 Alpha.hs 示例。

-- Initialize alpha blending function.
myInit :: IO ()
myInit = do
   blend $= Enabled
   blendFunc $= (SrcAlpha, OneMinusSrcAlpha)
   shadeModel $= Flat
   clearColor $= Color4 0 0 0 0