如何为我的引导加载程序制作内核？
Posted
技术标签:
【中文标题】如何为我的引导加载程序制作内核？【英文标题】：How to make the kernel for my bootloader? 【发布时间】：2016-02-09 18:53:22 【问题描述】：我正在尝试制作自己的自定义操作系统，我需要一些关于我的代码的帮助。 这是我的 bootloader.asm：
[ORG 0x7c00]
start:
cli
xor ax, ax
mov ds, ax
mov ss, ax
mov es, ax
mov [BOOT_DRIVE], dl
mov bp, 0x8000
mov sp, bp
mov bx, 0x9000
mov dh, 5
mov dl, [BOOT_DRIVE]
call load_kernel
call enable_A20
call graphics_mode
lgdt [gdtr]
mov eax, cr0
or al, 1
mov cr0, eax
jmp CODE_SEG:init_pm
[bits 32]
init_pm:
mov ax, DATA_SEG
mov ds, ax
mov ss, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ebp, 0x90000
mov esp, ebp
jmp 0x9000
[BITS 16]
graphics_mode:
mov ax, 0013h
int 10h
ret
load_kernel:
; load DH sectors to ES:BX from drive DL
push dx ; Store DX on stack so later we can recall
; how many sectors were request to be read ,
; even if it is altered in the meantime
mov ah , 0x02 ; Bios read sector function
mov al , dh ; Read DH sectors
mov ch , 0x00 ; Select cylinder 0
mov dh , 0x00 ; Select head 0
mov cl , 0x02 ; Start reading from second sector ( i.e.
; after the boot sector )
int 0x13 ; BIOS interrupt
jc disk_error ; Jump if error ( i.e. carry flag set )
pop dx ; Restore DX from the stack
cmp dh , al ; if AL ( sectors read ) != DH ( sectors expected )
jne disk_error ; display error message
ret
disk_error :
mov bx , ERROR_MSG
call print_string
hlt
[bits 32]
; prints a null - terminated string pointed to by EDX
print_string :
pusha
mov edx , VIDEO_MEMORY ; Set edx to the start of vid mem.
print_string_loop :
mov al , [ ebx ] ; Store the char at EBX in AL
mov ah , WHITE_ON_BLACK ; Store the attributes in AH
cmp al , 0 ; if (al == 0) , at end of string , so
je print_string_done ; jump to done
mov [edx] , ax ; Store char and attributes at current
; character cell.
add ebx , 1 ; Increment EBX to the next char in string.
add edx , 2 ; Move to next character cell in vid mem.
jmp print_string_loop ; loop around to print the next char.
print_string_done :
popa
ret ; Return from the function
[bits 16]
; Variables
ERROR_MSG db "Error!" , 0
BOOT_DRIVE: db 0
VIDEO_MEMORY equ 0xb8000
WHITE_ON_BLACK equ 0x0f
%include "a20.inc"
%include "gdt.inc"
times 510-($-$$) db 0
db 0x55
db 0xAA
我用这个编译它：
nasm -f bin -o boot.bin bootloader.asm
这是kernel.c：
call_main()main();
void main()
我用这个编译它：
gcc -ffreestanding -o kernel.bin kernel.c
然后：
cat boot.bin kernel.bin > os.bin
我想知道我做错了什么，因为当我使用 QEMU 进行测试时，它不起作用。有人可以提供一些提示来改进kernel.c，这样我就不必使用 call_main() 函数了吗？
测试时我使用：
qemu-system-i386 -kernel os.bin
我的其他文件
a20.inc：
enable_A20:
call check_a20
cmp ax, 1
je enabled
call a20_bios
call check_a20
cmp ax, 1
je enabled
call a20_keyboard
call check_a20
cmp ax, 1
je enabled
call a20_fast
call check_a20
cmp ax, 1
je enabled
mov bx, [ERROR]
call print_string
enabled:
ret
check_a20:
pushf
push ds
push es
push di
push si
cli
xor ax, ax ; ax = 0
mov es, ax
not ax ; ax = 0xFFFF
mov ds, ax
mov di, 0x0500
mov si, 0x0510
mov al, byte [es:di]
push ax
mov al, byte [ds:si]
push ax
mov byte [es:di], 0x00
mov byte [ds:si], 0xFF
cmp byte [es:di], 0xFF
pop ax
mov byte [ds:si], al
pop ax
mov byte [es:di], al
mov ax, 0
je check_a20__exit
mov ax, 1
check_a20__exit:
pop si
pop di
pop es
pop ds
popf
ret
a20_bios:
mov ax, 0x2401
int 0x15
ret
a20_fast:
in al, 0x92
or al, 2
out 0x92, al
ret
[bits 32]
[section .text]
a20_keyboard:
cli
call a20wait
mov al,0xAD
out 0x64,al
call a20wait
mov al,0xD0
out 0x64,al
call a20wait2
in al,0x60
push eax
call a20wait
mov al,0xD1
out 0x64,al
call a20wait
pop eax
or al,2
out 0x60,al
call a20wait
mov al,0xAE
out 0x64,al
call a20wait
sti
ret
a20wait:
in al,0x64
test al,2
jnz a20wait
ret
a20wait2:
in al,0x64
test al,1
jz a20wait2
ret
gdt.inc：
gdt_start:
dd 0 ; null descriptor--just fill 8 bytes dd 0
gdt_code:
dw 0FFFFh ; limit low
dw 0 ; base low
db 0 ; base middle
db 10011010b ; access
db 11001111b ; granularity
db 0 ; base high
gdt_data:
dw 0FFFFh ; limit low (Same as code)
dw 0 ; base low
db 0 ; base middle
db 10010010b ; access
db 11001111b ; granularity
db 0 ; base high
end_of_gdt:
gdtr:
dw end_of_gdt - gdt_start - 1 ; limit (Size of GDT)
dd gdt_start ; base of GDT
CODE_SEG equ gdt_code - gdt_start
DATA_SEG equ gdt_data - gdt_start
【问题讨论】：
你应该提供一个完整的例子。例如，您的问题中没有a20.inc 和 gdt.inc 文件。
您没有设置 SS（堆栈段）。在您的 16 位代码中（在 cli 之后）
您可能希望看到我给出的关于 bootloaders 的答案。特别是第 1 项。您应该将 DS 设置为 0（类似于 xor ax, axmov ds, ax）。您至少需要确保 DS 设置为 0，因为您已将 ORG 设置为 0x7c00。 BIOS 不能保证在加载时设置了 SS/DS/ES。 DL 将启动驱动器号，物理地址 0x00007c00 将是代码执行的开始位置。 不要假设其他任何事情都是有效的或你所期望的
你能提供一个实际编译的bootloader.asm、gdt.inc和a20.inc吗？例如ox90000 是一个错误，应该是`0x90000（它甚至不应该编译）。 %include 指令应该在它们周围加上引号等。关键是您需要提供给我们的代码至少应该可供 nasm 使用。 a20.inc 中也缺少一些函数。
gcc -ffreestanding -o kernel.bin kernel.c 是错误的。这不会创建平面二进制文件。它输出一个精灵对象。你的代码有很多问题，我认为你需要找到一个关于创建引导加载程序和内核的好教程。
【参考方案1】：
存在许多问题，但总的来说，您的汇编代码确实有效。我写了一个 *** 答案，其中包含 general bootloader development 的提示。
不要假设段寄存器设置正确
您问题中的原始代码没有设置 SS 堆栈段寄存器。我给出的提示 #1 是：
当 BIOS 跳转到您的代码时，您不能依赖 CS、DS、ES、SS、SP 具有有效或预期值的寄存器。他们应该被设置 当您的引导加载程序启动时适当地进行。
如果你需要ES，它也应该被设置。虽然在您的代码中似乎并非如此（除了我稍后将讨论的 print_string 函数）。
正确定义 GDT
阻止您进入保护模式的最大错误是您在 gdt.inc 中设置了全局描述符表 (GDT)，其开头为：
gdt_start:
dd 0 ; null descriptor--just fill 8 bytes dd 0
每个全局描述符需要 8 个字节，但 dd 0 只定义 4 个字节（双字）。应该是：
gdt_start:
dd 0 ; null descriptor--just fill 8 bytes
dd 0
实际上似乎第二个dd 0 被意外添加到了上一行的注释末尾。
在 16 位实模式下不要使用 32 位代码
您编写了一些print_string 代码，但它是 32 位代码：
[bits 32]
; prints a null - terminated string pointed to by EBX
print_string :
pusha
mov edx , VIDEO_MEMORY ; Set edx to the start of vid mem.
print_string_loop :
mov al , [ ebx ] ; Store the char at EBX in AL
mov ah , WHITE_ON_BLACK ; Store the attributes in AH
cmp al , 0 ; if (al == 0) , at end of string , so
je print_string_done ; jump to done
mov [edx] , ax ; Store char and attributes at current
; character cell.
add ebx , 1 ; Increment EBX to the next char in string.
add edx , 2 ; Move to next character cell in vid mem.
jmp print_string_loop ; loop around to print the next char.
print_string_done :
popa
ret ; Return from the function
您调用 print_string 作为 16 位代码中的错误处理程序，因此您在此处执行的操作可能会强制重启计算机。您不能使用 32 位寄存器和寻址。通过一些调整，代码可以变成 16 位：
; prints a null - terminated string pointed to by EBX
print_string :
pusha
push es ;Save ES on stack and restore when we finish
push VIDEO_MEMORY_SEG ;Video mem segment 0xb800
pop es
xor di, di ;Video mem offset (start at 0)
print_string_loop :
mov al , [ bx ] ; Store the char at BX in AL
mov ah , WHITE_ON_BLACK ; Store the attributes in AH
cmp al , 0 ; if (al == 0) , at end of string , so
je print_string_done ; jump to done
mov word [es:di], ax ; Store char and attributes at current
; character cell.
add bx , 1 ; Increment BX to the next char in string.
add di , 2 ; Move to next character cell in vid mem.
jmp print_string_loop ; loop around to print the next char.
print_string_done :
pop es ;Restore ES that was saved on entry
popa
ret ; Return from the function
主要区别（在 16 位代码中）是我们不再使用 EAX 和 EDX 32 位寄存器。为了访问视频内存@0xb8000，我们需要使用一个表示相同事物的段：偏移量对。 0xb8000可以表示为段：偏移量0xb800:0x0（计算为(0xb8000xb8000物理地址。我们可以利用这些知识将 b800 存储在 ES 寄存器中，并使用 DI 寄存器作为偏移量来更新显存。我们现在使用：
mov word [es:di], ax
将单词移动到视频内存中。
组装和链接内核和引导加载程序
您在构建内核时遇到的一个问题是您没有正确生成可以直接加载到内存中的平面二进制图像。我建议不要使用gcc -ffreestanding -o kernel.bin kernel.c，而是这样做：
gcc -g -m32 -c -ffreestanding -o kernel.o kernel.c -lgcc
ld -melf_i386 -Tlinker.ld -nostdlib --nmagic -o kernel.elf kernel.o
objcopy -O binary kernel.elf kernel.bin
这会将 kernel.c 组装成带有调试信息 (-g) 的 kernel.o。然后，链接器获取 kernel.o（32 位 ELF 二进制文件）并生成一个名为 kernel.elf的 ELF 可执行文件>（如果你想调试你的内核，这个文件会很方便）。然后，我们使用 objcopy 获取 ELF32 可执行文件 kernel.elf 并将其转换为平面二进制图像 kernel.bin 可以通过以下方式加载BIOS。需要注意的一个关键点是，使用 -Tlinker.ld 选项，我们要求 LD（链接器）从文件 linker.ld 中读取选项。这是一个简单的linker.ld，您可以使用它开始：
OUTPUT_FORMAT(elf32-i386)
ENTRY(main)
SECTIONS
. = 0x9000;
.text : *(.text)
.data : *(.data)
.bss : *(.bss) *(COMMON)
这里要注意的是. = 0x9000 告诉链接器它应该生成一个可执行文件，该可执行文件将被加载到内存地址 0x9000 。 0x9000 是您似乎将内核放在问题中的位置。其余的行使 C 部分可用，这些部分需要包含在内核中才能正常工作。
我建议在使用 NASM 时做类似的事情，所以不要这样做 nasm -f bin -o boot.bin bootloader.asm 这样做：
nasm -g -f elf32 -F dwarf -o boot.o bootloader.asm
ld -melf_i386 -Ttext=0x7c00 -nostdlib --nmagic -o boot.elf boot.o
objcopy -O binary boot.elf boot.bin
这类似于编译 C 内核。我们在这里不使用链接器脚本，但我们确实告诉链接器生成我们的代码，假设代码（引导加载程序）将在 0x7c00 处加载。
为此，您需要从 bootloader.asm 删除这一行：
[ORG 0x7c00]
清理内核 (kernel.c)
将您的 kernel.c 文件修改为：
/* This code will be placed at the beginning of the object by the linker script */
__asm__ (".pushsection .text.start\r\n" \
"jmp main\r\n" \
".popsection\r\n"
);
/* Place main as the first function defined in kernel.c so
* that it will be at the entry point where our bootloader
* will call. In our case it will be at 0x9000 */
int main()
/* Do Stuff Here*/
return 0; /* return back to bootloader */
在 bootloader.asm 中，我们应该调用 main 函数（将被放置在 0x9000）而不是跳转到它。而不是：
jmp 0x9000
改成：
call 0x9000
cli
loopend: ;Infinite loop when finished
hlt
jmp loopend
调用后的代码会在C函数main返回时执行。这是一个简单的循环，可以有效地停止处理器并无限期地保持这种状态，因为我们无处可去。
进行所有建议更改后的代码
bootloader.asm：
[bits 16]
global _start
_start:
cli
xor ax, ax
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0x8000 ; Stack pointer at SS:SP = 0x0000:0x8000
mov [BOOT_DRIVE], dl; Boot drive passed to us by the BIOS
mov dh, 17 ; Number of sectors (kernel.bin) to read from disk
; 17*512 allows for a kernel.bin up to 8704 bytes
mov bx, 0x9000 ; Load Kernel to ES:BX = 0x0000:0x9000
call load_kernel
call enable_A20
; call graphics_mode ; Uncomment if you want to switch to graphics mode 0x13
lgdt [gdtr]
mov eax, cr0
or al, 1
mov cr0, eax
jmp CODE_SEG:init_pm
graphics_mode:
mov ax, 0013h
int 10h
ret
load_kernel:
; load DH sectors to ES:BX from drive DL
push dx ; Store DX on stack so later we can recall
; how many sectors were request to be read ,
; even if it is altered in the meantime
mov ah , 0x02 ; BIOS read sector function
mov al , dh ; Read DH sectors
mov ch , 0x00 ; Select cylinder 0
mov dh , 0x00 ; Select head 0
mov cl , 0x02 ; Start reading from second sector ( i.e.
; after the boot sector )
int 0x13 ; BIOS interrupt
jc disk_error ; Jump if error ( i.e. carry flag set )
pop dx ; Restore DX from the stack
cmp dh , al ; if AL ( sectors read ) != DH ( sectors expected )
jne disk_error ; display error message
ret
disk_error :
mov bx , ERROR_MSG
call print_string
hlt
; prints a null - terminated string pointed to by EDX
print_string :
pusha
push es ;Save ES on stack and restore when we finish
push VIDEO_MEMORY_SEG ;Video mem segment 0xb800
pop es
xor di, di ;Video mem offset (start at 0)
print_string_loop :
mov al , [ bx ] ; Store the char at BX in AL
mov ah , WHITE_ON_BLACK ; Store the attributes in AH
cmp al , 0 ; if (al == 0) , at end of string , so
je print_string_done ; jump to done
mov word [es:di], ax ; Store char and attributes at current
; character cell.
add bx , 1 ; Increment BX to the next char in string.
add di , 2 ; Move to next character cell in vid mem.
jmp print_string_loop ; loop around to print the next char.
print_string_done :
pop es ;Restore ES that was saved on entry
popa
ret ; Return from the function
%include "a20.inc"
%include "gdt.inc"
[bits 32]
init_pm:
mov ax, DATA_SEG
mov ds, ax
mov ss, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ebp, 0x90000
mov esp, ebp
call 0x9000
cli
loopend: ;Infinite loop when finished
hlt
jmp loopend
[bits 16]
; Variables
ERROR db "A20 Error!" , 0
ERROR_MSG db "Error!" , 0
BOOT_DRIVE: db 0
VIDEO_MEMORY_SEG equ 0xb800
WHITE_ON_BLACK equ 0x0f
times 510-($-$$) db 0
db 0x55
db 0xAA
gdt.inc：
gdt_start:
dd 0 ; null descriptor--just fill 8 bytes
dd 0
gdt_code:
dw 0FFFFh ; limit low
dw 0 ; base low
db 0 ; base middle
db 10011010b ; access
db 11001111b ; granularity
db 0 ; base high
gdt_data:
dw 0FFFFh ; limit low (Same as code)
dw 0 ; base low
db 0 ; base middle
db 10010010b ; access
db 11001111b ; granularity
db 0 ; base high
end_of_gdt:
gdtr:
dw end_of_gdt - gdt_start - 1 ; limit (Size of GDT)
dd gdt_start ; base of GDT
CODE_SEG equ gdt_code - gdt_start
DATA_SEG equ gdt_data - gdt_start
a20.inc：
enable_A20:
call check_a20
cmp ax, 1
je enabled
call a20_bios
call check_a20
cmp ax, 1
je enabled
call a20_keyboard
call check_a20
cmp ax, 1
je enabled
call a20_fast
call check_a20
cmp ax, 1
je enabled
mov bx, [ERROR]
call print_string
enabled:
ret
check_a20:
pushf
push ds
push es
push di
push si
cli
xor ax, ax ; ax = 0
mov es, ax
not ax ; ax = 0xFFFF
mov ds, ax
mov di, 0x0500
mov si, 0x0510
mov al, byte [es:di]
push ax
mov al, byte [ds:si]
push ax
mov byte [es:di], 0x00
mov byte [ds:si], 0xFF
cmp byte [es:di], 0xFF
pop ax
mov byte [ds:si], al
pop ax
mov byte [es:di], al
mov ax, 0
je check_a20__exit
mov ax, 1
check_a20__exit:
pop si
pop di
pop es
pop ds
popf
ret
a20_bios:
mov ax, 0x2401
int 0x15
ret
a20_fast:
in al, 0x92
or al, 2
out 0x92, al
ret
[bits 32]
[section .text]
a20_keyboard:
cli
call a20wait
mov al,0xAD
out 0x64,al
call a20wait
mov al,0xD0
out 0x64,al
call a20wait2
in al,0x60
push eax
call a20wait
mov al,0xD1
out 0x64,al
call a20wait
pop eax
or al,2
out 0x60,al
call a20wait
mov al,0xAE
out 0x64,al
call a20wait
sti
ret
a20wait:
in al,0x64
test al,2
jnz a20wait
ret
a20wait2:
in al,0x64
test al,1
jz a20wait2
ret
kernel.c：
/* This code will be placed at the beginning of the object by the linker script */
__asm__ (".pushsection .text.start\r\n" \
"jmp main\r\n" \
".popsection\r\n"
);
/* Place main as the first function defined in kernel.c so
* that it will be at the entry point where our bootloader
* will call. In our case it will be at 0x9000 */
int main()
/* Do Stuff Here*/
return 0; /* return back to bootloader */
linker.ld
OUTPUT_FORMAT(elf32-i386)
ENTRY(main)
SECTIONS
. = 0x9000;
.text : *(.text.start) *(.text)
.data : *(.data)
.bss : *(.bss) *(COMMON)
使用 DD 创建磁盘映像/使用 QEMU 进行调试
如果您使用上述文件，并使用这些命令生成所需的引导加载程序和内核文件（如前所述）
nasm -g -f elf32 -F dwarf -o boot.o bootloader.asm
ld -melf_i386 -Ttext=0x7c00 -nostdlib --nmagic -o boot.elf boot.o
objcopy -O binary boot.elf boot.bin
gcc -g -m32 -c -ffreestanding -o kernel.o kernel.c -lgcc
ld -melf_i386 -Tlinker.ld -nostdlib --nmagic -o kernel.elf kernel.o
objcopy -O binary kernel.elf kernel.bin
您可以使用以下命令生成磁盘映像（在本例中，我们会将其设置为软盘大小）：
dd if=/dev/zero of=disk.img bs=512 count=2880
dd if=boot.bin of=disk.img bs=512 conv=notrunc
dd if=kernel.bin of=disk.img bs=512 seek=1 conv=notrunc
这将创建一个大小为 512*2880 字节（1.44 兆字节软盘大小）的零填充磁盘映像。 dd if=boot.bin of=disk.img bs=512 conv=notrunc 将 boot.bin 写入文件的第一个扇区，而不截断磁盘映像。 dd if=kernel.bin of=disk.img bs=512 seek=1 conv=notrunc 将 kernel.bin 放入磁盘映像中，从第二个扇区开始。 seek=1 在写入之前跳过第一个块 (bs=512)。
如果你想运行你的内核，你可以像这样在 QEMU 中将它作为软盘驱动器 A: (-fda) 启动：
qemu-system-i386 -fda disk.img
您还可以使用 QEMU 和 GNU 调试器 (GDB) 调试您的 32 位内核，并使用我们在使用说明编译/组装代码时生成的调试信息更多。
qemu-system-i386 -fda disk.img -S -s &
gdb kernel.elf \
-ex 'target remote localhost:1234' \
-ex 'layout src' \
-ex 'layout reg' \
-ex 'break main' \
-ex 'continue'
此示例使用远程调试器启动 QEMU，并使用文件 disk.img（我们使用 DD 创建）模拟软盘。 GDB 使用 kernel.elf（我们使用调试信息生成的文件）启动，然后连接到 QEMU，并在 function main( ) 在 C 代码中。当调试器最终准备就绪时，系统会提示您按<return> 继续。运气好的话，您应该在调试器中查看函数 main。
【讨论】：
感谢您的精彩回复。我会检查代码并希望它有效。 :)以上是关于如何为我的引导加载程序制作内核？的主要内容，如果未能解决你的问题，请参考以下文章
如何将控制从我的引导加载程序转移到位于硬盘驱动器中的应用程序
如何为 Wix 刻录引导程序 exepackage 添加依赖文件夹