如何从 tsql (sql 2005) 中的 utc 日期时间计算本地日期时间？

Posted 2023-02-25

技术标签:

【中文标题】如何从 tsql (sql 2005) 中的 utc 日期时间计算本地日期时间？【英文标题】：How to calculate the local datetime from a utc datetime in tsql (sql 2005)? 【发布时间】：2011-03-25 04:41:42 【问题描述】：

我想在 tsql 中循环一段时间，并打印 utc 日期时间和我们的本地变量。我们生活在 UTC +1，所以我可以轻松增加 1 小时，但在夏季，我们生活在 UTC +2。

在 C# 中，我可以创建一个日期时间并使用一种方法来请求 UTC 变体，反之亦然。

到现在为止我有这个：

declare @counter int
declare @localdate datetime
declare @utcdate datetime
 set @counter = 0
 while @counter < 100
 begin
   set @counter = @counter + 1
   print 'The counter is ' + cast(@counter as char)
  set @utcdate  = DATEADD(day,@counter,GETUTCDATE())
  --set @localdate = ????

  print  @localdate  
  print @utcdate
 end

【问题讨论】：

【参考方案1】：

我已经等待了 5 年的更优雅的解决方案，但由于尚未出现，我将发布我迄今为止一直在使用的内容......

CREATE FUNCTION [dbo].[UDTToLocalTime](@UDT AS DATETIME)  
RETURNS DATETIME
AS
BEGIN 
--====================================================
--Set the Timezone Offset (NOT During DST [Daylight Saving Time])
--====================================================
DECLARE @Offset AS SMALLINT
SET @Offset = -5

--====================================================
--Figure out the Offset Datetime
--====================================================
DECLARE @LocalDate AS DATETIME
SET @LocalDate = DATEADD(hh, @Offset, @UDT)

--====================================================
--Figure out the DST Offset for the UDT Datetime
--====================================================
DECLARE @DaylightSavingOffset AS SMALLINT
DECLARE @Year as SMALLINT
DECLARE @DSTStartDate AS DATETIME
DECLARE @DSTEndDate AS DATETIME
--Get Year
SET @Year = YEAR(@LocalDate)

--Get First Possible DST StartDay
IF (@Year > 2006) SET @DSTStartDate = CAST(@Year AS CHAR(4)) + '-03-08 02:00:00'
ELSE              SET @DSTStartDate = CAST(@Year AS CHAR(4)) + '-04-01 02:00:00'
--Get DST StartDate 
WHILE (DATENAME(dw, @DSTStartDate) <> 'sunday') SET @DSTStartDate = DATEADD(day, 1,@DSTStartDate)


--Get First Possible DST EndDate
IF (@Year > 2006) SET @DSTEndDate = CAST(@Year AS CHAR(4)) + '-11-01 02:00:00'
ELSE              SET @DSTEndDate = CAST(@Year AS CHAR(4)) + '-10-25 02:00:00'
--Get DST EndDate 
WHILE (DATENAME(dw, @DSTEndDate) <> 'sunday') SET @DSTEndDate = DATEADD(day,1,@DSTEndDate)

--Get DaylightSavingOffset
SET @DaylightSavingOffset = CASE WHEN @LocalDate BETWEEN @DSTStartDate AND @DSTEndDate THEN 1 ELSE 0 END

--====================================================
--Finally add the DST Offset 
--====================================================
RETURN DATEADD(hh, @DaylightSavingOffset, @LocalDate)
END



GO

注意事项：

这适用于观察夏令时的北美服务器。请将变量@Offest 更改为运行 SQL 函数的服务器的时区偏移量（虽然不观察夏令时）...

--====================================================
--Set the Timezone Offset (NOT During DST [Daylight Saving Time])
--====================================================
DECLARE @Offset AS SMALLINT
SET @Offset = -5

随着夏令时规则的变化，在这里更新它们...

