使用 XSLT 从同一输入 XML 中提取的最新日期更新输入 XML

Posted 2023-02-16

【中文标题】使用 XSLT 从同一输入 XML 中提取的最新日期更新输入 XML

【英文标题】：Update an input XML with latest date extracted from same input XML using XSLT

【发布时间】：2021-10-09 03:31:01

【问题描述】：

输入 XML 如下。我需要从日期字段中提取最新日期的输出 xml，并使用最大日期值更新日期字段。

<?xml version="1.0" encoding="UTF-8"?><rsp:response xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<rsp:period>
    <res:Period>
        <rsp:date>2020-07-06T19:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-05-06T19:18:39</rsp:date>
    </res:Period>
</rsp:period></rsp:response>

下面是用于输入 xml 的 XLST

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rsp="rsp.com/employee/Response/v30">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

<xsl:template
    match="*[local-name() = 'response']/*[local-name() = 'period']/*[local-name() = 'Period']/*[local-name() = 'date']">
    <xsl:copy>
        <xsl:apply-templates/>
        <xsl:copy-of select="*[local-name() = 'date']"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/">
    <xsl:for-each
        select="*[local-name() = 'response']/*[local-name() = 'period']/*[local-name() = 'Period']/*[local-name() = 'date']">

        <xsl:sort select="translate(., '-T:Z', '')" data-type="number"/>
        <xsl:choose>
            <xsl:when test="position() = last()">
                <xsl:copy-of select="."/>
            </xsl:when>
        </xsl:choose>

    </xsl:for-each>
</xsl:template></xsl:stylesheet>

以下是此 XSLT 的输出。它能够提取最新日期，但无法更新传入日期字段值中的最新提取日期。

<rsp:date xmlns:xs="http://www.w3.org/2001/XMLSchema"
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
      xmlns:rsp="rsp.com/employee/Response/v30"
      xmlns:res="res.com/Member/details/v1">2020-08-07T20:38:39</rsp:date>

下面是预期的输出

<?xml version="1.0" encoding="UTF-8"?><rsp:response xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period></rsp:response>

【参考方案1】：

我建议你这样处理：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="max-date">
    <xsl:for-each select="/rsp:response/rsp:period/res:Period">
        <xsl:sort select="rsp:date"/>
        <xsl:choose>
            <xsl:when test="position() = last()">
                <xsl:value-of select="rsp:date"/>
            </xsl:when>
        </xsl:choose>
    </xsl:for-each>
</xsl:variable>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="rsp:date">
    <xsl:copy>
        <xsl:value-of select="$max-date"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

---

注意：

没有必要使用像*[local-name()='response'] 这样的hack（正如你已经在your previous question 上被告知的那样）；

ISO 8601 日期将按原样正确排序为文本。