用于 Fortran 的 mex 网关中 REAL 变量的可移植声明

Posted 2023-02-16

【中文标题】用于 Fortran 的 mex 网关中 REAL 变量的可移植声明

【英文标题】：Portable declaration of REAL variables in mex gateway for Fortran

【发布时间】：2019-07-28 20:05:34

【问题描述】：

我正在为一段 Fortran 代码编写一个 mex 网关。

在 Fortran 代码中，为了可移植性，浮点变量声明为

REAL(kind(0.0D0)) :: x, y, etc

（顺便说一句，我知道有更好的方法可以做到这一点，如在 Fortran: integer*4 vs integer(4) vs integer(kind=4), What does "real*8" mean?，和 https://software.intel.com/en-us/blogs/2017/03/27/doctor-fortran-in-it-takes-all-kinds)

但是，在我看来，mex 只支持 REAL*8 和 REAL*4，前者是 Double，后者是 Single。我从以下函数/子例程中得到了这个印象：

mxIsDouble、mxIsSingle、mxCopyPtrToReal8、mxCopyReal8ToPtr、mxCopyPtrToReal4、mxCopyReal4ToPtr

我的问题如下。

mex 是否只支持 REAL*8 和 REAL*4？

如果我将双精度浮点变量声明为，是否会提高 mex 网关的可移植性

REAL(kind(0.0D0)) :: x, y 等

甚至

integer, parameter :: dp = selected_real_kind(15, 307)
real(kind=dp) :: x, y, etc

或者我应该简单地声明

REAL*8 :: x, y, etc 

是否所有平台都支持 REAL*8 和/或 REAL*4？如果不是，这是否意味着 MATLAB mex 本质上是不可移植的？

在 Fortran 代码的 mex 网关中指定浮点变量类型的最佳方法是什么？

以下代码是一个示例。请参阅 x、y 和 xs 的声明。

#include "fintrf.h"

      subroutine mexFunction(nlhs, plhs, nrhs, prhs)
C     y = square (x) 
C     x: a floating point scalar
C     y: x^2

      implicit none

C     mexFunction arguments 
      integer, intent(in) :: nlhs, nrhs 
      mwPointer, intent(in) :: prhs(nrhs)
      mwPointer, intent(inout) :: plhs(nlhs)

C     function declarations:
      mwPointer, external :: mxCreateDoubleScalar, mxGetPr
      mwSize, external :: mxGetM, mxGetN
      integer*4, external :: mxIsDouble, mxIsSingle 

C     variables
      mwSize, parameter :: mwOne = 1
      integer, parameter :: dKind = kind(0.0D0) 
      integer, parameter :: sKind = kind(0.0) 
      real(kind=dKind) :: x, y ! Does this improve the portablity?
      real(kind=sKind) :: xs ! Does this improve the portablity?

C     validate number of arguments
      if (nrhs .ne. 1) then
         call mexErrMsgIdAndTxt ('mex:nInput', '1 input required.')
      endif
      if (nlhs .gt. 1) then
         call mexErrMsgIdAndTxt ('mex:nOutput', 'At most 1 output.')
      endif

C     validate input
      if (mxIsDouble(prhs(1)) .ne. 1 .and. mxIsSingle(prhs(1)) .ne. 1) 
      ! What if the input is a floating point number but neither Double nor Single? 
     + then 
          call mexErrMsgIdAndTxt ('mex:Input', 'Input a real number.')
      endif
      if (mxGetM(prhs(1)) .ne. 1 .or. mxGetN(prhs(1)) .ne. 1) then
          call mexErrMsgIdAndTxt ('mex:Input', 'Input a scalar.')
      endif

C     read input
      if (mxIsDouble(prhs(1)) .eq. 1) then
         call mxCopyPtrToReal8(mxGetPr(prhs(1)), x, mwOne) 
      else
         call mxCopyPtrToReal4(mxGetPr(prhs(1)), xs, mwOne)
         x = real(xs, dKind) 
         ! What if the input is a floating point number but neither REAL*8 nor REAL*4
      endif

C     do the calculation
      y = x**2

