ORA-00984: 此处不允许列 - 动态 SQL

Posted 2023-03-28

【中文标题】ORA-00984: 此处不允许列 - 动态 SQL

【英文标题】：ORA-00984: column not allowed here - Dynamic SQL

【发布时间】：2015-02-12 08:21:37

【问题描述】：

这是我的包裹代码。

CREATE OR REPLACE PACKAGE BODY FMSSMART.GENERIC_PURGER
AS

   PROCEDURE GET_PARTITIONID_JULIAN (i_date                   IN     DATE,
                              i_number_of_partitions   IN     NUMBER,
                              o_partitionID               OUT NUMBER)
   IS
   BEGIN
      SELECT MOD (TO_NUMBER (TO_CHAR (TO_DATE (i_date, 'YYYYMMDD'), 'j')),
                  i_number_of_partitions)
        INTO o_partitionID
        FROM DUAL;

      DBMS_OUTPUT.put_line (o_partitionID);
   END GET_PARTITIONID_JULIAN;

 PROCEDURE DELETE_TBL_SML
    (
      i_tablename IN VARCHAR2,
      o_retcode OUT NUMBER,
      o_errormsg OUT VARCHAR2
    )
     IS

    stmt VARCHAR2(1000);
    o_start_time DATE;
    o_end_time DATE;

    BEGIN
      select to_char(sysdate, 'YYYYMMDDHH24MISS') into o_start_time from dual;
      stmt := 'DELETE FROM ' ||i_tablename;
      EXECUTE IMMEDIATE stmt;
      COMMIT;
      select to_char(sysdate, 'YYYYMMDDHH24MISS') into o_end_time from dual;

    EXCEPTION WHEN OTHERS THEN
    o_retcode := SQLCODE;
    o_errormsg := substr(SQLERRM, 1, 200);


    INSERT INTO AUDIT_PROC_TBL (error_number, error_message, package_name, procedure_name, start_time, end_time) VALUES (o_retcode, o_errormsg, 'GENERIC_PURGER','DELETE_TBL_SML', o_start_time, o_end_time);
    return;
    END DELETE_TBL_SML;

 PROCEDURE INSERT_AUDIT_PROC_TBL
 (
      i_retcode IN NUMBER,
      i_errormsg IN VARCHAR2,
      i_package_name IN  VARCHAR2,
      i_procedure_name IN VARCHAR2,
      i_start_time IN DATE,
      i_end_time IN DATE
 )
   IS
    BEGIN
          EXECUTE IMMEDIATE  'INSERT INTO AUDIT_PROC_TBL (error_number, error_message, package_name, procedure_name, start_time, end_time) VALUES (i_retcode, i_errormsg, i_package_name,  i_procedure_name,i_start_time,  i_end_time)';
          COMMIT;
          RETURN;
   END INSERT_AUDIT_PROC_TBL;

END GENERIC_PURGER;
/

执行时：

set autocommit off;
set serveroutput on size 1000000;
ALTER SESSION SET NLS_DATE_FORMAT='YYYYMMDD HH24:MI:SS';
EXECUTE INSERT_AUDIT_PROC_TBL(-1, 'NA', 'GENERIC_PURGER','DELETE_TBL_SML', '20150212164527', '20150212164527');

我遇到了一个错误：

Session altered.

BEGIN INSERT_AUDIT_PROC_TBL(-1, 'NA', 'GENERIC_PURGER','DELETE_TBL_SML', '20150212164527', '20150212164527'); END;

*
ERROR at line 1:
ORA-00984: column not allowed here
ORA-06512: at "FMSSMART.INSERT_AUDIT_PROC_TBL", line 12
ORA-06512: at line 1

【问题讨论】：

为什么要使用动态 SQL 进行审计插入？

我使用动态 SQL 进行审计插入，因为它不仅限于遇到错误。

【参考方案1】：

你得到的错误不是你调用过程的方式，而是过程在做什么。针对FMSSMART.INSERT_AUDIT_PROC_TBL过程的第12行报告了ORA-00984错误，即：

EXECUTE IMMEDIATE  'INSERT INTO AUDIT_PROC_TBL (error_number, error_message, package_name, procedure_name, start_time, end_time) VALUES (i_retcode, i_errormsg, i_package_name,  i_procedure_name,i_start_time,  i_end_time)';

您在不需要时使用动态 SQL；没有什么动态和静态的 SQL 就可以了：

