VBA：如何检索 HeaderRowRange 中给定元素的 ListObject-Column-Count？

Posted 2023-03-27

【中文标题】VBA：如何检索 HeaderRowRange 中给定元素的 ListObject-Column-Count？

【英文标题】：VBA: How to retrieve ListObject-Column-Count of given element in HeaderRowRange?

【发布时间】：2021-08-21 08:24:04

【问题描述】：

我正在尝试（但失败）在 ListObject 的 HeaderRowRange 中找到给定的字符串。我想提取 ListObject-Column Count（不是电子表格列数）。我正在尝试使用“.index”来解决，但是，它遇到了错误。下面的代码有什么问题？

查看屏幕截图以更好地了解我的目标： 在 ListObject Column3 中是第 3 列，而在工作表中是第 6 列（F 列）。我希望我的代码中的 j 为 3（而不是 6）。

Sub MWE()
Dim wb As Workbook: Set wb = ThisWorkbook
Dim ws As Worksheet: Set ws = wb.Sheets("worksheet1")
Dim lo As ListObject: Set lo = ws.ListObjects("table1")
Dim j As Long: j = lo.HeaderRowRange.Find("Column3", LookIn:=xlValues, LookAt:=xlWhole).Index
End Sub

【问题讨论】：

lo.ListColumns("Column3").Index怎么样

【参考方案1】：

除了hearderRow之外，还有几种方法可以访问listobject table中的列，希望对你有用

Sub tt()

Dim tb1 As ListObject
Dim rcol As Range

Set tb1 = Sheet1.ListObjects("Table1")
Set rcol = tb1.ListColumns("Ctry").DataBodyRange

Debug.Print rcol(3).Value  'Hawaii

End Sub

【讨论】：

@SiddharthRout，我想出了其他方法来找到 headerRow 也大声笑

【参考方案2】：

.Find 返回一个范围对象。这是你正在尝试的吗？

Option Explicit

Sub Sample()
    Dim wb As Workbook: Set wb = ThisWorkbook
    Dim ws As Worksheet: Set ws = wb.Sheets("worksheet1")
    Dim lo As ListObject: Set lo = ws.ListObjects("Table1")
    Dim aCell As Range
    Set aCell = lo.HeaderRowRange.Find("Column3", LookIn:=xlValues, LookAt:=xlWhole)

    If Not aCell Is Nothing Then
        MsgBox aCell.Column
    End If
End Sub

或者你也可以使用Application.Match

Option Explicit

Sub Sample()
    Dim wb As Workbook: Set wb = ThisWorkbook
    Dim ws As Worksheet: Set ws = wb.Sheets("worksheet1")
    Dim lo As ListObject: Set lo = ws.ListObjects("Table1")
    Dim j As Long: j = Application.Match("Column3", lo.HeaderRowRange, 0)
    
    MsgBox j
End Sub

PS：您的代码中也有错字。 Dim lo As listoject 应该是 Dim lo As ListObject

编辑

查看屏幕截图以更好地理解我的目标：在 ListObject Column3 中是第 3 列，而在工作表中是第 6 列（F 列）。我希望我的代码中的 j 为 3（而不是 6）。

在这种情况下，如果您的表格不是从 Col A 开始，那么您将不得不进行范围调整。在第一个代码中将MsgBox aCell.Column 更改为MsgBox aCell.Column - lo.HeaderRowRange.Column + 1。

输出

【讨论】：

application.match 完美运行。仍在考虑 .find 方法：如果我正确理解您的评论，则基本上不可能在 ListOject 中提取某些内容，因为 .find 指的是再次引用整个工作表的范围。

@user3601876 我建议使用Dim j As Variant。仅适用于“Column3”与搜索范围内的任何内容都不匹配的情况。然后使用If Not IsError(j) Then MsgBox j。按照建议的方式，它不会出现错误，即使没有使用IsError 检查，如果找不到字符串，它也会返回“错误 2042”...

".. 我希望我的代码中的 j 为 3（而不是 6）" - 因为 .Find 导致自身产生一个 range 对象 在给定的工作表中并且其.Column 属性返回其中的列（例如6），您可以通过减法计算listobject 中所需的列位置，如下所示：6 minus listobject 的起始列 (- lo.Range.Cells(1, 1).Column) 加上 +1 (因为没有零列) :-) @user3601876

除了@FaneDuru 的有效评论：由于后期绑定Application.Match 预计会返回一个位置编号，以防发现某些东西，也可以排除 non-findings 通过以下条件：If IsNumeric(j) Then MsgBox j 而不是否定错误:-)

@user3601876 如果您的表格不是从 Col A 开始，那么您将不得不进行范围调整。将MsgBox aCell.Column 更改为MsgBox aCell.Column - lo.HeaderRowRange.Column + 1

【参考方案3】：

由于我知道列标题的名称，我可以简单地使用此代码来获取 ListObject 中的列数：

j= lo.ListColumns("Column3").Index