通过 XSLT 在 XML 中格式化日期

Posted 2023-02-16

【中文标题】通过 XSLT 在 XML 中格式化日期

【英文标题】：Format a date in XML via XSLT

【发布时间】：2010-10-04 19:04:34

【问题描述】：

当我使用XML序列化器序列化一个DateTime时，它是这样写的：

<Date>2007-11-14T12:01:00</Date>

当通过 XSLT 样式表传递它以输出 html 时，我如何格式化它？在大多数情况下，我只需要日期，而当我需要时间时，我当然不希望出现“有趣的 T”。

【问题讨论】：

说明您的版本和 XSLT 平台非常重要

很可能是 XSLT 1.0 和 .NET，因为问题是用 C# 标记的

你试过使用内置功能吗？ msdn.microsoft.com/en-us/library/ms256099.aspx

【参考方案1】：

您可以使用以下几个 1.0 模板：-

<xsl:template name="formatDate">
    <xsl:param name="dateTime" />
    <xsl:variable name="date" select="substring-before($dateTime, 'T')" />
    <xsl:variable name="year" select="substring-before($date, '-')" />
    <xsl:variable name="month" select="substring-before(substring-after($date, '-'), '-')" />
    <xsl:variable name="day" select="substring-after(substring-after($date, '-'), '-')" />
    <xsl:value-of select="concat($day, ' ', $month, ' ', $year)" />
</xsl:template>

<xsl:template name="formatTime">
    <xsl:param name="dateTime" />
    <xsl:value-of select="substring-after($dateTime, 'T')" />
</xsl:template>

打电话给他们：-

    <xsl:call-template name="formatDate">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

和

    <xsl:call-template name="formatTime">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

其中 xpath 是具有标准日期时间格式的元素或属性的路径。

【讨论】：

XSLT 很烂。您的解决方案很优雅，但我们当然不应该手工制作日期格式化例程。

@Ryan：我同意，XSLT 2 对日期处理有更好的支持。不幸的是，即使现在 HTML 浏览器的安装基础也很少支持它。

@AnthonyWJones：这是一个严重的轻描淡写，XSLT 2.0 在动态语言之外非常薄弱。其中大部分是 Java 和一些 .NET。我们没有用于 XSLT 2.0 的 libXSLT，否则会将 XSLT 带到少数浏览器中。一旦存在 FOSS 和高效的 C/C++ XSLT 2.0 库，并且跨平台依赖程度相当低，我们就会看到浏览器支持。

【参考方案2】：

日期格式化在 XSLT 1.0 中并不容易。可能最优雅的方法是用 C# 编写一个简短的 XSLT 扩展函数来格式化日期。这是一个例子：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:myExtension="urn:myExtension"
                exclude-result-prefixes="msxsl myExtension">
  <xsl:output method="xml" indent="yes"/>

  <msxsl:script implements-prefix="myExtension" language="C#">
    <![CDATA[
      public string FormatDateTime(string xsdDateTime, string format)
      
          DateTime date = DateTime.Parse(xsdDateTime);
          return date.ToString(format); 
      

    ]]>
  </msxsl:script>

  <xsl:template match="date">
    <formattedDate>
      <xsl:value-of select="myExtension:FormatDateTime(self::node(), 'd')"/>
    </formattedDate>
  </xsl:template>
</xsl:stylesheet>

有了这个输入文件

<?xml version="1.0" encoding="utf-8"?>
<date>2007-11-14T12:01:00</date>

你会得到

<?xml version="1.0" encoding="utf-8"?>
<formattedDate>14.11.2007</formattedDate> 

格式化日期的函数将日期值作为字符串和DateTime.ToString Method 中描述的格式。使用 .NET 的 DateTime 结构，您可以免费解析任意 XSD 日期时间值（包括时区说明符）、时区计算和本地化输出。

