TightVNC 企业内部部署

Posted 2020-10-15

安装脚本

    安装包放在ftp服务器上，使用ftp下载，再使用msiexec静默安装

    

@echo off
Rem 创建目录
mkdir c:\temp

Rem 获取网卡信息存放到单独一台ftp上（非必须）
ipconfig /all >>c:\temp\%username%.txt

Rem 上传网卡信息
echo open 10.10.29.107 >putip.txt 
Rem ftpuser是账号 test.test是密码
echo user ftpuser test.test >>putip.txt 
echo binary >>putip.txt 
echo put "c:\temp\%username%.txt" >>putip.txt 
echo bye >>putip.txt 
ftp -n -s:putip.txt 
del putip.txt

rem 下载vnc
Rem 判断系统是否64位是则下载64位安装包，否则下载32位安装包
if "%PROCESSOR_ARCHITECTURE%" == "AMD64" (set tightvnc=tightvnc288x64.msi) else (set tightvnc=tightvnc288x86.msi)
echo open 10.10.50.3 >ftp.txt 
Rem ftpuser是账号 test.test是密码
echo user ftpuser test.test >>ftp.txt 
rem dfws.2016 >>ftp.txt 
echo cd "/资料共享库/办公软件/00.装机必备/vnc" >>ftp.txt
echo lcd "c:/temp" >>ftp.txt
echo binary >>ftp.txt
echo get %tightvnc% >>ftp.txt
echo bye >>ftp.txt
ftp -n -s:ftp.txt
del ftp.txt

rem 安装vnc
Rem 静默安装参数，^是bat续行符 ADDLOCAL是选择安装那个客户端Server是服务端，Client是客户端
Rem 同时设置3个密码都是test.9999 第一个是主要密码，第二个是连接密码 第三个是管理员密码.
msiexec.exe /i  c:\temp\%tightvnc% /qb /norestart ^
ADDLOCAL=Server SET_USEVNCAUTHENTICATION=1 VALUE_OF_USEVNCAUTHENTICATION=1 ^
SET_PASSWORD=1 VALUE_OF_PASSWORD=test.9999 ^
SET_VIEWONLYPASSWORD=1 VALUE_OF_VIEWONLYPASSWORD=test.9999 ^
SET_USECONTROLAUTHENTICATION=1 VALUE_OF_USECONTROLAUTHENTICATION=1 ^
SET_CONTROLPASSWORD=1 VALUE_OF_CONTROLPASSWORD=test.9999 
Rem 弹出安装成功是否提示
If errorlevel 1 (mshta vbscript:msgbox("安装VNC失败",64,"提示")(window.close))
else (mshta vbscript:msgbox("安装VNC成功",64,"提示")(window.close))

    

本文出自 “天天向上” 博客，请务必保留此出处http://bshark.blog.51cto.com/10309374/1983384