Oracle在所有表的所有列中搜索字符串[重复]

Posted 2023-03-15

【中文标题】Oracle在所有表的所有列中搜索字符串[重复]

【英文标题】：Oracle Search all tables all columns for string [duplicate]

【发布时间】：2011-09-17 09:28:24

【问题描述】：

我需要在我们的 oracle 数据库中搜索所有表和列中的字符串。我在网上找到了以下查询，但是当我执行它时出现以下错误

感谢任何帮助

ORA-06550: line 6, column 31:
PL/SQL: ORA-00904: "COLUMN_NAME": invalid identifier
ORA-06550: line 6, column 12:
PL/SQL: SQL Statement ignored
ORA-06550: line 8, column 30:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 7, column 4:
PL/SQL: Statement ignored
ORA-06550: line 12, column 38:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 12, column 16:
PL/SQL: Statement ignored

BEGIN  
  FOR t IN (SELECT table_name, column_name FROM all_tables) LOOP   
   EXECUTE IMMEDIATE    
    'SELECT COUNT(*) FROM '||t.table_name||' WHERE '||t.column_name||' = :1'   
     INTO match_count  
       USING v_search_string; 
          IF match_count > 0 THEN 
               dbms_output.put_line( t.table_name ||' '||t.column_name||' '||match_count );
           END IF; 
  END LOOP;
END;
/

【问题讨论】：

为什么不使用某种方式的 grep 来搜索数据库文件？至少你可以得到文件/块的偏移量，然后去找到有问题的表。

【参考方案1】：

至少，您需要查询 ALL_TAB_COLUMNS，而不是 ALL_TABLES

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

但是，如果您要查找字符串，您几乎肯定会希望限制自己查找可以存储字符串的列。例如，在 DATE 列中搜索字符串是没有意义的。除非您对 BLOB 列包含的内容和解析 BLOB 列的二进制格式有大量先验知识，否则在 BLOB 列中搜索字符串是没有意义的。鉴于此，我怀疑你想要更多类似的东西

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

当然，这会非常慢——你会为表中的每个字符串列对每个表进行一次完整扫描。对于中等大小的表和中等数量的字符串列，这可能需要相当长的时间。

【讨论】：

那行得通，通过查询它给了我以下 ORA-00942 错误：表或​​视图不存在 ORA-06512：在第 12 行我怎样才能让它恢复或忽略此错误

@Jim - 我在第二个解决方案中添加了一个异常处理程序。我还添加了架构所有者限定符，以防您可以访问架构之外的表。

我必须声明 v_search_string 和 match_count，并在隐式游标的 SELECT 中添加所有者字段才能完成这项工作。这是真正的宝石 +1。

@Blanthor - 好点。我添加了局部变量声明并修复了查询。谢谢！

这可能是个愚蠢的问题，但是这个搜索查询是否区分大小写搜索？