如何在我的主要模式挂钩中访问目录局部变量？

Posted 2023-02-21

【中文标题】如何在我的主要模式挂钩中访问目录局部变量？

【英文标题】：How can I access directory-local variables in my major mode hooks?

【发布时间】：2011-07-06 01:06:54

【问题描述】：

我定义了一个 .dir-locals.el 文件，内容如下：

((python-mode . ((cr/virtualenv-name . "saas"))))

在我的 .emacs 中，我有以下函数来检索此值并提供 virtualenv 路径：

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

最后，在我的 python-mode-hook 列表中，我有这个钩子函数：

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

当我打开一个新的 python 文件时，cr/python-mode-shell-setup 记录的消息表明cr/virtualenv-name 是nil。然而，当我 C-h v 这个名字时，我得到的是“saas”。

显然这里存在加载顺序问题；有没有办法让我的模式挂钩语句响应目录局部变量？

【参考方案1】：

这是因为normal-mode 依次调用(set-auto-mode) 和(hack-local-variables)。

但是hack-local-variables-hook是在处理完局部变量之后运行的，这可以实现一些解决方案：

首先是让 Emacs 为每个主要模式运行一个新的“局部变量挂钩”：

(add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
(defun run-local-vars-mode-hook ()
  "Run a hook for the major-mode after the local variables have been processed."
  (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))

(add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)

（通过这种方法，您的原始函数可以不加修改地使用。）

第二种选择是利用add-hook 的可选LOCAL 参数，使指定的函数成为局部缓冲区。使用这种方法，您可以按如下方式编写您的钩子：

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (add-hook 'hack-local-variables-hook
            (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
              (let ((python-base (cr/virtualenv)))
                (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                       (setq python-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command-args '( "-colors" "NoColor")))
                      (t
                       (setq python-python-command (concat python-base "/bin/python"))
                       (setq py-python-command (concat python-base "/bin/python"))
                       (setq py-python-command-args nil)))))
            nil t)) ; buffer-local hack-local-variables-hook

即python-mode-hook 首先运行并为当前缓冲区注册hack-local-variables-hook 的匿名函数；然后在处理完局部变量后调用该函数。

Lindydancer 的评论提示了第三种方法。它不像其他两个那样干净，但无论如何都证明很有趣。我不喜欢导致(hack-local-variables) 被调用两次的想法，但我发现如果您在本地设置local-enable-local-variables 缓冲区，它会阻止(hack-local-variables) 执行任何操作，所以您可以 这样做：

(defun cr/python-mode-shell-setup ()
  (report-errors "File local-variables error: %s"
    (hack-local-variables)))
  (set (make-local-variable 'local-enable-local-variables) nil)
  (let ((python-base (cr/virtualenv)))
    ...))

显然，这会稍微修改正常的执行顺序，因此可能会产生副作用。我担心如果文件中的局部变量 comment 设置了相同的主模式，这可能会导致无限递归，但这实际上似乎不是问题。

局部变量头cmets（例如-*- mode: foo -*-）由(set-auto-mode)处理，所以这些都很好；但是 mode: foo Local Variables: 评论似乎是一个问题，因为它是由 (hack-local-variables) 处理的，所以如果以这种方式设置模式，我认为它会导致递归。

在实践中，我可以通过使用一个简单的函数作为“模式”来触发问题，该模式只不过是尝试运行它的钩子；但是使用“正确”模式进行测试并没有出现问题，因此实际上它可能是安全的。我没有进一步研究这个（因为其他两个解决方案比这更干净），但我猜延迟模式挂钩机制可能解释了它？

【讨论】：

也许您可以从您的钩子中调用 (hack-local-variables)？

看不出方法 #2 的任何缺点，真的