c# XDocument：检查特定节点名称是不是存在，如果不添加

Posted 2023-02-16

【中文标题】c# XDocument：检查特定节点名称是不是存在，如果不添加

【英文标题】：c# XDocument : Check if particular node name exists , if not addc# XDocument：检查特定节点名称是否存在，如果不添加

【发布时间】：2019-07-04 20:21:51

【问题描述】：

我有以下节点，如果不存在，需要在 xslt 中添加：-

<xsl:template name="URLSpliter">
    <xsl:param name="url" />
    <xsl:variable name="splitURL" select="substring-after($url, '/')" />
    <xsl:if test="contains($splitURL, '/')">
      <!--To call the template recursively-->
      <xsl:call-template name="URLSpliter">
        <xsl:with-param name="url" select="$splitURL" />
      </xsl:call-template>
    </xsl:if>
    <xsl:if test="not(contains($splitURL, '/'))">
      <xsl:value-of select="$splitURL" />
    </xsl:if>
  </xsl:template>

为此，首先我需要检查它是否存在？-

我已经检查过了-

IEnumerable<XElement> xElements = from xmlAuthor in doc.Descendants()
                                                      let xElement = xmlAuthor.Element("URLSpliter")
                                                      where xElement != null 
                                                      select xmlAuthor;

                    var IsUrlSplitterExists= xElements.Any();

                    if(IsUrlSplitterExists)
                    

                    

1.我想知道它的方法是否正确？

如果不存在（元素[name="URLSpliter"]）则需要添加。

如何将其添加为 xslt 的第一个节点？

【参考方案1】：

要使用 LINQ to XML 在 XSLT 命名空间中选择此类元素，您可以使用

XNamespace xsl = "http://www.w3.org/1999/XSL/Transform"; 
if (!doc.Root.Elements(xsl + "template").Where(t => (string)t.Attribute("name") == "URLSplitter").Any())  
  doc.Root.AddFirst(new XElement(xsl + "template", new XAttribute("name", "URLSplitter"), ...)) 

当然，由于 XSLT 是 XML，您不妨使用 XSLT 来操作您的 XSLT：

<xsl:stylesheet 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:axsl="http://www.w3.org/1999/XSL/Transform-alias"
  exclude-result-prefixes="axsl"
  version="1.0">

  <xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>

  <xsl:output indent="yes"/>

  <xsl:param name="new-template">
   <axsl:template name="URLSpliter">
    <axsl:param name="url" />
    <axsl:variable name="splitURL" select="substring-after($url, '/')" />
    <axsl:if test="contains($splitURL, '/')">
      <!--To call the template recursively-->
      <axsl:call-template name="URLSpliter">
        <axsl:with-param name="url" select="$splitURL" />
      </axsl:call-template>
    </axsl:if>
    <axsl:if test="not(contains($splitURL, '/'))">
      <axsl:value-of select="$splitURL" />
    </axsl:if>
  </axsl:template>
 </xsl:param>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="xsl:transform[not(xsl:template[@name = 'URLSplitter'])] | xsl:stylesheet[not(xsl:template[@name = 'URLSplitter'])]">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:copy-of select="$new-template"/>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/94rmq5T