我们如何识别一组节点并将该组添加到另一个 XSLT 中 XML 源结构不同的节点？

Posted

技术标签:

【中文标题】我们如何识别一组节点并将该组添加到另一个 XSLT 中 XML 源结构不同的节点？【英文标题】：How do we identify a set of nodes and add that set into another where the structure of XML source vary in XSLT? 【发布时间】：2017-01-01 13:24:52 【问题描述】：

我正在尝试将基于 Flash 的文本格式转换为基于 html 的文本。

源 xml 中有 <LI></LI> 块，我需要在 <ul> 块内添加相邻的 <LI> 块。

<p></p>
<li></li> ------
<li></li>      | - should be wrapped with <ul> tag
<li></li> ------
<p></p>
<li></li>
<li></li>
<li></li>
<p></p>

XML 源代码

<root>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            edfg
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            sdgfdsgsds
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            sdfgdsg
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            dsgdfgdsfg
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">errytrtyr</FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="LEFT">
            sdgfdsgsds
        </P>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="System" SIZE="16" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">nm,hjku
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <LI>
            <FONT FACE="System" SIZE="16" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">
                <B>hgjgj</B>
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </LI>
    </TEXTFORMAT>
    <TEXTFORMAT LEADING="2">
        <P ALIGN="CENTER">
            <FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B" LETTERSPACING="0" KERNING="0">centered text</FONT>
        </P>
    </TEXTFORMAT>
</root>

预期输出

<div>
    <div style="text-align:LEFT; ">
        edfg
    </div>
    <div style="text-align:LEFT; ">
        sdgfdsgsds
    </div>
    <ul>
        <li>
            sdfgdsg
        </li>
        <li>
            dsgdfgdsfg
        </li>
        <li>
            <FONT COLOR="#4B4B4B" FACE="Lato" SIZE="12">errytrtyr</FONT>
        </li>
    </ul>
    <div style="text-align:LEFT; ">
        sdgfdsgsds
    </div>
    <ul>
        <li>
            <FONT COLOR="#4B4B4B" FACE="System" SIZE="16">nm,hjku
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </li>
        <li>
            <FONT COLOR="#4B4B4B" FACE="System" SIZE="16">
                <B>hgjgj</B>
                <FONT FACE="Lato" SIZE="12"></FONT>
            </FONT>
        </li>
    </ul>
    <div style="text-align:CENTER; ">
        <FONT COLOR="#4B4B4B" FACE="Lato" SIZE="12">centered text</FONT>
    </div>
</div>

我的代码：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" method="html"/>

    <!-- identity template -->

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="root">
        <div>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <!-- remove unwanted attributes -->
    <xsl:template match="@LETTERSPACING|@KERNING"/>

    <!-- Remove <P> tag and set the alignment -->
    <xsl:template match="P">
        <div>
            <xsl:attribute name="style">
                <!-- collect attributes -->
                <xsl:variable name="styles">
                    <xsl:if test="@ALIGN">
                        <xsl:value-of select="concat('text-align:', @ALIGN )"/>
                        <xsl:text>; </xsl:text>
                    </xsl:if>
                </xsl:variable>
                <!-- delete trailing spaces -->
                <xsl:value-of select="$styles"/>
            </xsl:attribute>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <!-- Replace <LI> with <li> -->
    <xsl:template match="LI">
        <li><xsl:apply-templates/></li>
    </xsl:template>

    <!-- Remove TEXTFORMAT -->
    <xsl:template match="TEXTFORMAT">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

【问题讨论】：

非常好的问题，顺便说一句。简洁、完整、语法有效的示例代码和输入，预期输出与给定输入匹配。在所有相关领域都到位。 @Tomalak 你能看看this 谢谢你的出色回答 【参考方案1】：

这种类型的分组在 XSLT 1.0 中有些困难。

如果可以假设每个 LI 组前面都有一个 P，并且在 root 元素中没有其他类型的节点，那么您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="LI" match="TEXTFORMAT[LI]" use="generate-id(preceding-sibling::TEXTFORMAT[P][1])" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="root">
    <div>
        <xsl:apply-templates select="TEXTFORMAT[P]"/>
    </div>
</xsl:template>