C     write output
      plhs(1) = mxCreateDoubleScalar(y)

      return
      end subroutine mexFunction

代码运行正确。但我不确定它是否便携。

【问题讨论】：

也许还有real*4 single; real(kind(single)) x。同样不便携，但限制了需要担心的部件数量。

“这是否意味着 MATLAB mex 本质上是不可移植的？”。 MATLAB 仅适用于 3 个操作系统和the documentation lists exactly which version of which compilers you can use to make MEX-files。所以是的，MEX 本质上是不可移植的，因为您无法在其他平台上或使用其他编译器编译 MEX 文件。

感谢@francescalus 和 Cris Luengo 提供的信息丰富的 cmets！

【参考方案1】：

REAL*4 和 REAL*8 是非标准且不可移植的。 REAL(KIND(0.0D0) 在每个平台上为您提供 DOUBLE PRECISION，这是 Fortran 标准所要求的。

我无法与 MEX 网关交谈，但您应该避免使用明显的非标准功能。

一个流行的选择是定义一个模块，为使用的种类声明命名（PARAMETER）常量。例如：

module kinds integer, parameter :: SP = KIND(0.0) integer, parameter :: DP = KIND(0.0D0) end module kinds

然后您可以使用SP 和DP 作为种类值。如果您需要更改这些，只需编辑模块即可。

【讨论】：

谢谢你，史蒂夫。我可以再问两个问题吗？ Q1。在所有平台上，REAL(DP) 是否等同于 REAL*8，REAL(SP) 是否等同于 REAL*4？ Q2。我应该如何以类似的方式声明 INTEGER*4 ？我问这些问题是因为 mex 明确要求 REAL*8、REAL*4 和 INTEGER*4。非常感谢！

我想说，写这些“要求”的人需要被送去接受再教育。说真的，您可以将“REAL*4”解释为“单精度”，将“REAL*8”解释为“双精度”。在支持这些扩展的编译器上，这就是它们的意思。至于 INTEGER*4，您可以使用 KIND(0)，尽管我实际上可能建议使用标准内在函数 SELECTED_INT_KIND 和 SELECTED_REAL_KIND，并为参数设置适当的值。

再次感谢@Steve Lionel。我完全同意再教育——这些不标准的东西让我很头疼。很抱歉打扰您最后一个关于“参数的适当值”的问题：SELECTED_INT_KIND(7), SELECTED_INT_KIND(8), SELECTED_INT_KIND(9) 都会给我们 INTEGER*4, SELECTED_INT_KIND(6, 37) 是否正确给我们 REAL*4，SELECTED_INT_KIND(15,307) 会给我们 REAL*8？我从其他地方读到了这些价值观，但很高兴听到真正专家的意见。非常感谢！

我假设您的意思是说 SELECTED_REAL_KIND 用于真实类型。这些是我将使用的值（INT 为 9），尽管我知道一个平台（在不寻常的配置中），其中 (15,307) 不会得到你想要的。另一种选择（虽然我不喜欢它）是来自内部模块 ISO_FORTRAN_ENV 的 INT32、REAL32 和 REAL64 常量。 （我对这些经常使用的方式有一些哲学上的反对意见，但它们适用于你的情况。）

REAL*8 从来都不是标准的。 F90 之前的表达方式是DOUBLE PRECISION

【参考方案2】：

目前，将变量定义为 REAL*8/REAL*4 或 REAL(REAL64)/REAL(REAL32) 没有区别。将来 MathWorks 可能会出现并重写他们的函数以使用可移植变量声明，但在我看来这不太可能有很多原因。

如果您查看 fintrf.h 文件（包含在每个 Fortran MEX 网关源文件中），您会看到所有 MEX 特定过程都使用“星号符号”定义，例如# define MWPOINTER INTEGER*8。因此，即使您使用 iso_fortran_env 或 selected_real_kind 中的种类定义所有变量，只要您使用 MathWorks 变量类型，您仍然使用“星号表示法”类型，除非您浏览该头文件并使用您选择的种类重新定义每个符号规范。

【讨论】：

确实如此。遵循您使用的头文件的表示法更容易。