最后一个参数中的正斜杠导致批处理文件目录的路径（“%~dp0”）改变

Posted 2023-03-07

【中文标题】最后一个参数中的正斜杠导致批处理文件目录的路径（“%~dp0”）改变

【英文标题】：Forward slash in last argument causes path to directory of batch file ("%~dp0") to change

【发布时间】：2017-03-31 11:58:32

【问题描述】：

我正在学习如何在批处理脚本中使用参数，并最终创建了某种模板来读取参数和设置参数

@echo off
SetLocal EnableDelayedExpansion
set needextra=
set errstat=
set noflag=
set param_f=Not set yet
set param_g=You didn't use G-flag

:readARGS
IF [%1] == [] goto :endARGS
call :arg_%1 2> nul
IF ERRORLEVEL 1 call :arg_default %1
SHIFT
IF DEFINED needextra (
    set %needextra%=%~1
    SHIFT
    set needextra=
)
goto :readARGS
:endARGS
echo path to directory of batch script: %~dp0
echo    - noflag:  !noflag!
echo    - param_f: !param_f!
echo    - param_g: !param_g!
EndLocal
exit /b 0

打印目录的第一个回显对我的问题很重要（见下文） 之后，我为每个标志 (arg_/flag) 创建一个函数，并为没有标志的参数创建一个函数 (arg_default)：

:arg_/f           -- flag f: set param_f to value of next argument
set needextra=param_f
exit /b 0

:arg_/g           -- flag g: just set the param_g to a value
set param_g=You used the G-flag
exit /b 0

:arg_default      -- default, neither flag f or g: just set the noflag
echo noflag=%~1
exit /b 0

当我把所有东西都放在一个批处理文件中时，比如说C:\Users\user\scripts\params.bat 并将目录放在我可以执行脚本的路径中：

> params "just an arg"
path to directory of batch script: C:\Users\user\scritpts\
   - noflag:  just an arg
   - param_f: Not set yet
   - param_g: You didn't use G-flag
> params another /G /F "this is f"
path to directory of batch script: C:\Users\user\scritpts\
   - noflag:  another
   - param_f: this is f
   - param_g: You used the G-flag

我把它放在函数中的事实允许我按我希望的任何顺序输入参数，但是如果我把 G 标志放在最后，我会得到这个奇怪的行为：

> params /F "this is f again" bizar /G
path to directory of batch script: C:\
   - noflag:  bizar
   - param_f: this is f again
   - param_g: You used the G-flag

%~dp0 仅返回 C:\！我尝试使用其他参数，将批处理文件移动到另一个目录，在目录中调用它，%~dp0 一直只返回C:\。事实上，每次最后一个参数包含一个“/”时，%~dp0 的行为都会像这个例子一样“奇怪”：

> params /G /F stranger "what happens /here"
path to directory of batch script: C:\Users\user\script\what happens \
   - noflag:  what happens /here
   - param_f: stranger
   - param_g: You used the G-flag

有人可以解释一下为什么会这样吗？我不知道为什么，也无法在网上找到任何东西。我使用的是 Windows 10

非常感谢您提供的任何帮助。

【参考方案1】：

原因

params "just an arg"
params another /G /F "this is f"

工作和这个

params /G /F stranger "what happens /here"
params /F "this is f again" bizar /G

不起作用是......在这两种情况下它都不起作用！

正如 Magoo 指出的那样，您的问题是 shift 命令。默认情况下，它会移动所有参数，因此第十个参数存储在%9，旧的%9存储在%8 ...和%1存储在%0 ，失去对当前批处理文件的引用。

在您的代码中，您正在移动所有参数，直到所有参数都被处理。这将最后一个参数留在%0 中，此时事情变得有趣了。

当请求%~dp0 时，最后一个参数存储在%0 中，并且当我们要求参数中引用的元素的驱动器和文件夹时，cmd 会尝试解决它，假设您知道您的要求for 并且变量包含对文件系统中元素的有效引用，将其转换为绝对路径，然后检索请求的元素。

在这里你遇到了两个案例

%0 只包含一个没有斜杠或反斜杠的简单字符串。 cmd 将其作为存储在当前活动目录中的文件名处理，因此，当您请求驱动器和路径时，将检索当前活动目录的驱动器和路径。在您的“工作”案例中，您以结尾

"C:\Users\user\script\just an arg" -> %~dp0 = "C:\Users\user\script\"
"C:\Users\user\script\this is f"   -> %~dp0 = "C:\Users\user\script\"

%0 包含带有斜杠或反斜杠的字符串。同样的情况是，在 BUT 之前，字符串包含一个以当前活动目录为前缀的相对路径（第一个失败案例）或根文件夹中的路径（第二个失败案例），因此您以 结尾

"C:\Users\user\script\what happens /here" -> %~dp0 = "C:\Users\user\script\what happens "
"C:/g" -> %~dp0 = "C:\"

你怎么解决的？

按照 Magoo 的建议，最简单的解决方法可能是在对参数进行任何转换之前保存 %0 参数的值。

另一种选择是将shift 命令更改为shift /1，以表示移位将从第一个参数开始，而%0 保持不变。

如果这些选项都不能使用，您仍然可以从子例程中检索对批处理文件的引用

@echo off
    setlocal enableextensions disabledelayedexpansion

    rem Ensure %0 is discarded    
    shift
    echo %0

    call :getCurrentBatchFolder dp0
    echo %dp0%

    exit /b

:getCurrentBatchFolder returnVar
    set "%~1=%~dp0"
    goto :eof

【讨论】：

非常感谢您的完整解释！我特别喜欢你的SHIFT /1 解决方案。

【参考方案2】：

我建议%~d0 在SHIFT 命令之后可能不可靠，所以我会在开始时保存它的值。

也许This question 可能会有所帮助。不过我还是先保存~dp0...

【讨论】：

非常感谢。不幸的是，我现在不能赞成你的回答，因为我还是新手。你的链接虽然重定向到同样的问题：p