--Get First Possible DST StartDay
IF (@Year > 2006) SET @DSTStartDate = CAST(@Year AS CHAR(4)) + '-03-08 02:00:00'
ELSE              SET @DSTStartDate = CAST(@Year AS CHAR(4)) + '-04-01 02:00:00'
--Get DST StartDate 
WHILE (DATENAME(dw, @DSTStartDate) <> 'sunday') SET @DSTStartDate = DATEADD(day, 1,@DSTStartDate)


--Get First Possible DST EndDate
IF (@Year > 2006) SET @DSTEndDate = CAST(@Year AS CHAR(4)) + '-11-01 02:00:00'
ELSE              SET @DSTEndDate = CAST(@Year AS CHAR(4)) + '-10-25 02:00:00'
--Get DST EndDate 
WHILE (DATENAME(dw, @DSTEndDate) <> 'sunday') SET @DSTEndDate = DATEADD(day,1,@DSTEndDate)

干杯，

【讨论】：

非常感谢您分享这个！这有几个错误。请参阅包含解释和更新代码的答案：***.com/a/36361558/341942【参考方案2】：

假设您使用 SQL 2005 以上版本，您可以开发一个 SQL CLR 函数来获取 UTC 日期并转换为本地日期。

This link 是 MSDN How-To 解释如何在 C# 中创建标量 UDF。

按照以下方式创建一个 SQL 函数

[SqlFunction()]
public static SqlDateTime ConvertUtcToLocal(SqlDateTime utcDate) 

    // over to you to convert SqlDateTime to DateTime, specify Kind
    // as UTC, convert to local time, and convert back to SqlDateTime

您上面的示例将变为

set @localdate = dbo.ConvertUtcToLocal(@utcdate)

SQL CLR 在部署方面有其开销，但我觉得这样的情况最适合它。

【讨论】：

想出了如何将 utc 转换为其他时区，并尝试实现 SqlCLR 函数。但是将它们组合起来不起作用，因为我使用 TimeZoneInfo 对象来计算不同的日期时间，并且我无法从我的 SqlProject 引用该类所在的程序集（因为您似乎只能引用 .net 的一个子集框架） OK - 很好奇为什么您需要 TimeZoneInfo 类，因为您需要将 UTC 转换为本地。如果您的 SQL 服务器配置为在您的本地时区（同意 - 这是一个约束），那么您的 c# 函数将变为类似 'return new SqlDateTime(utcDate.Value.toLocalTime()); ' .您无需指定时区。我理解错了吗？你是对的，但它必须适用于不同时区的不同用户最后：没有找到不硬编码的方法。标记为 Neil 所做努力的答案。 @Michel，您应该能够在 SQL Server 中引用任何 .NET 程序集；与安全有关的不同设置有一些限制，有些事情可能无法正常工作，因为程序集在“沙箱”中运行。但是，请考虑使用Noda Time，因为正确处理日期和时间的最棘手的元素是日历和时区会发生变化。 Noda Time 包含tz database，它可以独立于代码本身进行更新。【参考方案3】：

这个解决方案似乎太明显了。

如果您可以使用 GETUTCDATE() 获取 UTC 日期，并且可以使用 GETDATE() 获取您的本地日期，则您有一个偏移量，您可以申请任何日期时间

SELECT DATEADD(hh, DATEPART(hh, GETDATE() - GETUTCDATE()) - 24, GETUTCDATE())

这应该返回您执行查询的本地时间，

SELECT DATEADD(hh, DATEPART(hh, GETDATE() - GETUTCDATE()) - 24, N'1/14/2011 7:00:00'  )

这将返回 2011-01-14 02:00:00.000 因为我在 UTC +5

除非我错过了什么？

【讨论】：

我认为这不会处理夏季时间偏移不要无缘无故地堆砌，但这不仅不处理夏季时间（或夏令时），而且也不处理时区或日历的历史变化。【参考方案4】：

您可以使用我的 SQL Server Time Zone Support 项目在 IANA 标准时区 as listed here 之间进行转换。

例子：

SELECT Tzdb.UtcToLocal('2015-07-01 00:00:00', 'America/Los_Angeles')

【讨论】：

【参考方案5】：