<xsl:template match="TEXTFORMAT">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="P">
    <div style="text-align:@ALIGN;">
        <xsl:apply-templates/>
    </div>
    <xsl:variable name="li" select="key('LI', generate-id(..))" />
    <xsl:if test="$li">
        <ul>
            <xsl:apply-templates select="$li"/>
        </ul>           
    </xsl:if>
</xsl:template>

<xsl:template match="LI">
    <li>
        <xsl:apply-templates/>
    </li>
</xsl:template>

<xsl:template match="@LETTERSPACING|@KERNING"/>

</xsl:stylesheet>

【讨论】：

【参考方案2】：

以下 XSLT 1.0 转换为您提供了看似想要的结果：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" method="html"/>

    <xsl:key name="list" match="TEXTFORMAT[LI]" use="generate-id(
        (self::*|preceding-sibling::*)[LI][
            not(preceding-sibling::*[1][LI])
        ][last()]
    )" />

    <!-- identity template -->
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="root">
        <div>
            <xsl:apply-templates />
        </div>
    </xsl:template>

    <!-- Remove <P> tag and set the alignment -->
    <xsl:template match="P">
        <div>
            <xsl:attribute name="style">
                <xsl:apply-templates select="@*" mode="css" />
            </xsl:attribute>
            <xsl:apply-templates/>
        </div>
    </xsl:template>

    <xsl:template match="@ALIGN" mode="css">
        <xsl:value-of select="concat('text-align:', ., ';')"/>
    </xsl:template>
    <!-- add more -->
    <xsl:template match="@*" mode="css" />

    <!-- remove unwanted attributes -->
    <xsl:template match="@LETTERSPACING|@KERNING"/>

    <xsl:template match="TEXTFORMAT[LI]">
        <xsl:variable name="adjacent" select="key('list', generate-id())" />
        <xsl:if test="$adjacent">
            <ul>
                <xsl:apply-templates select="$adjacent/LI" />
            </ul>
        </xsl:if>
    </xsl:template>

    <!-- Replace <LI> with <li> -->
    <xsl:template match="LI">
        <li><xsl:apply-templates/></li>
    </xsl:template>

    <!-- Remove TEXTFORMAT -->
    <xsl:template match="TEXTFORMAT">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

结果：

<div>
   <div style="text-align:LEFT;">
      edfg

   </div>
   <div style="text-align:LEFT;">
      sdgfdsgsds

   </div>
   <ul>
      <li>
         sdfgdsg

      </li>
      <li>
         dsgdfgdsfg

      </li>
      <li><FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B">errytrtyr</FONT></li>
   </ul>
   <div style="text-align:LEFT;">
      sdgfdsgsds

   </div>
   <ul>
      <li><FONT FACE="System" SIZE="16" COLOR="#4B4B4B">nm,hjku
            <FONT FACE="Lato" SIZE="12"></FONT></FONT></li>
      <li><FONT FACE="System" SIZE="16" COLOR="#4B4B4B"><B>hgjgj</B><FONT FACE="Lato" SIZE="12"></FONT></FONT></li>
   </ul>
   <div style="text-align:CENTER;"><FONT FACE="Lato" SIZE="12" COLOR="#4B4B4B">centered text</FONT></div>
</div>

解决方案的关键，顾名思义，就是这个结构：

<xsl:key name="list" match="TEXTFORMAT[LI]" use="generate-id(
    (self::*|preceding-sibling::*)[LI][
        not(preceding-sibling::*[1][LI])
    ][last()]
)" />

这会根据开始当前系列的最近的TEXTFORMAT[LI] 的唯一 ID 对文档中的每个 TEXTFORMAT[LI] 进行索引，即之前没有 TEXTFORMAT[LI] 的最近的 ID。

从那里开始，我们可以在&lt;xsl:template match="TEXTFORMAT[LI]"&gt; 中决定是否为任何给定的TEXTFORMAT[LI] 输出一些东西。

【讨论】：

以上是关于我们如何识别一组节点并将该组添加到另一个 XSLT 中 XML 源结构不同的节点？的主要内容，如果未能解决你的问题，请参考以下文章

如何在 xslt 中添加空格并将记录限制为 300 个字符

如何将前缀类型添加到重复父节点并使用 XSLT 选择每个元素的所有元素？

XSLT 如何组合模板并将现有字段添加到某些元素

使用 xslt 2 从节点生成 xpath

XSLT如何仅对XML文档的字符串节点中的数值进行排序

如何在XSLT中正确编辑节点值