启用 oracle 约束的问题

Posted 2023-03-28

【中文标题】启用 oracle 约束的问题

【英文标题】：Problem to enable oracle constraints

【发布时间】：2011-06-16 14:39:36

【问题描述】：

我尝试了几天来禁用所有表的约束、插入数据并启用约束。它可以工作，但我做了一些测试，当我插入不尊重外键的行时，启用约束时没有错误消息。我所能看到的是，该约束没有得到验证。

这是禁用的代码

begin    
     BEGIN
      FOR rec IN ( SELECT constraint_name, table_name FROM user_constraints WHERE  constraint_type = 'R' OR constraint_type = 'P' )
      LOOP
        BEGIN
        EXECUTE IMMEDIATE 'alter table '||rec.table_name||' disable constraint '||rec.constraint_name;
         EXCEPTION WHEN OTHERS THEN
             dbms_output.put_line( 'ERROR: alter table '||rec.table_name||' DISABLE constraint '||rec.constraint_name||';' );
        END;      
      END LOOP;
      DBMS_OUTPUT.PUT_LINE('CONSTRAINTS DISABLED');
     END;
     BEGIN
     FOR rec IN ( SELECT trigger_name FROM user_triggers WHERE TRIGGER_NAME NOT LIKE 'BIN$%' )
      LOOP
            EXECUTE IMMEDIATE 'alter trigger '||rec.trigger_name||' disable';
      END LOOP;
    END;
    DBMS_OUTPUT.PUT_LINE('TRIGGERS DISABLED');
end;    
/

这是启用的代码

begin
  BEGIN
      FOR rec IN ( SELECT constraint_name, table_name FROM user_constraints where status = 'DISABLED' and constraint_type = 'R' OR constraint_type = 'P' )
      LOOP
        BEGIN
          EXECUTE IMMEDIATE 'alter table '||rec.table_name||' enable constraint '||rec.constraint_name;
          dbms_output.put_line('alter table '||rec.table_name||' enable constraint '||rec.constraint_name);
        EXCEPTION
          WHEN OTHERS THEN
            dbms_output.put_line('ERROR: alter table '||rec.table_name||' enable constraint '||rec.constraint_name||' ;' );

        END;
      END LOOP;
    END;
                DBMS_OUTPUT.PUT_LINE('CONSTRAINTS ENABLED');
    BEGIN
      FOR rec IN ( SELECT trigger_name FROM user_triggers WHERE TRIGGER_NAME NOT LIKE 'BIN$%' )
      LOOP
          EXECUTE IMMEDIATE 'alter trigger '||rec.trigger_name||' enable';
      END LOOP;
    END;
                DBMS_OUTPUT.PUT_LINE('TRIGGERS ENABLED');
END;

我不知道最后如何检查所有约束，如果不起作用则回滚。

【问题讨论】：

如果数据最终必须遵守这些约束，为什么要禁用约束？

因为我加载了很多带有数据的xml文件并且我没有按好顺序插入它们，所以需要太长时间。

【参考方案1】：

首先，您的代码会捕获无法启用约束时引发的错误，并且会丢弃该错误而不是重新引发该错误。这几乎总是一个错误。如果你不想忽略启用约束失败的事实，你会想要类似

FOR rec IN ( SELECT constraint_name, 
                    table_name 
               FROM user_constraints 
              where status = 'DISABLED' 
                and constraint_type = 'R' 
                 OR constraint_type = 'P' )
LOOP
  BEGIN
    l_sql_stmt := 'alter table '||rec.table_name||
                  ' enable constraint ' || rec.constraint_name;
    dbms_output.put_line( l_sql_stmt );
    EXECUTE IMMEDIATE l_sql_stmt;
  EXCEPTION
    WHEN OTHERS THEN
      dbms_output.put_line('ERROR: ' || l_sql_stmt );
      raise; -- re-raise the exception
  END;
END LOOP;

因为 ALTER TABLE 是 DDL，所以不能回滚。如果您在启用一个约束时遇到错误，则无法回滚所有先前约束的启用。

根据您上次的更新，听起来您可能根本不想禁用和启用约束。您可能只是想创建可延迟的约束。

SQL> create table foo (
  2    col1 number
  3  );

Table created.

SQL> ed
Wrote file afiedt.buf

  1  alter table foo
  2    add constraint pk_foo
  3        primary key( col1 )
  4*       deferrable
SQL> /

Table altered.

通常，它的行为类似于任何其他主键约束

SQL> insert into foo values( 1 );

1 row created.

SQL> insert into foo values( 1 );
insert into foo values( 1 )
*
ERROR at line 1:
ORA-00001: unique constraint (SCOTT.PK_FOO) violated


SQL> rollback;

Rollback complete.

但是，如果您推迟约束，则在您提交之前不会对其进行验证。如果在事务结束时违反了约束，则事务将回滚。

SQL> alter session set constraints = deferred;

Session altered.

SQL> select * from foo;

no rows selected

SQL> insert into foo values( 1 );

1 row created.

SQL> insert into foo values( 1 );

1 row created.

SQL> insert into foo values( 1 );

1 row created.

SQL> commit;
commit
*
ERROR at line 1:
ORA-02091: transaction rolled back
ORA-00001: unique constraint (SCOTT.PK_FOO) violated

【讨论】：

感谢您的快速回复！！所以这是不可能的，因为它是 DDL？

@Marc-Andre - 不可能回滚 DDL，是的。

@Justin Cave 感谢您的快速回复！我从许多 xml 文件中插入数据，但我不知道我将拥有它们的顺序，所以它可能不会在脚本运行时遵守所有约束，但最后，这应该是好的，因为 xml 尊重数据库约束。但这并不安全，因为有人可以编辑文件。有什么我可以做的吗？谢谢

@Marc-Andre - 听起来您可能想让您的约束可延迟，而不是禁用和启用它们。我已经更新了我的答案。

@Alex - 我很确定你不能改变一个不可延迟的约束来将它变成一个可延迟的约束。通常，这将要求基础索引从唯一索引变为非唯一索引，但即使您最初创建约束并指定它使用非唯一索引，您似乎也无法修改约束。您必须删除并重新创建约束。