GETUTCDATE() 只为您提供 UTC 的当前时间，您对该值执行的任何 DATEADD() 都不会包括任何夏令时转换。

您最好的选择是建立您自己的 UTC 转换表，或者只使用类似的东西：

http://www.codeproject.com/KB/database/ConvertUTCToLocal.aspx

【讨论】：

哇。希望有人上来告诉我，这不是真的 sql server 不能这样做吗？ SQL Server 无法开箱即用，您需要构建自己的函数或填充自己的查找表【参考方案6】：

这是一个功能（同样仅限美国），但它更灵活一些。它将 UTC 日期转换为服务器本地时间。它首先根据当前偏移量调整约会日期，然后根据当前偏移量与约会日期偏移量的差值进行调整。

CREATE FUNCTION [dbo].[fnGetServerTimeFromUTC]
(
    @AppointmentDate AS DATETIME, 
    @DateTimeOffset DATETIMEOFFSET
)
RETURNS DATETIME
AS
BEGIN
    --DECLARE @AppointmentDate DATETIME;
    --SET @AppointmentDate = '2016-12-01 12:00:00'; SELECT @AppointmentDate;

    --Get DateTimeOffset from Server
    --DECLARE @DateTimeOffset; SET @DateTimeOffset = SYSDATETIMEOFFSET();
    DECLARE @DateTimeOffsetStr NVARCHAR(34) = @DateTimeOffset;

    --Set a standard DatePart value for Sunday (server configuration agnostic)
    DECLARE @dp_Sunday INT = 7 - @@DATEFIRST + 1;

    --2006 DST Start First Sunday in April (earliest is 04-01) Ends Last Sunday in October (earliest is 10-25)
    --2007 DST Start Second Sunday March (earliest is 03-08) Ends First Sunday Nov (earliest is 11-01)
    DECLARE @Start2006 NVARCHAR(6) = '04-01-';
    DECLARE @End2006 NVARCHAR(6) = '10-25-';
    DECLARE @Start2007 NVARCHAR(6) = '03-08-';
    DECLARE @End2007 NVARCHAR(6) = '11-01-';

    DECLARE @ServerDST SMALLINT = 0;
    DECLARE @ApptDST SMALLINT = 0;
    DECLARE @Start DATETIME;
    DECLARE @End DATETIME;

    DECLARE @CurrentMinuteOffset INT; 

    DECLARE @str_Year NVARCHAR(4) = LEFT(@DateTimeOffsetStr,4);
    DECLARE @Year INT = CONVERT(INT, @str_Year);

    SET @CurrentMinuteOffset = CONVERT(INT, SUBSTRING(@DateTimeOffsetStr,29,3)) * 60 + CONVERT(INT, SUBSTRING(@DateTimeOffsetStr,33,2)); --Hours + Minutes

    --Determine DST Range for Server Offset
    SET @Start = CASE 
        WHEN @Year <= 2006 THEN CONVERT(DATETIME, @Start2006 + @str_Year + ' 02:00:00')
        ELSE CONVERT(DATETIME, @Start2007 + @str_Year + ' 02:00:00')
        END;
    WHILE @dp_Sunday <> DATEPART(WEEKDAY, @Start) BEGIN
        SET @Start = DATEADD(DAY, 1, @Start)
    END;

    SET @End = CASE 
        WHEN @Year <= 2006 THEN CONVERT(DATETIME, @End2006 + @str_Year + ' 02:00:00')
        ELSE CONVERT(DATETIME, @End2007 + @str_Year + ' 02:00:00')
        END;
    WHILE @dp_Sunday <> DATEPART(WEEKDAY, @End) BEGIN
        SET @End = DATEADD(DAY, 1, @End)
    END;

    --Determine Current Offset based on Year
    IF @DateTimeOffset >= @Start AND @DateTimeOffset < @End SET @ServerDST = 1;

    --Determine DST status of Appointment Date
    SET @Year = YEAR(@AppointmentDate);

    SET @Start = CASE 
        WHEN @Year <= 2006 THEN CONVERT(DATETIME, @Start2006 + @str_Year + ' 02:00:00')
        ELSE CONVERT(DATETIME, @Start2007 + @str_Year + ' 02:00:00')
        END;
    WHILE @dp_Sunday <> DATEPART(WEEKDAY, @Start) BEGIN
        SET @Start = DATEADD(DAY, 1, @Start)
    END;

    SET @End = CASE 
        WHEN @Year <= 2006 THEN CONVERT(DATETIME, @End2006 + @str_Year + ' 02:00:00')
        ELSE CONVERT(DATETIME, @End2007 + @str_Year + ' 02:00:00')
        END;
    WHILE @dp_Sunday <> DATEPART(WEEKDAY, @End) BEGIN
        SET @End = DATEADD(DAY, 1, @End)
    END;

    --Determine Appointment Offset based on Year
    IF @AppointmentDate >= @Start AND @AppointmentDate < @End SET @ApptDST = 1;

    SET @AppointmentDate = DATEADD(MINUTE, @CurrentMinuteOffset + 60 * (@ApptDST - @ServerDST), @AppointmentDate)

    RETURN @AppointmentDate
