交织 SAS 数据集（按常见患者编号）

Posted 2023-02-16

【中文标题】交织 SAS 数据集（按常见患者编号）

【英文标题】：Interleaving SAS Data Sets (by common patient number)

【发布时间】：2016-06-14 02:39:20

【问题描述】：

我需要交错到 SAS 数据集，但前提是它们都存在患者 ID。在合并语句中，我会使用“in”和“if”，但是，我需要堆叠数据。数据在变量方面是等价的。

有什么想法吗？

【问题讨论】：

不会因为这个技巧而进行内部连接（在 ID 上）吗？

如果 obs 是 FIRST.ID 和 IN 数据集 2，那么数据集 1 中没有 obs。

【参考方案1】：

这有点麻烦，但如果数据集相同，那么您可以尝试以下方法。假设您在变量 ID 上进行匹配。

proc sql;
select t1.*
from
  TABLE_A t1
where ID in (select ID from TABLE_B)
union all
select t2.*
from
  TABLE_B t2  
where ID in (select ID from TABLE_A)
;quit;

【讨论】：

谢谢。但是，它并没有真正起作用，可能是因为我的 SQL 技能。 TABLE_A 是数据吗？ t1.* 是 ??也许我应该提到每个患者 ID 有多个观察结果。

如果您可以举一个小例子说明您现有的输入和输出，那么也许有人可以提出更好的答案:)

【参考方案2】：

如果您在任一数据集上恰好有一行，则在数据步骤中很容易做到这一点。

data have_1;
  do id = 1 to 20 by 2;
    output;
  end;
run;

data have_2;
  do id = 1 to 20 by 3;
    output;
  end;
run;

data want;
  set have_1 have_2;
  by id;
  if not (first.id and last.id);
run;

基本上，如果它不是该 ID 的第一行或不是最后一行，则仅输出一行 - 如果它在两个数据集中都为真，则为真。如果每个 ID 在任一数据集中都有多行，则此方法不起作用。

【参考方案3】：

如果您在一个或两个数据集中的每个 ID 都有重复项，那么您还有很多其他解决方案。这是与您的 MERGE 想法最相似的一个。

在 Double DoW 循环中，您循环遍历数据集两次，一次检查您的条件，然后一次实际输出。这使您可以查看每个 ID 的所有行，查看您的条件是否有效，然后再次查看所有行以针对该条件采取行动。

data have_1;
  do id = 1 to 20 by 2;
    output;
    output;
  end;
run;

data have_2;
  do id = 1 to 20 by 3;
    output;
    output;
  end;
run;



data want;
  _a=0;  *initialize temporary variables;
  _b=0;  *they will be cleared once for each ID;
  do _n_ = 1 by 1 until (last.id);
    set have_1(in=a) have_2(in=b);
    by id;
    if a then _a=1;  *save that value temporarily;
    if b then _b=1;  *again temporary;
  end;
  do _n_ = 1 by 1 until (last.id);
    set have_1 have_2;
    by id;
    if _a and _b then output;  *only output the rows that have both _a and _b;
  end;
run;