通过拖动鼠标滚动图像

Posted 2023-05-08

【中文标题】通过拖动鼠标滚动图像

【英文标题】：Scrolling the image by dragging the mouse

【发布时间】：2011-08-06 02:23:06

【问题描述】：

当我使用水平和垂直滚动条时，图像会滚动。但我想像在 Photoshop 中一样通过拖动来滚动图像（使用手动工具并浏览缩放的图像）。在 Visual Basic 6.0 中有什么方法可以这样做吗？我已将鼠标的默认光标更改为手形光标。现在我只想通过拖动图像来滚动。

【参考方案1】：

简单，您只需要处理包含您的图像的控件的鼠标事件。我将使用我编写的应用程序中的生产代码逐步引导您完成此完全相同的功能。

从MouseDown 事件开始。在这里，您需要检查哪个按钮被按下（如果您想允许仅使用左键、左右键或仅使用右键进行拖动），请将鼠标光标更改为闭合或合拢的手（表示正在进行拖动），并设置一些成员变量来跟踪光标的起始坐标。示例：

Private Sub picBox_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
    ' When left mouse button is pressed down (initiating a drag)
    If Button = 1 Then
        ' Store the coordinates of the mouse cursor
        xpos = x
        ypos = y

        ' Change the cursor to hand grab icon
        picBox.MouseIcon = LoadPicture(App.Path & "\Resources\Cursors\grab.ico")
    End If
End Sub

然后，您将处理MouseMove 事件，您将在该事件中进行实际拖动（在图片框内移动图像）。在示例中，我选择简单地在容器 Form 上移动整个图片框控件，而不是在图片框内移动图像。您可能需要在此处更改逻辑，具体取决于表单的布局和您的特定需求。例如，您说您有滚动条——在这种情况下，您需要在此处调整 X 和 Y 滚动条的位置。

Private Sub picBox_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
    ' When left mouse button is being held down (drag)
    If Button = 1 Then
        ' Drag the picture box around the form
        picBox.Move x + (picBox.Left - xpos), y + (picBox.Top - ypos)
    End If
End Sub

最后，您需要处理MouseUp 事件，您将通过重置光标来结束拖动：

Private Sub picBox_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
    ' Stop normal dragging
    If Button = 1 Then
        ' Set the cursor back to the unclapsed hand
        picBox.MouseIcon = LoadPicture(App.Path & "\Resources\Cursors\hand.ico")
    End If
End Sub

当然，您需要将这些成员变量添加到 Form 类的顶部，以跟踪光标的 previous 位置（在 x 和 y 坐标中）。像这样简单的事情：

Private xpos As Long
Private ypos As Long

光标看起来像这样，类似于您在 Adob​​e Acrobat 或 Mac OS 9 中发现的（可能最初是由像 Susan Kare 这样的魔术师绘制的；可能不在公共领域）：