在混合 MPI/OpenMP 中进行 MPI 调用的线程

Posted 2023-03-27

【中文标题】在混合 MPI/OpenMP 中进行 MPI 调用的线程

【英文标题】：Threads making MPI calls in a Hybrid MPI/OpenMP

【发布时间】：2016-02-08 18:23:28

【问题描述】：

我在我的混合 MPI/OpenMP 代码中发现了一个问题，该代码被复制 在下面引用的代码中以最简单的形式。我正在使用 2 个线程 每个 MPI 等级。然后在 OpenMP“部分”中使用这两个线程 要进行多次计算，其中之一是对两个不同的向量 A 和 B 进行“mpi_allreduce”调用，其结果 存储在 W 和 WW 中。问题是每次我运行程序 我最终得到不同的输出。我的想法是 MPI 调用是 重叠和缩减的数组 W 和 WW 被组合，即使它们 有不同的名字，但我不确定。关于如何克服的任何评论 这个问题是受欢迎的。

详情： MPI线程级别在代码中初始化为MPI_THREAD_MULTIPLE 但我也尝试过串行和漏斗（同样的问题）。

我编译代码 mpiifort -openmp allreduce_omp_mpi.f90 和 跑步我用：

导出 OMP_NUM_THREADS=2 mpirun -np 3 ./a.out

      PROGRAM HELLO
      use mpi 
      use omp_lib
      IMPLICIT NONE

      INTEGER nthreads, tid 

      Integer Provided,mpi_err,myid,nproc
      CHARACTER(MPI_MAX_PROCESSOR_NAME):: hostname
      INTEGER :: nhostchars

      integer :: i
      real*8 :: A(1000), B(1000), W(1000),WW(1000)

      provided=0
      !Initialize MPI context
      call mpi_init_thread(MPI_THREAD_MULTIPLE,provided,mpi_err)
      CALL mpi_comm_rank(mpi_comm_world,myid,mpi_err)
      CALL mpi_comm_size(mpi_comm_world,nproc,mpi_err)
      CALL mpi_get_processor_name(hostname,nhostchars,mpi_err)

      !Initialize arrays
      A=1.0
      B=2.0
      !Check if MPI_THREAD_MULTIPLE is available
      if (provided >= MPI_THREAD_MULTIPLE) then
      write(6,*) ' mpi_thread_multiple provided',myid
      else
      write(6,*) ' not mpi_thread_multiple provided',myid
      endif

!$OMP PARALLEL PRIVATE(nthreads, tid) NUM_THREADS(2)
!$omp sections
!$omp section
       call mpi_allreduce(A,W,1000,mpi_double_precision,mpi_sum,mpi_comm_world,mpi_err)
!$omp section
       call mpi_allreduce(B,WW,1000,mpi_double_precision,mpi_sum,mpi_comm_world,mpi_err)
!$omp end sections
!$OMP END PARALLEL

       write(6,*) 'W',(w(i),i=1,10)
       write(6,*) 'WW',(ww(i),i=1,10)

      CALL mpi_finalize(mpi_err)
      END 

【问题讨论】：

一个不请自来的可移植性建议：不要使用以mpi_ 开头的名称来命名您自己的变量和常量。这样做可能会导致与 MPI 库的名称冲突。此外，不能保证DOUBLE_PRECISION 和REAL*8 是同一种类型。

我要添加另一个建议，不要使用write(6,，而是使用write(*,。它不再更便携。

【参考方案1】：

MPI standard 禁止在同一个通信器上同时执行（阻塞）集体操作（第 5.13 节“[集体通信] 的正确性”）：

...

最后，在多线程实现中，一个进程可以有多个并发执行的集体通信调用。在这些情况下，用户有责任确保同一进程中的两个不同的集体通信调用不会同时使用同一个通信器。

这里的重点是：相同的沟通者。没有什么能阻止您通过不同的通信器开始并发集体通信：

integer, dimension(2) :: comms

call MPI_COMM_DUP(MPI_COMM_WORLD, comms(1), ierr)
call MPI_COMM_DUP(MPI_COMM_WORLD, comms(2), ierr)

!$omp parallel sections num_threads(2)
!$omp section
    call MPI_ALLREDUCE(A, W, 1000, MPI_REAL8, MPI_SUM, comms(1), ierr)
!$omp section
    call MPI_ALLREDUCE(B, WW, 1000, MPI_REAL8, MPI_SUM, comms(2), ierr)
!$omp end parallel sections

call MPI_COMM_FREE(comms(1), ierr)
call MPI_COMM_FREE(comms(2), ierr)

这个程序只是将MPI_COMM_WORLD 复制了两次。第一个副本用于第一个并行部分，第二个副本用于第二个。尽管这两个新的通信器是MPI_COMM_WORLD 的副本，但它们是独立的上下文，因此可以对它们进行并发操作。

MPI_COMM_DUP 是一项昂贵的操作，因此新创建的通信器在被释放之前应尽可能长时间地使用。

【讨论】：

太棒了！你今天帮了我很多，我一直在努力解决这些问题，但我不知道要问什么人。