ADODB.Parameters 错误 '800a0e7c' 参数对象定义不正确。提供的信息不一致或不完整

Posted 2023-02-19

【中文标题】ADODB.Parameters 错误 \'800a0e7c\' 参数对象定义不正确。提供的信息不一致或不完整

【英文标题】：ADODB.Parameters error '800a0e7c' Parameter object is improperly defined. Inconsistent or incomplete information was providedADODB.Parameters 错误 '800a0e7c' 参数对象定义不正确。提供的信息不一致或不完整

【发布时间】：2016-06-01 09:55:45

【问题描述】：

我主要是一名 php 开发人员，但我有一些旧的 ASP 是我们以前的开发人员之一制作的，它坏了，我不知道如何修复它。我们有一个程序将一些变量发送到侦听器页面，该页面将这些数据与注册码和 msSQL 数据库进行比较，然后让程序知道注册码是否有效。

我在哪里遇到以下错误

.Parameters.Append .CreateParameter("@code", adVarChar, 1, 50, x)

是第 134 行：

ADODB.Parameters 错误'800a0e7c'

参数对象定义不正确。提供的信息不一致或不完整。

/checkregistrationpro.asp，第 134 行

我已经在包含文件中指定了我没有包含在代码中的任何命名常量，因此与此无关。

我的连接字符串（我已经验证这些设置是正确的）：

set conn = Server.CreateObject("ADODB.Connection")
set cmd = Server.CreateObject("ADODB.Command")
sConnString = "Provider=sqloledb; Data Source=MYDATASOURCE; Initial Catalog=MYCATALOG; User ID=MYUSERID; Password='MYPASSWORD';"
conn.Open sConnString

我的代码：

...