END
GO

【讨论】：

【参考方案7】：

对于那些停留在 SQL Server 2005 中并且不想或不能使用 udf 的人——尤其是在美国以外的地区——我采用了@Bobman 的方法并对其进行了推广。以下将适用于美国、欧洲、新西兰和澳大利亚，但需要注意的是，并非所有澳大利亚州都遵守 DST，即使是在同一“基本”时区的州也是如此。添加尚不支持的 DST 规则也很容易，只需在 @calculation 值中添加一行即可。

-- =============================================
-- Author:      Herman Scheele
-- Create date: 20-08-2016
-- Description: Convert UTC datetime to local datetime
--              based on server time-distance from utc.
-- =============================================
create function dbo.UTCToLocalDatetime(@UTCDatetime datetime)
returns datetime as begin
    declare @LocalDatetime datetime, @DSTstart datetime, @DSTend datetime

    declare @calculation table (
        frm smallint,
        til smallint,
        since smallint,
        firstPossibleStart datetime,-- Put both of these with local non-DST time!
          firstPossibleEnd datetime -- (In Europe we turn back the clock from 3 AM to 2 AM, which means it happens 2 AM non-DST time)
    )

    insert into @calculation
    values
        (-9, -2, 1967, '1900-04-24 02:00', '1900-10-25 01:00'), -- USA first DST implementation
        (-9, -2, 1987, '1900-04-01 02:00', '1900-10-25 01:00'), -- USA first DST extension
        (-9, -2, 2007, '1900-03-08 02:00', '1900-11-01 01:00'), -- USA second DST extension
        (-1,  3, 1900, '1900-03-25 02:00', '1900-10-25 02:00'), -- Europe
        (9.5,11, 1971, '1900-10-01 02:00', '1900-04-01 02:00'), -- Australia (not all Aus states in this time-zone have DST though)
        (12, 13, 1974, '1900-09-24 02:00', '1900-04-01 02:00')  -- New Zealand

    select top 1    -- Determine if it is DST /right here, right now/ (regardless of input datetime)
        @DSTstart = dateadd(year, datepart(year, getdate())-1900, firstPossibleStart),          -- Grab first possible Start and End of DST period
        @DSTend   = dateadd(year, datepart(year, getdate())-1900, firstPossibleEnd),            
        @DSTstart = dateadd(day, 6 - (datepart(dw, @DSTstart) + @@datefirst - 2) % 7, @DSTstart),-- Shift Start and End of DST to first sunday
        @DSTend   = dateadd(day, 6 - (datepart(dw, @DSTend) + @@datefirst - 2) % 7, @DSTend),
        @LocalDatetime = dateadd(hour, datediff(hour, getutcdate(), getdate()), @UTCDatetime),  -- Add hours to current input datetime (including possible DST hour)
        @LocalDatetime = case
                when frm < til and getdate() >= @DSTstart and getdate() < @DSTend               -- If it is currently DST then we just erroneously added an hour above,
                  or frm > til and (getdate() >= @DSTstart or getdate() < @DSTend)              -- substract 1 hour to get input datetime in current non-DST timezone,
                    then dateadd(hour, -1, @LocalDatetime)                                      -- regardless of whether it is DST on the date of the input datetime
                else @LocalDatetime
            end
    from @calculation
    where datediff(minute, getutcdate(), getdate()) between frm * 60 and til * 60
      and datepart(year, getdate()) >= since
    order by since desc

    select top 1    -- Determine if it was/will be DST on the date of the input datetime in a similar fashion
        @DSTstart = dateadd(year, datepart(year, @LocalDatetime)-1900, firstPossibleStart),
        @DSTend   = dateadd(year, datepart(year, @LocalDatetime)-1900, firstPossibleEnd),
        @DSTstart = dateadd(day, 6 - (datepart(dw, @DSTstart) + @@datefirst - 2) % 7, @DSTstart),
        @DSTend   = dateadd(day, 6 - (datepart(dw, @DSTend) + @@datefirst - 2) % 7, @DSTend),
        @LocalDatetime = case
                when frm < til and @LocalDatetime >= @DSTstart and @LocalDatetime < @DSTend     -- If it would be DST on the date of the input datetime,
                  or frm > til and (@LocalDatetime >= @DSTstart or @LocalDatetime < @DSTend)    -- add this hour to the input datetime.
                    then dateadd(hour, 1, @LocalDatetime)
                else @LocalDatetime
            end
    from @calculation
    where datediff(minute, getutcdate(), getdate()) between frm * 60 and til * 60
      and datepart(year, @LocalDatetime) >= since
    order by since desc

    return @LocalDatetime