但是，请注意有一个带有 msxml 脚本扩展的 caveat (http://support.microsoft.com/kb/316775)：每次加载 XSLT 时，都会动态生成一个包含脚本代码的程序集并将其加载到内存中。由于 .NET 运行时的设计，无法卸载此程序集。这就是为什么您必须确保您的 XSLT 只加载一次（然后缓存起来以供进一步重用）。这在 IIS 中运行时尤其重要。

【讨论】：

是的，这和我用的方法几乎一模一样！

只是对否决票感到好奇：有技术原因吗？还是只是个人不喜欢这种方法？

我投了反对票，因为 msxsl:script 不需要（参见 AnthonyW 的帖子，这是最优雅的解决方案）并且有严重的缺点：tkachenko.com/blog/archives/000620.html。 XSLT 扩展对象比在 .NET 中创建自定义 XSLT 函数更可取，试试吧:)

问题是我提到的问题，实际上通常可以轻松解决。无论如何，出于性能原因，只加载一次 XSLT 是一种很好的做法。 XSLT 扩展对象有一个很大的缺点（至少到目前为止），它们使用后期绑定调用，因此非常慢。

（续） AnthonyW 在我看来也是一个非常优雅（纯）的 XSLT 解决方案，但是支持不同的日期格式需要做更多的工作，因为您没有获得所有 .NET 日期时间的东西免费

【参考方案3】：

John Workman 详细讨论了这个问题，并在他的博客上的 discussion^[1] 中提供了几种解决方案。基本上，解析各个日期组件并按照您希望的任何顺序重新组合。对于您的情况，纯 XSLT 1.0+ 版本将是：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="date">
<!-- converts FROM <date>2001-12-31T12:00:00</date> TO some new format (DEFINED below) -->
<xsl:template name="FormatDate">
<xsl:param name="DateTime" />

<xsl:variable name="year" select="substring($DateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($DateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($DateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<!-- EUROPEAN FORMAT -->
<xsl:value-of select="$day"/>
<xsl:value-of select="'.'"/> <!--18.-->
<xsl:value-of select="$month"/>
<xsl:value-of select="'.'"/> <!--18.03.-->
<xsl:value-of select="$year"/>
<xsl:value-of select="' '"/> <!--18.03.1976 -->
<xsl:value-of select="$hh"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13: -->
<xsl:value-of select="$mm"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13:24 -->
<xsl:value-of select="$ss"/> <!--18.03.1976 13:24:55 -->
<!-- END: EUROPEAN FORMAT -->

</xsl:template>

另一种格式（替换 EUROPEAN FORMAT 部分）：

<!-- Long DATE FORMAT -->
<xsl:choose>
<xsl:when test="$month = '1' or $month= '01'">January</xsl:when>
<xsl:when test="$month = '2' or $month= '02'">February</xsl:when>
<xsl:when test="$month= '3' or $month= '03'">March</xsl:when>
<xsl:when test="$month= '4' or $month= '04'">April</xsl:when>
<xsl:when test="$month= '5' or $month= '05'">May</xsl:when>
<xsl:when test="$month= '6' or $month= '06'">June</xsl:when>
<xsl:when test="$month= '7' or $month= '07'">July</xsl:when>
<xsl:when test="$month= '8' or $month= '08'">August</xsl:when>
<xsl:when test="$month= '9' or $month= '09'">September</xsl:when>
<xsl:when test="$month= '10'">October</xsl:when>
<xsl:when test="$month= '11'">November</xsl:when>
<xsl:when test="$month= '12'">December</xsl:when>
</xsl:choose> 
<xsl:value-of select="' '"/> <!--January -->
<xsl:value-of select="$day"/> <!--January 12 -->
<xsl:value-of select="','"/> <!--January 12,-->
<xsl:value-of select="' '"/> <!--January 12, -->
<xsl:value-of select="$year"/> <!--January 12, 2001-->
<!-- END: Long DATE FORMAT -->

您可以选择任何方式重新组合元素。

[1]http://geekswithblogs.net/workdog/archive/2007/02/08/105858.aspx@@http://archive.is/4Hjep

【讨论】：

我想在这里给你一个很好的评论。你的代码让我头疼不已。

【参考方案4】：

很抱歉对这个旧线程发表评论，但对于像我一样发现它的其他人，如果您使用的是 MS 转换器，您也可以使用 javascript：

