如何获取所有使用的命名空间的列表？
Posted
技术标签:
【中文标题】如何获取所有使用的命名空间的列表？【英文标题】：How to get a list of all used namespaces? 【发布时间】：2011-04-14 09:45:58 【问题描述】：我正在编写一个 XSLT 1.0 样式表来将多名称空间 XML 文档转换为 html。在结果 HTML 中的某个位置，我想列出文档中出现的所有命名空间。
这可能吗？
我想过类似的事情
<xsl:for-each select="//*|//@*">
<xsl:value-of select="namespace-uri(.)" />
</xsl:for-each>
但我当然会得到数以百万计的重复。所以我必须以某种方式过滤我已经打印的内容。
递归调用模板可以，但我不知道如何访问所有元素。
直接访问//@xmlns:* 不起作用，因为无法通过XPath 访问它（不允许将任何前缀绑定到xmlns: 命名空间）。
【问题讨论】：
好问题 (+1)。请参阅我的答案以获得简短而有效的解决方案。 :) 我刚刚在我的答案中添加了一个 XSLT 2.0 解决方案——只是为了完整性。 【参考方案1】：另一个没有扩展功能的：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="*">
<xsl:param name="pNamespaces" select="'
'"/>
<xsl:variable name="vNamespaces">
<xsl:variable name="vMyNamespaces">
<xsl:value-of select="$pNamespaces"/>
<xsl:for-each select="namespace::*
[not(contains(
$pNamespaces,
concat('
',.,'
')))]">
<xsl:value-of select="concat(.,'
')"/>
</xsl:for-each>
</xsl:variable>
<xsl:variable name="vChildsNamespaces">
<xsl:apply-templates select="*[1]">
<xsl:with-param name="pNamespaces"
select="$vMyNamespaces"/>
</xsl:apply-templates>
</xsl:variable>
<xsl:value-of select="concat(substring($vMyNamespaces,
1 div not(*)),
substring($vChildsNamespaces,
1 div boolean(*)))"/>
</xsl:variable>
<xsl:variable name="vFollowNamespaces">
<xsl:apply-templates select="following-sibling::*[1]">
<xsl:with-param name="pNamespaces" select="$vNamespaces"/>
</xsl:apply-templates>
</xsl:variable>
<xsl:value-of
select="concat(substring($vNamespaces,
1 div not(following-sibling::*)),
substring($vFollowNamespaces,
1 div boolean(following-sibling::*)))"/>
</xsl:template>
</xsl:stylesheet>
输出（带有 Dimitre 的输入样本）：
http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3
编辑：也是这个 XPath 表达式：
//*/namespace::*[not(. = ../../namespace::*|preceding::*/namespace::*)]
作为证明，这个样式表：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:for-each select="//*/namespace::*
[not(. = ../../namespace::*|
preceding::*/namespace::*)]">
<xsl:value-of select="concat(.,'
')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
输出：
http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3
编辑 4： 与两次转换的效率相同。
这个样式表：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:key name="kElemByNSURI"
match="*[namespace::*[not(. = ../../namespace::*)]]"
use="namespace::*[not(. = ../../namespace::*)]"/>
<xsl:template match="/">
<xsl:for-each select=
"//namespace::*[not(. = ../../namespace::*)]
[count(..|key('kElemByNSURI',.)[1])=1]">
<xsl:value-of select="concat(.,'
')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
输出：
http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3
编辑 5：当您处理没有namespace ax 实现的XSLT 处理器（如TransforMiix）时，您只能提取实际用于此样式表的命名空间：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:key name="kElemByNSURI" match="*|@*" use="namespace-uri()"/>
<xsl:template match="/">
<xsl:for-each select=
"(//*|//@*)[namespace-uri()!='']
[count(.|key('kElemByNSURI',namespace-uri())[1])=1]">
<xsl:value-of select="concat(namespace-uri(),'
')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
TransforMiix 输出：
mynamespace2
【讨论】：
@Alejandro：正确答案 +1。我们都知道不使用xxx:node-set() 会导致效率更低的解决方案:)
+1 用于避免扩展的解决方案。我正在研究一个使用字符串来累积命名空间 URI 的方法，但你的可能更好。
感谢您的解决方案！我错过了namespace:: 轴，我总是忘记了<xsl:key/>（尤其是当它的使用非常有价值时）。
@Boldewyn：你很高兴！很高兴它对您有所帮助。
@Alejandro：很好的解决方案，但是用 count 检查集合成员的效率仍然很低。如果有人需要最有效的解决方案（如果要找到唯一的命名空间，这是必须的，因为文档中有太多的命名空间节点），使用两遍的方法就是答案。【参考方案2】：
这种转变：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:for-each select=
"//namespace::*[not(. = ../../namespace::*)]">
<xsl:value-of select="concat(.,'
')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
应用于此 XML 文档时：
<authors xmlns:user="mynamespace">
<?ttt This is a PI ?>
<author xmlns:user2="mynamespace2">
<name idd="VH">Victor Hugo</name>
<user2:name idd="VH">Victor Hugo</user2:name>
<nationality xmlns:user3="mynamespace3">French</nationality>
</author>
</authors>
产生想要的正确结果：
http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3
更新：
正如@svick 所评论的，上述解决方案仍会偶尔产生重复的命名空间，例如以下 XML 文档：
<authors xmlns:user="mynamespace">
<?ttt This is a PI ?>
<author xmlns:user2="mynamespace2">
<name idd="VH">Victor Hugo</name>
<user2:name idd="VH">Victor Hugo</user2:name>
<nationality xmlns:user3="mynamespace3">French</nationality>
</author>
<t xmlns:user2="mynamespace2"/>
</authors>
命名空间"mynamespace2" 将在输出中生成两次。
以下转换解决了这个问题：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
exclude-result-prefixes="ext">
<xsl:output method="text"/>
<xsl:key name="kNSbyURI" match="n" use="."/>
<xsl:template match="/">
<xsl:variable name="vrtfNS">
<xsl:for-each select=
"//namespace::*[not(. = ../../namespace::*)]">
<n><xsl:value-of select="."/></n>
</xsl:for-each>
</xsl:variable>
<xsl:variable name="vNS" select="ext:node-set($vrtfNS)/*"/>
<xsl:for-each select=
"$vNS[generate-id()
=
generate-id(key('kNSbyURI',.)[1])
]">
<xsl:value-of select="concat(., '
')"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
当对上述 XML 文档应用此转换时，它只会生成文档中所有唯一的命名空间：
http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3
第二部分：XSLT 2.0 解决方案。
XSLT 2.0 解决方案是一个简单的 XPath 2.0 单行：
distinct-values(//namespace::*)
【讨论】：
在两个地方定义一个命名空间时，这将无法正常工作：<root><node xmlns="ns" /><node xmlns="ns" /></root>。
@svick：很好的收获！我现在已经解决了这个问题。
感谢您的回答！我一直在寻找非 EXSLT 解决方案，因为我需要模板是跨引擎可执行的。但如果我将来某个时候在 XSLT 2.0 中重写它，我会回来使用节点集解决方案。
谢谢。我还没有意识到在 XSLT 2.0 中会这么简单。以上是关于如何获取所有使用的命名空间的列表？的主要内容，如果未能解决你的问题，请参考以下文章