end

此函数在运行时查看本地时间和 UTC 时间之间的差异，以确定要应用哪些 DST 规则。然后它知道datediff(hour, getutcdate(), getdate()) 是否包含 DST 小时，如果包含则减去它。然后它确定在输入 UTC 日期时间的日期它是否是或将是 DST，如果是，则将 DST 小时向后添加。

这有一个怪癖，即在 DST 的最后一小时和非 DST 的第一小时，该函数无法确定它是哪个，并假定后者。因此，无论输入日期时间如何，如果此代码在 DST 的最后一小时运行，它会给出错误的结果。这意味着这在 99.9886% 的时间内都有效。

【讨论】：

【参考方案8】：

Bobman 的答案很接近，但有几个错误： 1) 您必须将本地 DAYLIGHT 时间（而不是本地 STANDARD 时间）与夏令时结束日期时间进行比较。 2) SQL BETWEEN 是包容性的，因此您应该使用 ">= 和

这是一个有效的修改版本以及一些测试用例：（同样，这只适用于美国）

-- Test cases:
-- select dbo.fn_utc_to_est_date('2016-03-13 06:59:00.000') -- -> 2016-03-13 01:59:00.000 (Eastern Standard Time)
-- select dbo.fn_utc_to_est_date('2016-03-13 07:00:00.000') -- -> 2016-03-13 03:00:00.000 (Eastern Daylight Time)
-- select dbo.fn_utc_to_est_date('2016-11-06 05:59:00.000') -- -> 2016-11-06 01:59:00.000 (Eastern Daylight Time)
-- select dbo.fn_utc_to_est_date('2016-11-06 06:00:00.000') -- -> 2016-11-06 01:00:00.000 (Eastern Standard Time)
CREATE FUNCTION [dbo].[fn_utc_to_est_date]
(
    @utc datetime
)
RETURNS datetime
as
begin
    -- set offset in standard time (WITHOUT daylight saving time)
    declare @offset smallint
    set @offset = -5  --EST

    declare @localStandardTime datetime
    SET @localStandardTime = dateadd(hh, @offset, @utc)

    -- DST in USA starts on the second sunday of march and ends on the first sunday of november.
    -- DST was extended beginning in 2007:
    --   https://en.wikipedia.org/wiki/Daylight_saving_time_in_the_United_States#Second_extension_.282005.29
    -- If laws/rules change, obviously the below code needs to be updated.

    declare @dstStartDate datetime,
            @dstEndDate datetime,
            @year int
    set @year = datepart(year, @localStandardTime)

    -- get the first possible DST start day
    if (@year > 2006) set @dstStartDate = cast(@year as char(4)) + '-03-08 02:00:00'
    else              set @dstStartDate = cast(@year as char(4)) + '-04-01 02:00:00'
    while ((datepart(weekday,@dstStartDate) != 1)) begin --while not sunday
        set @dstStartDate = dateadd(day, 1, @dstStartDate)
    end

    -- get the first possible DST end day
    if (@year > 2006) set @dstEndDate = cast(@year as char(4)) + '-11-01 02:00:00'
    else              set @dstEndDate = cast(@year as char(4)) + '-10-25 02:00:00'
    while ((datepart(weekday,@dstEndDate) != 1)) begin --while not sunday
        set @dstEndDate = dateadd(day, 1, @dstEndDate)
    end

    declare @localTimeFinal datetime,
            @localTimeCompare datetime
    -- if local date is same day as @dstEndDate day,
    -- we must compare the local DAYLIGHT time to the @dstEndDate (otherwise we compare using local STANDARD time).
    -- See: http://www.timeanddate.com/time/change/usa?year=2016
    if (datepart(month,@localStandardTime) = datepart(month,@dstEndDate)
            and datepart(day,@localStandardTime) = datepart(day,@dstEndDate)) begin
        set @localTimeCompare = dateadd(hour, 1, @localStandardTime)
    end
    else begin
        set @localTimeCompare = @localStandardTime
    end

    set @localTimeFinal = @localStandardTime

    -- check for DST
    if (@localTimeCompare >= @dstStartDate and @localTimeCompare < @dstEndDate) begin
        set @localTimeFinal = dateadd(hour, 1, @localTimeFinal)
    end

    return @localTimeFinal
