有没有办法使用 vba/macro 一次将多个配置上传到 alm 中的测试用例？

Posted 2023-03-31

【中文标题】有没有办法使用 vba/macro 一次将多个配置上传到 alm 中的测试用例？

【英文标题】：Is there a way to upload multiple configurations at once to a test case in alm using vba/macro?

【发布时间】：2017-07-09 19:02:58

【问题描述】：

我有一种情况，我需要在 HP-ALM（应用程序生命周期管理）中添加多个配置来测试用例。

手动添加 100 多个配置是一项平凡的任务。

有没有办法在 ALM 中为测试用例使用宏/vba 一次上传多个配置？

例如：我有一个测试步骤如下，其中添加了一个参数“字段”，我想在不同的测试用例中使用不同的字段值执行这个测试用例。如果表中有 100 个字段需要验证，我将不得不在 alm.xml 中为单个测试用例手动添加 100 个配置。想知道是否有任何 vba 脚本可以导出放置在 excel 列中的配置并将其映射到指定的测试 id。

在这种情况下，我必须在我的测试用例中为要验证的表中的所有字段（EmpID、EmpName、EmpDesignation 等）添加配置：

config1：Verify_EmpID_in_Table-XYZ config2：Verify_EmpName_in_Table-XYZ config3: Verify_EmpDesignation_in_Table-XYZ

【问题讨论】：

是的，可以使用 OTA。您可以在问题中添加示例配置吗？

我为示例测试用例添加了示例配置。如果要添加更多信息，请告诉我。

【参考方案1】：

下面是使用TestId上传批量配置的代码

Sub Add_Configurations()

Dim qcURL As String
Dim qcID As String
Dim qcPWD As String
Dim qcDomain As String
Dim qcProject As String
Dim tdConnection As Object

On Error GoTo ErrHandler:


   Set cnf = ThisWorkbook.Sheets("config")

   qcURL = cnf.Cells(1, 2)
   qcID = cnf.Cells(2, 2)
   qcPWD = cnf.Cells(3, 2)
   qcDomain = cnf.Cells(4, 2)
   qcProject = cnf.Cells(5, 2)


    Set tdConnection = CreateObject("TDApiOle80.TDConnection")
    tdConnection.InitConnectionEx qcURL
    tdConnection.Login qcID, qcPWD
    tdConnection.Connect qcDomain, qcProject


   lastrow = cnf.Cells(Rows.Count, 5).End(xlUp).Row

   For i = 2 To lastrow
      Test_Id = cnf.Cells(i, 5)
      Set myTest = tdConnection.TestFactory.Item(Test_Id)
      Set aNewConfig = myTest.TestConfigFactory.AddItem(Null)
      aNewConfig.Name = cnf.Cells(i, 6)
      aNewConfig.Post
      Set aNewConfig = Nothing
   Next

MsgBox "Configurations successfully exported to ALM" & Chr(10) & "Please refresh to view the configurations"
Exit Sub

ErrHandler:
MsgBox "!!!!! Error in exporting configurations !!!!!" & Chr(10) & "possible error causes: " & Chr(10) & Chr(10) & "1. Duplicate configuration name" & Chr(10) & "2. Configuration name is blank for a test id"
Exit Sub

End Sub