VBA 处理多种自定义数据类型的可能性

Posted 2023-02-16

【中文标题】VBA 处理多种自定义数据类型的可能性

【英文标题】：VBA Handling multiple custom datatype possibilities

【发布时间】：2018-07-24 12:02:19

【问题描述】：

我做了一些研究，没有发现任何类似的问题。

我有一个 VBA 宏，它可以导入一个 .CSV 文件，其中包含设备发送的电报。

在这个宏的末尾，我想创建一个图表，其中 x 轴上已用的时间和对应于电报的值。

问题是这个值可以是不同的类型：十六进制、布尔值、整数......而且它们不遵守标准的 Excel 数字格式，这意味着它们不能用于创建图形。 以下是一些示例（在值周围使用 " 以显示其开始和结束）：

十六进制：“A7 C8” 布尔值：“$00”或“$01” 百分比：“30 美元”

And here is an example of data, with custom time format and boolean value

到目前为止，这是我的相关代码，我尝试转换为自定义类型，然后转换回数字以获取通用数字数据类型：

If wsRes.Range("R1").Value Like "$##" Then
    wsRes.Range("R1:R" & plotLine).NumberFormat = "$##"
    wsRes.Range("R1:R" & plotLine).NumberFormat = General
End If

If wsRes.Range("R1").Value Like "??[ ]??" Then
    Dim valArray(1) As String
    For i = 1 To plotLine Step 1
        valArray = Split(wsRes.Range("R" & i), " ")
        wsRes.Range("R" & i).Value = ToInt32(valArray(0) + valArray(1), 16)
        wsRes.Range("" & i).NumberFormat = General
    Next i
End If

我还不能用 hexa 对其进行测试，但是转换技巧不适用于百分比/布尔值

编辑：

首先，感谢您的回答。

这是我为所有感兴趣的人准备的最终代码，改编自 Vityata 的。

如果需要，此方法将允许轻松添加其他数据类型。

Sub TestMe()
    Dim RangeData as String
    Set wsRes = ActiveWorkbook.Sheets("Results")

    For i = 1 To plotLine Step 1  'plotLine is the last line on which I have data
        DetectType wsRes.Range("R" & i).Value, i
    Next i

    RangeData = "Q1:R" & plotLine
    CreateGraph RangeData 'Call My sub creating the graph
End Sub



Public Sub DetectType(str As String, i As Integer)

    Select Case True
        Case wsRes.Range("R" & i).Value Like "??[ ]??"
            wsRes.Range("R" & i).Value = HexValue(str)

        Case wsRes.Range("R" & i).Value Like "?##"
            wsRes.Range("R" & i).Value = DecValue(str)

        Case Else
            MsgBox "Unsupported datatype detected : " & str
            End
    End Select

End Sub



Public Function HexValue(str As String) As Long
    Dim valArray(1) As String 'Needed as I have a space in the middle that prevents direct conversion
    valArray(0) = Split(str, " ")(0)
    valArray(1) = Split(str, " ")(1)
    HexValue = CLng("&H" & valArray(0) + valArray(1))
End Function


Public Function DecValue(str As String) As Long
    DecValue = Right(str, 2)
End Function

【问题讨论】：

欢迎来到 Stack Overflow：请阅读 How to ask a good question，然后编辑您的问题并确保询问 good, clear, concise question，包括代码、预期行为以及问题所在......然后我们可以尝试帮助

我认为有可能，如果您编写 3 个布尔函数，取决于变量是否为 IsHex()、IsBoolean() 和“IsPercentage()”。

您可以在单元格内的字符串上使用条件，例如将字符串的某些部分与left 或instr if left("$01", 1)="$" then ... 进行比较，这是一种可能性，但你有什么到目前为止，我们可以帮助您编写代码？

更新了我使用的相关代码

【参考方案1】：

您需要三个布尔函数，遵循您的业务逻辑和一些Clean Code principles (although the author of the book does not recognize VBA people as programmers)：

IsHex() IsBoolean() IsPercentage()

---

Public Sub TestMe()

    Dim myInput As Variant
    myInput = Array("A7C8", "$01", "$30")        
    Dim i As Long        
    For i = LBound(myInput) To UBound(myInput)
        Debug.Print IsHex(myInput(i))
        Debug.Print IsBoolean(myInput(i))
        Debug.Print IsPercentage(myInput(i))
        Debug.Print "-------------"
    Next i        
    'or use this with the DetectType() function below:
    'For i = LBound(myInput) To UBound(myInput)
    '    Debug.Print DetectType(myInput(i))
    'Next i

End Sub

Public Function IsHex(ByVal str As String) As Boolean    
    On Error GoTo IsHex_Error       
    IsHex = (WorksheetFunction.Hex2Dec(str) <> vbNullString)        
    On Error GoTo 0
    Exit Function    
IsHex_Error:    
End Function

Public Function IsBoolean(ByVal str As String) As Boolean
    IsBoolean = CBool((str = "$00") Or (str = "$01"))
End Function

Public Function IsPercentage(ByVal str As String) As Boolean
    IsPercentage = (Len(str) = 3 And Left(str, 1) = "$" And IsNumeric(Right(str, 2)))
End Function

---

然后需要一些额外的逻辑，因为 $01 既是 布尔值 又是 百分比。在这种情况下，您可以将其视为百分比。这是某种映射器，遵循以下业务逻辑：

Public Function DetectType(str) As String

    Select Case True
        Case IsHex(str)
            DetectType = "HEX!"
        Case IsPercentage(str) And IsBoolean(str)
            DetectType = "Boolean!"
        Case IsPercentage(str)
            DetectType = "Percentage!"
        Case Else
            DetectType = "ELSE!"
    End Select

End Function

【讨论】：

我想澄清一下你所说的关于干净代码的内容：我无法访问整本书，但似乎其中一个原则是尽量减少函数的数量。在这种情况下，在 TestMe() 中简单地使用 3 个 IF 语句来进行测试不是更好吗？

@mickael - 原则之一是尽可能多地编写函数并使它们专门化。因此，与其将三个 IsHex()、IsBoolean() 和 IsPercentage() 组合在一个函数/子中，但最好将其放入 3 中。顺便说一句，这是一本不错的书（不属于附属）。

该视频并没有明确表明他“不承认 VBA 人是程序员”。充其量，他将 VBA 程序员边缘化，但我认为任何花费大量时间编写软件的人都不会严重贬低 VBA 程序员作为程序员。我想说问题更多在于 VBA 与 MS Office 的关系中的可访问性，因为您可以仅通过简单地记录宏来学习引用，但实际上并不能学习如何在 VBA 中正确编程，甚至无法使用 VBA 的所有工具必须提供。这些类型的人应该打折，但不是整个班级。

@Jaberwocky - idk，一般人都反对 VBA 程序员。但是，我通常不在乎，但是当它来自 R.C.M.然后有点奇怪。不过，这本书真的很不错，值得一读。如果不是因为它，我的答案应该是一个功能。

@Vityata 我没有将他的评论解释为仇恨。我将他的评论解释为边缘化，因为 VBA 组真的可以分解为真正的程序员，否则不能；大概是40/60分割。我买了它用，作者没有利润:)。但是，我不会因为作者的狙击而阻止自己进一步发展。