end

【讨论】：

【参考方案9】：

虽然问题的标题提到了 SQL Server 2005，但该问题通常使用 SQL Server 进行标记。对于 SQL Server 2016 及更高版本，您可以使用：

SELECT yourUtcDateTime AT TIME ZONE 'Mountain Standard Time'

SELECT * FROM sys.time_zone_info提供时区列表

【讨论】：

【参考方案10】：

我最近不得不做同样的事情。诀窍是计算出与 UTC 的偏移量，但这并不是一个难点。您只需使用 DateDiff 来获取本地和 UTC 之间的小时差。我写了一个函数来处理这个问题。

Create Function ConvertUtcDateTimeToLocal(@utcDateTime DateTime)
Returns DateTime
Begin
    Declare @utcNow DateTime
    Declare @localNow DateTime
    Declare @timeOffSet Int

    -- Figure out the time difference between UTC and Local time
    Set @utcNow = GetUtcDate()
    Set @localNow = GetDate()
    Set @timeOffSet = DateDiff(hh, @utcNow, @localNow) 

    DECLARE @localTime datetime 

    Set @localTime = DateAdd(hh, @timeOffset, @utcDateTime) 

    -- Check Results
    return @localTime 

End
GO

这确实有一个关键的缺点：如果时区使用小数偏移量，例如尼泊尔，它是 GMT+5:45，这将失败，因为这只处理整个小时。但是，它应该可以很好地满足您的需求。

【讨论】：

不幸的是，这不涉及夏令时。 GetDate() 和 GetUtcDate() 之间的差异全年都不是恒定的。

以上是关于如何从 tsql (sql 2005) 中的 utc 日期时间计算本地日期时间？的主要内容，如果未能解决你的问题，请参考以下文章

从 sql 脚本创建 xml 文件

TSQL / SQL-SERVER：如何在具有主键的快照复制中查找所有表

如何从 SQL Server 2005 中另一个表中的相应数据更新一个表中的数据

SQL 2005，XML DML - 一次更新两个值？

如何使用 PHP 将记录从远程 SQL Server 2005 复制到本地 mySQL？

将 PL/SQL 定义转换为 TSQL