Excel - 查找和替换多个单词

Posted 2023-03-11

【中文标题】Excel - 查找和替换多个单词

【英文标题】：Excel - Find and replace multiple words

【发布时间】：2012-10-27 02:54:53

【问题描述】：

我只想对多个字符串进行简单的查找和替换。例如，我需要将所有“A1”、“A2”、“A3”替换为“system”，将所有“B1”、“B2”替换为“ACC”等等......

有谁知道好路线吗？我只是不确定如何开始。感谢您的帮助！

【问题讨论】：

“A2”是字符串还是单元格引用？

【参考方案1】：

在底部更新迈克尔的评论，这是许多模式替换的更好方法

如果您使用 Excel 菜单中的手动 Replace 选项录制一个简单的宏，您将获得可以整理的代码

第一个选项将更新ActiveSheet 中的单元格，而不是将包含"I am A1" 的单元格更新为"I am System" - 部分字符串匹配 第二个选项只会将ActiveSheet 中仅包含"A1" 的单元格更新为"Sytem" - 即整个单元格字符串匹配

代码

Sub UpdatePartial()
With ActiveSheet.UsedRange
.Replace "A1", "System", xlPart
.Replace "A2", "System", xlPart
.Replace "A3", "System", xlPart
.Replace "B1", "ACC", xlPart
.Replace "B2", "ACC", xlPart
End With
End Sub

Sub UpdateWhole()
With ActiveSheet.UsedRange
.Replace "A1", "System", xlWhole
.Replace "A2", "System", xlWhole
.Replace "A3", "System", xlWhole
.Replace "B1", "ACC", xlWhole
.Replace "B2", "ACC", xlWhole
End With
End Sub

更新

下面的代码

使用基本的Timer 来比较替换从A1-A99 和B1-B99 范围内的所有部分 字符串 这两种方法是 上面的Replace方法循环调用了198次（即2*99） 一个RegExp\变体数组组合

在我的测试中，对于 1,000,000 个单元格范围内的 198 个替换，第二种方法更快。

更少的替换将提高Replace 的相对速度。更多关于RegExp 更多单元格也将提高对Replace 的相对速度。少往RegExp

我没有继续尝试稍后解析字符串的Find 方法。作为一种混合类型的解决方案（find then parse ut 不会与单个 replace 或 parse 竞争）

定时器

Sub MainCaller()
Dim dbTime As Double
Dim lngCnt As Long

dbTime = Timer()
For lngCnt = 1 To 99
Call UpdatePartial("A" & lngCnt, "System")
Call UpdatePartial("B" & lngCnt, "System")
Next lngCnt
Debug.Print Timer() - dbTime
dbTime = Timer()
Call RegexReplace("(A|B)[1-99]", "System")
Debug.Print Timer() - dbTime
End Sub

1) 替换子

Sub UpdatePartial(StrIn As String, StrOut As String)
ActiveSheet.UsedRange.Replace StrIn, StrOut, xlPart
End Sub    

2) 正则表达式 - 变体数组子

Sub RegexReplace(StrIn As String, StrOut As String)
    Dim rng1 As Range
    Dim rngArea As Range
    Dim lngRow As Long
    Dim lngCol As Long
    Dim lngCalc As Long
    Dim objReg As Object
    Dim X()


    'On Error Resume Next
    'Set rng1 = Application.InputBox("Select range for the replacement of leading zeros", "User select", Selection.Address, , , , , 8)
    'If rng1 Is Nothing Then Exit Sub
    'On Error GoTo 0

    ActiveSheet.UsedRange
    Set rng1 = ActiveSheet.UsedRange

    'See Patrick Matthews excellent article on using Regular Expressions with VBA
    Set objReg = CreateObject("vbscript.regexp")
    With objReg
    .Pattern = StrIn
    .ignorecase = False
    .Global = True
    End With

   'Speed up the code by turning off screenupdating and setting calculation to manual
   'Disable any code events that may occur when writing to cells
    With Application
        lngCalc = .Calculation
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
        .EnableEvents = False
    End With

    'Test each area in the user selected range

    'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
    For Each rngArea In rng1.Areas
        'The most common outcome is used for the True outcome to optimise code speed
        If rngArea.Cells.Count > 1 Then
           'If there is more than once cell then set the variant array to the dimensions of the range area
           'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
            X = rngArea.Value2
            For lngRow = 1 To rngArea.Rows.Count
                For lngCol = 1 To rngArea.Columns.Count
                    'replace the leading zeroes
                    X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), StrOut)
                Next lngCol
            Next lngRow
            'Dump the updated array back over the initial range
            rngArea.Value2 = X
        Else
            'caters for a single cell range area. No variant array required
            rngArea.Value = objReg.Replace(rngArea.Value, StrOut)
        End If
    Next rngArea

    'cleanup the Application settings
    With Application
        .ScreenUpdating = True
        .Calculation = lngCalc
        .EnableEvents = True
    End With

    Set objReg = Nothing
End Sub

【讨论】：

如果我只想在一列中更新它怎么办？我会在活动表中使用类似 Columns("C:C") 的东西吗？

您可以使用With ActiveSheet.Columns("A:A") 而不是ActiveSheet.UsedRange。但是在运行之前，您应该通过 xl 菜单将查找和替换选项设置为 worksheet 而不是 workbook

如果你使用 Regex，你只需要写两个替换语句。您将搜索 A[0-9]1,2，而不是 A1、A2、A3。这将找到 A1-A99。与 B 相同：B[0-9]1,2。这样，如果您的数据集变大/变小，您就不必一直编写替换语句。

@tmoore82 除了 OP 没有要求从 A1-A99 匹配。另外，您实际上不能直接将 Regexp 与 Excel VBA 替换一起使用。

@brettdj 太棒了！看到不同的方法排列在一起真的很有用。感谢上学！ :)