声明“msxsl”命名空间：

xmlns:msxsl="urn:schemas-microsoft-com:xslt" 

为你的脚本声明一个命名空间：

xmlns:js="urn:custom-javascript" 

（可选）省略输出中的前缀：

exclude-result-prefixes="msxsl js" 

所以你最终会得到一个像这样的 xsl 声明：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  xmlns:js="urn:custom-javascript"
  exclude-result-prefixes="msxsl js">

在 msxsl:script 元素中编写 JavaScript：

<msxsl:script language="JavaScript" implements-prefix="js"> 
<![CDATA[ 
function javascriptFunction(dateValue)
  var date = new Date(dateValue);
  if(!isNaN(date)) return date.toLocaleString();
  return dateValue;

]]>
</msxsl:script>

调用您的 JavaScript 函数（使用 XPath 语法“.”表示“此节点”）：

<xsl:value-of select="js:javascriptFunction(string(.))"/>

注意：在撰写本文时，似乎没有 (xsl) 方法来包含外部 js 文件（例如 jquery 库）。这可以通过在转换之前解析 xsl 文件服务器端并将 js 文件内容作为字符串添加到 CDATA 部分来完成。我自己开始走这条路，但得出的结论是，如果您需要这种级别的功能，最好将其放置在管道的不同部分。

来源：http://dev.ektron.com/kb_article.aspx?id=482 参考：http://www.ibm.com/developerworks/xml/library/x-tipxsltjs/index.html

【参考方案5】：

更正 roy 的帖子：函数中的日期将始终获得月份值。使用以下内容：

<xsl:variable name="year" select="substring($dateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($dateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($dateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<xsl:value-of select="concat($month,'/',$day,'/',$year,' ',$hh,':',$mm,':',$ss)" />

【参考方案6】：

谢谢，这篇文章很有帮助。

我正在转换使用以下日期格式的 RSS 提要：Mon, 04 Apr 2011 23:18:00 -0700。这是我用来解析它的命名模板。

<!--Parse date format: Mon, 04 Apr 2011 23:18:00 -0700-->
<xsl:template name="formatDate">

    <xsl:param name="dateIn" />

    <xsl:variable name="day" select="substring($dateIn, 0, 3)" />
    <xsl:variable name="date" select="substring($dateIn, 6, 2)" />
    <xsl:variable name="month" select="substring($dateIn, 9, 3)" />
    <xsl:variable name="year" select="substring($dateIn, 13, 4)" />

    <xsl:variable name="hour" select="substring($dateIn, 18, 2)" />
    <xsl:variable name="min" select="substring($dateIn, 21, 2)" />
    <xsl:variable name="sec" select="substring($dateIn, 24, 2)" />

    <xsl:value-of select="concat($date, ' ', $month, ' ', $year, ' ', $hour, ':', $min, ':', $sec)" />

</xsl:template>

【参考方案7】：

<xsl:template match="date">
     <xsl:copy>
         <xsl:call-template name="formatdate">
             <xsl:with-param name="DateTimeStr" select="."/>
        </xsl:call-template>
     </xsl:copy>
  </xsl:template>

  <xsl:template name="formatdate">
     <xsl:param name="DateTimeStr" />

     <!-- input format xslt datetime string -->
     <!-- output format mm/dd/yyyy -->

     <xsl:variable name="datestr">
         <xsl:value-of select="substring-before($DateTimeStr,'T')" />
     </xsl:variable>

     <xsl:variable name="mm">
         <xsl:value-of select="substring($datestr,6,2)" />
     </xsl:variable>

     <xsl:variable name="dd">
        <xsl:value-of select="substring($datestr,9,2)" />
     </xsl:variable>

     <xsl:variable name="yyyy">
        <xsl:value-of select="substring($datestr,1,4)" />
     </xsl:variable>

     <xsl:value-of select="concat($mm,'/', $dd, '/', $yyyy)" />
  </xsl:template>

这对我有用。 您可以在以下位置查看其他选项：

https://blog.fpmurphy.com/2008/05/xslt-datetime-formatting.html