Prolog中的列表处理计算以找到朋友将访问的目的地

Posted 2023-02-22

【中文标题】Prolog中的列表处理计算以找到朋友将访问的目的地

【英文标题】：List processing calculation in Prolog to find a destination friends will visit

【发布时间】：2020-03-16 15:52:18

【问题描述】：

我正在尝试编写一个谓词来计算一组朋友将访问的目的地。 朋友们这样列出他们喜欢的国家/地区

choice(marie, [peru,greece,vietnam]). 
choice(jean, [greece,peru,vietnam]). 
choice(sasha, [vietnam,peru,greece]). 
choice(helena,[peru,vietnam,greece]). 
choice(emma, [greece,peru,vietnam]).

我想编写一个名为 where 的谓词，它需要 2 个参数来执行计算。 我想到的公式是，第一个国家值 3 分，第二个国家值 2 分，最后一个国家值 1 分。

这是我想要实现的一个示例。

?- where([marie,jean,sasha,helena,emma],Country). 
peru .

到目前为止我有这个

where([], X).
where([H|T], N) :- choice(H, [A|B]), where(T,N).

它让我可以遍历所有不同的朋友并显示他们的选择，但我无法遍历选择列表并将点分配给目的地。

我应该如何遍历每个朋友的选择列表并分配积分来计算最佳目的地？

【问题讨论】：

你需要一个accumulator. 只是谷歌Prolog accumulator，你会发现很多例子。

【参考方案1】：

虽然这将解决您的问题，但我知道它使用了许多您未见过的谓词。所以想想这是一个让自己脱颖而出并学到很多东西的机会。

即使您不完全理解，测试中也有足够的细节和中间结果，您应该能够导航到您创建的正确解决方案。

而且这绝不是有效的，这只是我做的一个快速概念证明，看看如何做到这一点。

choice(marie, [peru,greece,vietnam]).
choice(jean, [greece,peru,vietnam]).
choice(sasha, [vietnam,peru,greece]).
choice(helena,[peru,vietnam,greece]).
choice(emma, [greece,peru,vietnam]).

destinations(Destinations) :-
    findall(D1,choice(_,D1),D2),
    flatten(D2,D3),
    list_to_set(D3,Destinations).

init_weights(Destinations,Weights) :-
    empty_assoc(Assoc),
    init_weights(Destinations,Assoc,Weights).

init_weights([],Weights,Weights).
init_weights([H|T],Assoc0,Weights) :-
    put_assoc(H,Assoc0,0,Assoc1),
    init_weights(T,Assoc1,Weights).

update_weights([C1,C2,C3],Weights0,Weights) :-
    del_assoc(C1,Weights0,Value0,Weights1),
    Value1 is Value0 + 3,
    put_assoc(C1,Weights1,Value1,Weights2),
    del_assoc(C2,Weights2,Value2,Weights3),
    Value3 is Value2 + 2,
    put_assoc(C2,Weights3,Value3,Weights4),
    del_assoc(C3,Weights4,Value4,Weights5),
    Value5 is Value4 + 1,
    put_assoc(C3,Weights5,Value5,Weights).

person_weight(Person,Weights0,Weights) :-
    choice(Person,[C1,C2,C3]),
    update_weights([C1,C2,C3],Weights0,Weights).

people(People) :-
    findall(Person,choice(Person,_),People).

choice(Destination) :-
    destinations(Destinations),
    init_weights(Destinations,Weights0),
    people(People),
    update_choices(People,Weights0,Weights1),
    cross_ref_assoc(Weights1,Weights),
    max_assoc(Weights, _, Destination),
    true.

cross_ref_assoc(Assoc0,Assoc) :-
    assoc_to_list(Assoc0,List0),
    maplist(key_reverse,List0,List),
    list_to_assoc(List,Assoc).

key_reverse(Key-Value,Value-Key).

update_choices([],Weights,Weights).
update_choices([Person|People],Weights0,Weights) :-
    person_weight(Person,Weights0,Weights1),
    update_choices(People,Weights1,Weights).

测试

:- begin_tests(destination).

test(destinations) :-
    destinations([peru, greece, vietnam]).

test(init_weights) :-
    destinations(Destinations),
    init_weights(Destinations,Weights),
    assoc_to_list(Weights,[greece-0, peru-0, vietnam-0]).

test(update_weights) :-
    destinations(Destinations),
    init_weights(Destinations,Weights0),
    update_weights([peru,greece,vietnam],Weights0,Weights),
    assoc_to_list(Weights,[greece-2,peru-3,vietnam-1]).

test(person_weight) :-
    destinations(Destinations),
    init_weights(Destinations,Weights0),
    person_weight(jean,Weights0,Weights),
    assoc_to_list(Weights,[greece-3,peru-2,vietnam-1]).

test(people) :-
    people([marie,jean,sasha,helena,emma]).

test(update_choices) :-
    destinations(Destinations),
    init_weights(Destinations,Weights0),
    people(People),
    update_choices(People,Weights0,Weights),
    assoc_to_list(Weights,[greece-10,peru-12,vietnam-8]).

test(cross_ref_assoc) :-
    List0 = [1-a,2-b,3-c],
    list_to_assoc(List0,Assoc0),
    cross_ref_assoc(Assoc0,Assoc),
    assoc_to_list(Assoc,[a-1,b-2,c-3]).

test(choice) :-
    choice(peru).

:- end_tests(destination).

【参考方案2】：

正如 GuyCoder 所建议的，您需要一个累加器来汇总每个人的偏好，foldl/N 允许这样做。

choice(marie, [peru,greece,vietnam]).
choice(jean,  [greece,peru,vietnam]).
choice(sasha, [vietnam,peru,greece]).
choice(helena,[peru,vietnam,greece]).
choice(emma,  [greece,peru,vietnam]).

where(People,Where) :-
    foldl([Person,State,Updated]>>(choice(Person,C),update(State,C,Updated)),
          People,
          [0=greece,0=peru,0=vietnam],
          Pref),
    aggregate(max(S,S=W),member(S=W,Pref),max(_,_=Where)).
%    sort(Pref,Sorted),
%    last(Sorted,_=Where).

update(S0,[A,B,C],S3) :-
    update(S0,3,A,S1),
    update(S1,2,B,S2),
    update(S2,1,C,S3).

update(L,V,C,U) :-
    append(X,[Y=C|Z],L),
    P is Y+V,
    append(X,[P=C|Z],U).

我已将最后两个目标的注释留下来替换为单个目标聚合/3，因此您可以尝试理解语法...