如何使用具有两个不同类但其中一个来自 VCL 的泛型

Posted 2023-02-16

【中文标题】如何使用具有两个不同类但其中一个来自 VCL 的泛型

【英文标题】：How to use a generic with two different classes but one of them from the VCL

【发布时间】：2018-11-24 23:22:14

【问题描述】：

我正在维护和扩展一个使用 8 位位图的旧版应用程序，但出于多种原因，我从头开始创建自己的位图类 (TMyBitmap)，实现了一些明显的功能，例如 Width、Height 和 ScanLine 属性。请注意，TBitmap 和 TMyBitmap 之间没有关系（TMyBitmap 不继承自 TBitmap）。

现在我想做一个实用类，它有几种方法可以使用标准 TBitmap 或我自己的 TMyBitmap。这些方法的实现对于 TBitmap 或 TMyBitmap 是相同的，因为它们只使用“通用”属性（Width、Height 和 ScanLine），因此泛型看起来是一个合适的解决方案：

TBmpUtility<T> = class
strict private
  FBmp: T;
public
  constructor Create(Bmp: T);
  procedure Fill(Y: Integer; Code: Byte); //example of an utility method
end;

procedure TBmpUtility<T>.Fill(Y: Integer; Code: Byte);
var
  i: Integer;
  Line: PByteArray;
begin
  Line := Self.FBmp.ScanLine[Y];
  for i := 0 to Self.FBmp.Width - 1 do
    Line[i] := Code;
end;

这里明显的问题是我不能真正调用Self.FBmp.ScanLine[Y] 和Self.FBmp.Width，因为此时编译器对 TBitmap 或 TMyBitmap 一无所知。然后我声明了一个接口并在 TMyBitmap 上实现：

  IBitmap  = interface
  ['029D42A0-132F-4C6E-BE72-648E1361C0A4']
    function GetWidth: Integer;
    procedure SetWidth(Value: Integer);
    function GetHeight: Integer;
    procedure SetHeight(Value: Integer);
    function GetScanLine(Y: Integer): Pointer;
    property Width: Integer read GetWidth write SetWidth;
    property Height: Integer read GetHeight write SetHeight;
    property ScanLine[Y: Integer]: Pointer read GetScanLine;
  end;

  TMyBitmap = class (TSinglentonImplementation, IBitmap)
  ...
  end;

然后我可以在泛型声明上添加类型约束，以便能够从实用方法实现中通过Self.FBmp 调用这些方法。

TBmpUtility<T: IBitmap> = class

这里的问题是：标准的 TBitmap 没有实现我的 IBitmap 接口。所以我不能使用带有标准位图的实用程序类，如下所示：

Bmp := TBitmap.Create();
BmpUtil := TBmpUtility<TBitmap>.Create(Bmp);

我可以这样做：

TCustomBitmap = class (TBitmap, IBitmap)
...
end;

但是项目代码到处都在使用 TBitmap，而不是 TCustomBitmap，所以我不能互换这些类型，所以这不是一个选项。

我尝试了一个辅助类。像这样的：

TBitmapHelper = class (IBitmap) helper for TBitmap
...
end;

但显然，它不起作用

知道如何解决这种情况吗？ 记住一开始的目标：只有一个实现代码块用于处理 TBitmap 和 TMyBitmap 的实用程序方法。如果泛型是正确的解决方案，它应该如下所示：

Bmp := TBitmap.Create();
BmpUtil := TBmpUtility<TBitmap>.Create(Bmp);
BmpUtil.Fill(10, 0);
//or
MyBmp := TMyBitmap.Create();
BmpUtil := TBmpUtility<TMyBitmap>.Create(MyBmp);
BmpUtil.Fill(10, 0);

（仅供参考：我使用的是 Delphi 10.2.3 [东京]）

【问题讨论】：

我不认为泛型在这里有用。您需要通过将调用转发到 TBitmap 实例来创建一个实现接口的适配器类。

相关：Invoke method on generic type?

【参考方案1】：

正如 David 所建议的，您可以创建一个适配器类。此类可以实现您的接口并（在大多数情况下）作为对实际位图类的简单传递。用于 TBitmap 的可能如下所示（为简洁起见，省略了一些方法）：

type
  TBitmapAdapter = class(TInterfacedObject, IBitmap)
  private
    FBitmap: TBitmap;
    function GetWidth: Integer;
    procedure SetWidth(Value: Integer);
    // And everything else from IBitmap
  public
    constructor Create(ABitmap: TBitmap);
  end;

function TBitmapAdapter.GetWidth: Integer;
begin
  Result := FBitmap.Width;
end;

procedure TBitmapAdapter.SetWidth(Value: Integer);
begin
  FBitmap.Width := Value;
end;

您可以创建一个类来处理这两种类型，但这需要在每个方法中使用 if。我会创建两个单独的类，因此您可以简单地创建一个 TBitmapAdapter 或 TMyBitmapAdapter。

您可以简单地构造该类并将其作为接口传递。如果你的 TBmpUtility 可以接受一个 IBitmap，你可以这样构造它：

TBmpUtility.Create(TBitmapAdapter.Create(Self))

您确实可以为 TBitmap 和 TMyBitmap 编写类助手来为您创建正确的包装器。还是 TBitmap 版本：

type
  TBitmapHelper = class helper for TBitmap
    function AsIBitmap: IBitmap;
  end;

function TBitmapHelper.AsIBitmap: IBitmap;
begin
  Result := TBitmapAdapter.Create(Self);
end;

然后您可以像这样简单地使用它：

TBmpUtility.Create(Bitmap.AsIBitmap)

或者也许只是将它传递给实用程序类的方法，您可以拥有一个可以处理任何位图的实用程序实例：

BmpUtility.Fill(Bitmap.AsIBitmap);

可以临时存储对 IBitmap 的引用，以防止在每次调用时创建和销毁适配器：

var b: IBitmap;
begin
  b := Bitmap.AsIBitmap;
  BmpUtility.SetHeight(b, 100);
  BmpUtility.SetWidth(b, 100);
  BmpUtility.Fill(b);
end;

Bitmap.AsIBitmap的结果是适配器类的IBitmap接口，但是使用它的代码甚至都不知道，并且接口是refcount的，所以一旦超出范围就会释放适配器.