INSERT INTO AUDIT_PROC_TBL (error_number, error_message, package_name,
  procedure_name, start_time, end_time)
VALUES (i_retcode, i_errormsg, i_package_name,  
  i_procedure_name,i_start_time,  i_end_time);

不过，为了将来参考，当您使用动态 SQL 时，您需要对传入的值使用绑定变量；您在动态 SQL 语句中有一个由冒号表示的绑定占位符，例如:var1，然后使用 using 子句提供实际值。目前，在您的原始版本中，i_retcode 被解释为列名，而不是您的变量，这超出了动态上下文的范围。所以你会使用类似的东西：

EXECUTE IMMEDIATE  'INSERT INTO AUDIT_PROC_TBL (error_number, '
  || 'error_message, package_name, procedure_name, start_time, end_time) '
  || 'VALUES (:retcode, :errormsg, :package_name,  :procedure_name, '
  || ':start_time,  :end_time)'
USING i_retcode, i_errormsg, i_package_name,  i_procedure_name,
  i_start_time,  i_end_time;

为了便于阅读，我将语句拆分为多行；通过|| 的连接意味着最终的字符串与都在一行中一样。

---

我还有一些超出问题范围的其他意见：

您在会话中设置 NLS_DATE_FORMAT，然后依赖隐式转换；奇怪地使用与您的字符串不匹配的格式。最好在您的通话中明确传递日期值，例如to_date('20150212164527', 'YYYYMMDDHH24MISS') 或 timestamp 文字。 在您的DELETE_TBL_SML 包中更糟，因为您仍然依赖会话 NLS 设置，您不会总是控制它，并且您将日期显式转换为字符串只是为了隐式地将它们转换回来。而不是select to_char(sysdate, 'YYYYMMDDHH24MISS') into o_start_time from dual; 只是o_start_time := sysdate)。 在过程中提交或回滚通常被认为是不好的做法；最好由调用者决定是否提交以及何时提交，因为它可能正在做您的程序不知道的其他事情，应将其视为同一事务的一部分。 捕获您不处理的异常，尤其是when others，通常是一个错误。尽管您在这里将代码和消息返回给调用者，但他们必须查找它。让异常传播回调用者几乎总是更好 - 这也可以反馈到提交/回滚决策中。

删除过程可以简化为：

PROCEDURE DELETE_TBL_SML(i_tablename IN VARCHAR2) IS
  o_start_time DATE;
  o_end_time DATE;
BEGIN
  o_start_time := sysdate;
  EXECUTE IMMEDIATE 'DELETE FROM ' ||i_tablename;
  o_end_time := sysdate;

  INSERT INTO AUDIT_PROC_TBL (error_number, error_message, package_name,
    procedure_name, start_time, end_time)
  VALUES (SQLERRCODE, substr(SQLERRM, 1, 200), 'GENERIC_PURGER',
    'DELETE_TBL_SML', o_start_time, o_end_time);
END DELETE_TBL_SML;

除非您只想审核错误，在这种情况下，您需要将执行包含在其自己的子块中；然后将其称为exec FMSSMART.GENERIC_PURGER.DELETE_TBL_SML(<your table name>)。

【讨论】：

嗨，Alex，非常感谢，您解决了我的问题。我也是这个pl/sql的初学者，现在，我可以执行这个sql并且成功了。更改会话集 NLS_DATE_FORMAT='YYYYMMDD HH24:MI:SS';执行 INSERT_AUDIT_PROC_TBL(-1, 'NA', 'GENERIC_PURGER', 'DELETE_TBL_SML', '20150212174829', '20150212174829');

嗨，Alex，你能帮我解决一下我在 DELETE_TBL_SML 中的代码吗，我在使用这个包时遇到了问题。谢谢

@LelanCalusay - 您应该针对新问题提出新问题。我可以看到一些可能没有按您希望的方式运行的事情，但您需要展示您如何调用它以及您得到什么输出/错误，这值得自己提出问题。

好的，我采纳了你的建议，它给了我一个很好的结果，而无需使用 NLS_DATE_FORMAT.. set autocommit off;执行 INSERT_AUDIT_PROC_TBL(-1, 'NA', 'GENERIC_PURGER', 'DELETE_TBL_SML', to_date('20150212183731', 'YYYYMMDDHH24MISS'), to_date('20150212183732', 'YYYYMMDDHH24MISS'));

看来，我还要等2天再问一个问题。也许我应该在这里粘贴我的代码