Function BlockInjectCode(StrVal)
    BlockInjectCode = Replace(StrVal,"--","")
    BlockInjectCode = Replace(BlockInjectCode,"'","")
    BlockInjectCode = Replace(BlockInjectCode,"""","")
    if instr(lcase(BlockInjectCode),"<") > 0 then
        BlockInjectCode = ""
    end if
End Function

    x = BlockInjectCode(Request.QueryString("rid"))
    uid = BlockInjectCode(Request.QueryString("uid"))
    chkcode = BlockInjectCode(Request.QueryString("Code"))
    CheckPro = BlockInjectCode(Request.QueryString("pro"))
    CheckProProd = BlockInjectCode(Request.QueryString("prod"))
    CheckProMac = BlockInjectCode(Request.QueryString("mac"))
    MacAdd = CheckProMac

    CodeValid = False

    if x <> "" and uid <> "" then

        '-- Get information about this registration code.   
        sqlStr = "select * from MYTABLE where Code = ? and IsValid = 1"

        set cmdCodes = Server.CreateObject("ADODB.Command")
        Set cmdCodes.ActiveConnection = Conn
        cmdCodes.CommandText = sqlStr
        with cmdCodes
            .Parameters.Append .CreateParameter("@code", adVarChar, 1, 50, x)
        end With    
        Set rsCodes = cmdCodes.execute      
...

【问题讨论】：

你需要给 adVarChar 一个值，它现在是空的并且是无效的。使用文档：w3schools.com/asp/met_comm_createparameter.asp。 adVarChar 的值应该是 200。我实际上有一个很好的函数，它可以使用 VarType 自动执行此操作，当我备份我的 VM 并关闭源代码时，我会为你发布它。

此外，如果您在导致错误的页面的第一行添加 ，它将打开严格的变量检查并在未定义变量时抛出错误，这会告诉你确定 adVarChar 是否在任何地方都没有价值。

@Ryios 我不建议在global.asa 中定义它们，尽管您可以我的建议是让 IIS 直接从类型库为您加载它们，这样您就不必再定义了只需将METADATA 指令添加到页面/global.asa。

如果可以的话，我实际上是 .net 开发人员，mvc 5/6，nuget 等。我正在进行的这个项目是公司最后一个经典项目，做出的决定在我对任何事情有发言权之前，这已经过去了。由于我们在生产中还有大量其他经典的 asp 东西，所以我现在制作的东西在清理不良代码并使其更容易移植到 .net 或 java spring 时派上用场。

您可能只是遇到了问题，因为旧服务器上的应用程序池可能设置为经典模式，而新服务器上的应用程序池可能是集成模式。或者，新的应用程序池可能在 64 位模式下运行，而应用程序依赖于只有 32 位版本的 dll，因此它需要在 32 位模式下运行才能工作。也有可能您在 global.asa 中的 typelib 元数据标记为 ADO 指的是新服务器上不存在的 ado DLL，这在您的错误上下文中更有意义。

【参考方案1】：

常见的情况可能是您没有定义adVarChar，因此CreateParameter() 方法是“未正确定义”。

这只是 ADODB 库中众多命名常量之一的示例。处理此问题的一种混乱方法是自己定义值；

Const adVarChar = 200

这种方法的问题是您必须定义所有命名常量，这可能会让人头疼。另一种方法是跳过整个命名常量，只使用整数值，所以调用是；

.Parameters.Append .CreateParameter("@code", 200, 1, 50, x)

然而，这并不容易阅读，尽管看起来您已经使用 1 的 ParameterDirectionEnum 值来执行此操作，这是 ADODB 库中的命名常量 adParamInput。无论如何，我不会推荐这种方法。

更好的方法是使用#include 指令，以便它在调用页面中包含您可能想要的所有命名常量定义，这就是大多数人的做法。微软为此目的提供了一个预定义的文件 IIS（或者可能是我不确定的 MDAC 库安装），称为 adovbs.inc 或 adovbs.asp，包括您的页面将可以访问此文件中的所有命名常量定义。

这一切的原因是 VBScript 不支持类型库，因此在 Client 场景中您自己定义它们或从 adovbs.inc 文件复制和粘贴是您唯一的选择。然而，在 Server 场景中，我们仍然拥有 IIS 的强大功能，它可以让我们做一些时髦的事情。

如果类型库可以只添加一次并且您不必担心它，那不是很好吗？不需要定义烦人的常量？让我们面对现实，它们已经存在于类型库中，那么为什么我们不能从那里得到它们呢？事实证明，我们可以感谢 METADATA 指令。

这是一个例子；

<!--
   METADATA    
   TYPE="TypeLib"    
   NAME="Microsoft ActiveX Data Objects 2.5 Library"    
   UUID="00000205-0000-0010-8000-00AA006D2EA4"    
   VERSION="2.5"
-->

这种方法的美妙之处在于您可以用于任何类型库（理想情况下暴露给 COM） 并且您可以在一个页面中定义，或者将其添加到 global.asa 中以在整个整个 Web 应用程序。

通过这种方法，您可以安全地使用类似的代码；

.Parameters.Append .CreateParameter("@code", adVarChar, adParamInput, 50, x)

---

有用的链接

VBScript ADO Programming Answer to ASP 3.0 Declare ADO Constants w/out Including ADOVBS.inc Answer to Passing Parameters to a Stored Procedure using ASP Using METADATA to Import DLL Constants

【讨论】：

我已经有一个包含的配置文件，其中定义了 adVarChar 就像这样在考虑我的代码 sn-p 时遗漏了。

@nosajimiki 很好，但是这个答案不只是适合你。

这是很棒的建议，与 OP 无关，但 MetaData 标签从我正在开发的应用程序中删除了一大堆讨厌的声明代码。另外要补充的是，参数化查询确实可以在经典 asp 中使用，但您不能使用该名称。经典的 asp 只支持 ?查询中的通配符基本上会按照参数添加到命令对象的顺序来获取参数。因此，您可以将 CreateParameter 的名称（第一个参数）留空。除非你知道我不知道不同的通配符。例如“where email = @email”不起作用，但“where email = ？”是的。

@Ryios 从 ADO 2.6 开始，您可以使用 ADODB.Command 属性 NamedParameters 允许您按名称查询参数。但并非所有提供商都支持它。

啊，所以也许 postgresql 不支持它，只能使用问号。

【参考方案2】：

在您定义 adVarChar 和其他 ADO 幻数的地方，完全去掉它们。

而是将其添加到 global.asa 的顶部（如果不存在，则创建一个）。

<!--METADATA TYPE="TypeLib" file="C:\Program Files (x86)\Common Files\System\ado\msado15.dll" -->

这将导入已经定义了所有这些幻数的 msado15 类型库。它会自动为您提取所有定义。这意味着您不必自己定义 adVarChar 等，元数据标签会自动为您导入它们。这要归功于@Lankymart，因为他的评论让我发现并弄清楚了这一点，而且效果很好。

现在，转而创建一个空的测试 asp 页面，并在选项显式打开的情况下向其中添加一些测试代码。

<%
    Option Explicit
    Response.Write "adVarChar: " & adVarChar
%>

如果您收到未定义 adVarChar 的错误，则表明 msado15.dll 不在服务器上。因此，您需要联系 godaddy 等，让他们告诉您那里的任何版本的 MSADO 的路径，并更改您的元数据标记以引用正确的版本。

【讨论】：

哪个部分修复了它？添加 msado15.dll 元数据标签，还是发现服务器上没有 ado15？如果是元数据标签，请将答案交给 LankyMart，因为如果他没有在评论中提到它，我什至不知道该怎么做。我是事后才知道的:)

这是 msado15.dll。是的，我同意 Lankymart 发现了这个问题，但我发现这个答案对于那些对 ASP 不太了解的人来说要清楚得多；所以，向你们两个竖起大拇指，感谢你们的帮助。谢谢。