描述关于关系排序的整数序列的最一般的高阶约束
Posted
技术标签:
【中文标题】描述关于关系排序的整数序列的最一般的高阶约束【英文标题】：Most general higher-order constraint describing a sequence of integers ordered with respect to a relation 【发布时间】：2015-01-15 10:18:41 【问题描述】：在 CLP(FD) 中，我们经常需要声明：“这是按（有时：严格）升序/降序排列的整数和有限域变量的列表。”
是否有任何 CLP(FD) 系统为此任务提供通用（可参数化）内置约束？
SWI-Prolog 提供了一个名为 chain/2 的约束，这与我正在寻找的类似。但是，该名称有点过于具体，无法包含约束可以描述的所有关系（例如：#< 不是偏序但在chain/2 中是可接受的，导致序列（作为一组整数）不再计数作为数学顺序理论中定义的链）。因此，名称并不能完全描述约束实际实现的内容。
请给出关于通常二进制 CLP(FD) 约束的最一般定义 - 或至少包含 #<、#>、#=< 和 @987654327 的合适子集@ — 包括根据约束定义的代数结构的专有名称。施加的条件是约束描述了一个在文献中具有专有名称的实际数学结构。
首先，考虑使用 SICStus Prolog 或 SWI：
:- use_module(library(clpfd)).
connex(Relation_2, List) :-
connex_relation(Relation_2),
connex_(List, Relation_2).
connex_relation(#=).
connex_relation(#<).
connex_relation(#=<).
connex_relation(#>).
connex_relation(#>=).
connex_([], _).
connex_([L|Ls], Relation_2) :-
foldl(adjacent(Relation_2), Ls, L, _).
adjacent(Relation_2, X, Prev, X) :- call(Relation_2, Prev, X).
示例案例：
?- connex(#<, [A,B,C]).
A#=<B+-1,
B#=<C+-1.
?- connex(#=, [A,B,C]).
A = B, B = C,
C in inf..sup.
?- maplist(connex(#<), [[A,B],[C,D]]).
A#=<B+-1,
C#=<D+-1.
请注意，允许#\= 甚至是可以接受的，因为这种关系仍然描述了数学顺序理论中已知的连接。因此，就通常的二进制 CLP(FD) 约束而言，上述代码并不是最通用的。
【问题讨论】：
s(X)！部分目标的命名约定很好 (Relation_2)！
【参考方案1】：
Hoogle 不是很有用，但是Hayoo is!
foldcmpl
所以这是列表的一种特殊折叠形式，但它不适用于 length list 次，而是应用一次。
isSortedBy
在它的名字上并不完全通用，但在它的签名上。也许坚持使用最通用的名称并没有太大帮助。否则我们只是到处都是实体？
定义如下：
如果谓词对列表中的所有相邻元素对返回 true，则 isSortedBy 函数返回 True。
也许：all_adjacent_pairs(R_2, Xs)。在有一个以 adjacent_pair 作为修饰符的循环构造之后，这听起来有点。
【讨论】：
谓词应该在给定的限制下尽可能通用。它的 name 应该尽可能具体，同时仍然包含所有用例。foldcmpl 朝着正确的方向前进（也是字面意思）！ foldadjl ...?【参考方案2】：
这是受到我曾经实现的功能性高阶习语工具箱的启发。那时我发现角落案例很痛苦，我今天仍然这样做:) 另外，找到好名字总是一个问题......
考虑元谓词mapadj/4：
mapadj(Relation_4,As,Bs,Cs) :-
list_list_list_mapadj(As,Bs,Cs,Relation_4).
list_list_list_mapadj([],[],[],_).
list_list_list_mapadj([A|As],Bs,Cs,Relation_4) :-
list_prev_list_list_mapadj(As,A,Bs,Cs,Relation_4).
list_prev_list_list_mapadj([],_,[],[],_).
list_prev_list_list_mapadj([A1|As],A0,[B|Bs],[C|Cs],Relation_4) :-
call(Relation_4,A0,A1,B,C),
list_prev_list_list_mapadj(As,A1,Bs,Cs,Relation_4).
示例用途：
z_z_sum_product(X,Y,Sum,Product) :-
Sum #= X + Y,
Product #= X * Y.
:- mapadj(z_z_sum_product,[], [], []).
:- mapadj(z_z_sum_product,[1], [], []).
:- mapadj(z_z_sum_product,[1,2], [3], [2]).
:- mapadj(z_z_sum_product,[1,2,3], [3,5], [2,6]).
:- mapadj(z_z_sum_product,[1,2,3,4],[3,5,7],[2,6,12]).
我知道角落案例As = [] 和As = [_] 的分歧，但我仍然觉得这与“所有相邻列表项”一样接近。
此外，所有这些都可以轻松扩展：
下至mapadj/2（类似于chain/2，除了单例列表的类型检查）
侧面，带有额外的状态参数，foldadjl/n，scanadjl/n
关于名称：IMO 需要 l / r 后缀与 fold / scan，但不是 map。
编辑 2015-04-26
前面提到的foldadjl/4来了：
foldadjl(Relation_4,Xs) -->
list_foldadjl(Xs,Relation_4).
list_foldadjl([],_) -->
[].
list_foldadjl([X|Xs],Relation_4) -->
list_prev_foldadjl(Xs,X,Relation_4).
list_prev_foldadjl([],_,_) -->
[].
list_prev_foldadjl([X1|Xs],X0,Relation_4) -->
call(Relation_4,X0,X1),
list_prev_foldadjl(Xs,X1,Relation_4).
编辑 2015-04-27
元谓词splitlistIfAdj/3，基于
if_/3 在a previous answer 中提出
关于具体化。
split_if_adj(P_3,As,Bss) :- splitlistIfAdj(P_3,As,Bss).
splitlistIfAdj(P_3,As,Bss) :-
list_split_(As,Bss,P_3).
list_split_([],[],_).
list_split_([X0|Xs], [Cs|Bss],P_3) :-
list_prev_split_(Xs,X0,Cs,Bss, P_3).
list_prev_split_([], X, [X],[],_).
list_prev_split_([X1|Xs],X0,[X0|Cs],Bss,P_3) :-
if_(call(P_3,X0,X1),
(Cs = [], Bss = [Cs0|Bss0]),
(Cs = Cs0, Bss = Bss0)),
list_prev_split_(Xs,X1,Cs0,Bss0,P_3).
为了在使用中展示它，让我们定义 dif/3 与 (=)/3 完全相同的方式，但具有翻转的真值：
dif(X, Y, R) :- X == Y, !, R = false.
dif(X, Y, R) :- ?=(X, Y), !, R = true. % syntactically different
dif(X, Y, R) :- X \= Y, !, R = true. % semantically different
dif(X, Y, R) :- R == false, !, X = Y.
dif(X, X, false).
dif(X, Y, true) :-
dif(X, Y).
现在我们将它们串联使用：
?- splitlistIfAdj(dif,[1,2,2,3,3,3,4,4,4,4],Pss).
Pss = [[1],[2,2],[3,3,3],[4,4,4,4]]. % succeeds deterministically
如果我们概括一些列表项会怎样？对于正确的未决目标，我们是否得到了多个答案？
首先，一个小例子：
?- splitlistIfAdj(dif,[1,X,2],Pss).
X = 1, Pss = [[1,1],[2]] ;
X = 2, Pss = [[1],[2,2]] ;
dif(X,1),dif(X,2), Pss = [[1],[X],[2]].
一个更大的例子，涉及两个变量X 和Y。
?- splitlistIfAdj(dif,[1,2,2,X,3,3,Y,4,4,4],Pss).
X = 2, Y = 3, Pss = [[1],[2,2,2],[3,3,3],[4,4,4]] ;
X = 2, Y = 4, Pss = [[1],[2,2,2],[3,3],[4,4,4,4]] ;
X = 2, dif(Y,3),dif(Y,4), Pss = [[1],[2,2,2],[3,3],[Y],[4,4,4]] ;
X = Y, Y = 3, Pss = [[1],[2,2],[3,3,3,3],[4,4,4]] ;
X = 3, Y = 4, Pss = [[1],[2,2],[3,3,3],[4,4,4,4]] ;
X = 3, dif(Y,3),dif(Y,4), Pss = [[1],[2,2],[3,3,3],[Y],[4,4,4]] ;
dif(X,2),dif(X,3), Y = 3, Pss = [[1],[2,2],[X],[3,3,3],[4,4,4]] ;
dif(X,2),dif(X,3), Y = 4, Pss = [[1],[2,2],[X],[3,3],[4,4,4,4]] ;
dif(X,2),dif(X,3), dif(Y,3),dif(Y,4), Pss = [[1],[2,2],[X],[3,3],[Y],[4,4,4]].
编辑 2015-05-05
这里是tpartition/4：
tpartition(P_2,List,Ts,Fs) :- tpartition_ts_fs_(List,Ts,Fs,P_2).
tpartition_ts_fs_([],[],[],_).
tpartition_ts_fs_([X|Xs0],Ts,Fs,P_2) :-
if_(call(P_2,X), (Ts = [X|Ts0], Fs = Fs0),
(Ts = Ts0, Fs = [X|Fs0])),
tpartition_ts_fs_(Xs0,Ts0,Fs0,P_2).
使用示例：
?- tpartition(=(0), [1,2,3,4,0,1,2,3,0,0,1], Ts, Fs).
Ts = [0, 0, 0],
Fs = [1, 2, 3, 4, 1, 2, 3, 1].
编辑 2015-05-15
继续，...这里是splitlistIf/3：
split_if(P_2,As,Bss) :- splitlistIf(P_2,As,Bss).
splitlistIf(P_2,As,Bss) :-
list_pred_split(As,P_2,Bss).
list_pred_split([],_,[]).
list_pred_split([X|Xs],P_2,Bss) :-
if_(call(P_2,X), list_pred_split(Xs,P_2,Bss),
(Bss = [[X|Ys]|Bss0], list_pred_open_split(Xs,P_2,Ys,Bss0))).
list_pred_open_split([],_,[],[]).
list_pred_open_split([X|Xs],P_2,Ys,Bss) :-
if_(call(P_2,X), (Ys = [], list_pred_split(Xs,P_2,Bss)),
(Ys = [X|Ys0], list_pred_open_split(Xs,P_2,Ys0,Bss))).
让我们使用它：
?- splitlistIf(=(x),[x,1,2,x,1,2,3,x,1,4,x,x,x,x,1,x,2,x,x,1],Xs).
Xs = [[1, 2], [1, 2, 3], [1, 4], [1], [2], [1]].
【讨论】：
非常感谢这个有用的元谓词列表，+1！对于这个具体的问题，我只搜索一个名字，所以我想你建议mapadj/2?这肯定会奏效。我看到两个仍然悬而未决的问题：(a) mapadj/2 对“排序”以外的任何关系有用吗？并且 (b) mapadj/2 没有命名像 connex/2 这样的实际出现的结构，这在 CLP(FD) 约束的上下文中很有意义，所以在这个意义上谓词 (name) 是 too 一般。【参考方案3】：
与较早的答案中提出的mapadj/4 非常相似...也许这个名字更好。
forallAdj(P_2,Xs) :-
list_forallAdj(Xs,P_2).
list_forallAdj([],_).
list_forallAdj([X|Xs],P_2) :-
list_forallAdj_prev(Xs,P_2,X).
list_forallAdj_prev([],_,_).
list_forallAdj_prev([X1|Xs],P_2,X0) :-
call(P_2,X0,X1),
list_forallAdj_prev(Xs,P_2,X1).
使用示例：
:- use_module(library(clpfd)).
:- use_module(library(lambda)).
?- Ls = [0,_,_,_,_,_], forallAdj(\X0^X1^(X0 + 1 #= X1), Ls).
Ls = [0, 1, 2, 3, 4, 5].
这能带我们去哪里？
forallAdj => existAdj
可能带有索引（forallAdjI，existAdjI）的变体，例如Collections.List Module (F#)
findfirstAdj/pickfirstAdj也喜欢F# find/pick
【讨论】：
F# 中没有类型类吗？许多功能的要求似乎非常ad hoc - 只是一些静态成员的存在。所以静态成员似乎有一个全局语义范围。我理解正确吗？ here 我希望我们可以在类型类中拥有一些东西——至少在概念层面上。以上是关于描述关于关系排序的整数序列的最一般的高阶约束的主要内容，如果未能解决你的问题，请参考以下文章