PL/SQL 逗号分隔列表；删除重复并放入数组

Posted 2023-03-27

【中文标题】PL/SQL 逗号分隔列表；删除重复并放入数组

【英文标题】：PL/SQL comma delimited list; remove dups and put in array

【发布时间】：2017-02-21 20:19:04

【问题描述】：

我在 PL/SQL 过程中有一个逗号分隔列表作为字符串。我需要

删除重复项 将列表放入数组中。

我已经找到了多种方法来做到这一点，但不是两者兼而有之。 有什么帮助吗？

【问题讨论】：

如果每个部分你都知道怎么做，为什么把它们组合在一起是个问题？

至少试一试并发布您尝试过的内容。

问题是删除重复项的方法似乎有点不可靠。在运行示例时，有些示例根本不起作用，给出错误的集合或留下逗号。 （我想我可以消除它。）他们中的大多数使用一种或另一种形式的数组从列表到数组，但是这些数组类型不利于重复删除技术。谢谢！

【参考方案1】：

有一个众所周知的 SQL 技巧可以将逗号分隔的列表转换为行。只需使用这个技巧，添加一个DISTINCT 关键字，然后将BULK COLLECT 结果添加到您的数组中（我假设您的意思是集合）。

DECLARE
  p_test_string   VARCHAR2 (4000) := 'A,B,C,B,B,D';

  TYPE string_array_type IS TABLE OF VARCHAR2 (4000);

  l_array         string_array_type;
BEGIN
  SELECT DISTINCT REGEXP_SUBSTR (p_test_string,
                        '[^,]+',
                        1,
                        LEVEL)
  BULK   COLLECT INTO l_array
  FROM   DUAL
  CONNECT BY REGEXP_SUBSTR (p_test_string,
                            '[^,]+',
                            1,
                            LEVEL)
               IS NOT NULL
  ORDER BY 1;

  DBMS_OUTPUT.put_line ('l_array.count = ' || l_array.COUNT);
  DBMS_OUTPUT.put_line ('l_array(2) = ' || l_array (2));
END;

输出：

l_array.count = 4
l_array(2) = B

【讨论】：

非常感谢！工作！不要抱怨（好吧）一些比我了解更多的人应该创建一个好的字符串包，其中包含重复删除等内容。

如果你想把它变成一个库，以供广泛使用，你应该实现 MT0 的解决方案（我会赞成）。他说得对，纯 PL/SQL 方法会快得多（可能快 20-30 倍）。如果您只调用几次，我会喜欢我发布的方法，因为它很简单。如果您将其调用一百万次，或者将其放入库中，我会支持 MT0 的解决方案。

【参考方案2】：

split a delimited string 有多种方法。其中之一是使用简单的 PL/SQL 函数：

CREATE TYPE string_list IS TABLE OF VARCHAR2(4000);
/

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN STRING_LIST DETERMINISTIC
AS
  p_result       STRING_LIST := STRING_LIST();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

这是一个使用简单字符串函数的纯 PL/SQL 函数（而不是使用更昂贵的正则表达式和上下文切换到 SQL 范围）。

还有一个非常简单的内置函数 SET( collection_value ) 用于从集合中删除重复项：

SET( STRING_LIST( 'A', 'B', 'A', 'C', 'B' ) )

会赠送收藏：

STRING_LIST( 'A', 'B', 'C' )

因此，如果您想拆分分隔字符串并对其进行重复数据删除，那么您可以这样做：

SET( split_String( 'A,B,C,A,B,D,C,E' ) )

这会给你：

STRING_LIST( 'A', 'B', 'C', 'D', 'E' )