如何利用VB编写NT服务程序

Posted 2023-05-08

　　一、NT服务程序
　　所谓NT服务，实际上就是一个可以在系统启动时自动在一定身份下启动的伴随系统长时间存在的进程。象FTP server、HTTP server、脱机打印等都是采用NT服务的形式提供的。这实际上类似Unix的root daemon进程。NT服务归纳起来，NT服务又以下几个特征：
　　1、可以自启动，不需要交互启动。这对于服务器来说是一个重要的特征。当然，你可以决定服务是否自启动，甚至可以屏蔽某个服务。
　　2、NT服务没有用户界面，基本上类似一个DOS 程序，因为NT服务必须长时间运行，所以不想普通win32进程一样有自己的界面。但是NT服务可以同用户有界面交互，这是一类特殊的服务进程。可以通过NT的任务管理器来看到服务进程。
　　3、NT服务通过SCM（Services Control Manager）接口来管理，安装、启动、停止、撤除等都需要SCM的接口功能来进行。控制面板的服务控制器就是利用SCM接口来管理系统中的所有服务的。实际上，还有一些可以控制服务的程序或者命令，有net.exe 、服务器管理器等 、SCM.exe等。
　　4、这些进程都以一定的身份运行，以方便进行服务器资源的存取。一般情况下使用域中的LocalSystem账号运行，此账号对本机上的大多数资源（除非特别禁止）有完全的存取权限，这样可以保证服务程序的“强大”。但是，也有些服务采用特别的账号运行，你也可以特别设定一个服务的帐号。
　　5、由系统自动以线程方式运行，一般情况下不过多占用系统资源，这同普通的进程有所区别，如果不采用线程方式，一般进程往往消耗整个CPU资源。一般需要时时存在，又不能过多消耗资源的任务以服务来实现最合适。

　　二、服务控件
　　一般认为编写NT服务需要使用C/C++来实现，VC6利用ATL向导来提供一个基本的服务框架。具体实现步骤为:FileàNew…àATL COM AppWizardàserviceàFinish.但是使用VC编写NT服务需要编写太多的代码，这也意味着需要太多的调试、维护。实际上，NT服务不是必须由C/C++才可以编写的，实际上可以由任何能够实现上一节几个特点的任何语言实现，包括VB。
　　VB编写服务有那些好处呢，至少可以列出以下几条：
　　1、编码简单，熟悉Vb语法的任何人理解本文后都可编写。
　　2、意味着修改服务实现的逻辑简单，维护简单。
　　3、可以利用几乎大多数的Vb中的组件功能，编写一个强大的服务，譬如ado等，如果用VC来实现，相信任何人都会发怵。
　　4、(牵强一点)可以证明Vb在Bill的天空下是多么强大。
　　那么，Vb如何实现NT服务编写呢？据我所至，至少有两种途径：
　　1、 按照C/C++的思路利用WinAPI来实现。
　　2、 利用组件按照Vb传统方式实现。
　　如果利用方法1实际上是照搬C/C++的套路，如果有更好的路子可以实现，相信任何人都不会走这条“绝路”，因为相对于其他语言来说这种编程完全丧失了Vb自身得特点同时也没有获得其他语言的任何优势。在这里，想告诉大家的是利用OCX来实现一个服务。如果您在MSDN中搜索Samples/msdn/techart/4920/，您可以看到一个已经编写好的vc5的工程文件。编译这个工程实际上会得到一个ntsvc.ocx的。如果您对C/C++不熟悉，可以从http://www.mywebtech.net/download/ntsvc.zip 下载一个ntsvc.ocx,此OCX是我从backoffice碟中获得的，将其拷贝到/winnt/system32/下，利用regsvr32 ntsvc.ocx命令注册之。这样，您的Vb就可以从project/components…引出的对话框列表中看到名为“Microsoft NT Service Control”项。此组件拥有我们创建一个服务的基本的功能,如果要编写一个NT服务，我们将其拖进我们的窗体，然后设定其属性，调用其与系统、注册表、SCM交互的功能就可以实现完成一个服务了。
　　我们首先了解这个组件的属性，并向大家解释这些属性的用法：
　　Account String ,账号属性，即本NT服务在哪一个NT域账号下运行，缺省是LocalSystem账号，实际上大多数的NT服务都可以在此账号下安全圆满的运行。
　　ControlsAccepted Long,此服务接受那些SCM控制，为以下值：
　　0 允许Start 以及 Stop .
　　2 允许Pause 以及 Continue .
　　4 允许 shutdown 。
　　其他值，用户自定义的某些事件.
　　利用这个属性，您可以自己决定NT服务进程某个（譬如某个不可中断操作）时刻是否允许SCM停止、暂停、启动等操作。
　　Dependencies String ,如果您编写的服务依赖于某个或者某些服务才能正常运行，您必须在注册服务时指定依赖的服务列表。Dependencies按照依赖顺序以chr(0)来分隔多个服务，最后必须以两个chr(0)结束。（大家可以看到这是一个C/C++的存在痕迹）
　　DisplayName String,显示名，NT服务以何种名字显示给察看者。
　　Interactive Boolean ,是否允许有同桌面用户有交互的部分。
　　LoadOrderGroup String,同Dependencies相关，决定如果本服务启动之前，那些服务必须启动，格式也类似，也以chr(0)分割，连续的两个chr(0)结尾。
　　Password String,服务启动的口令，如果使用缺省得账号，就没有必要设定服务启动的帐号。
　　ServiceName String,服务名，如果使用net.exe来控制服务，net.exe的指定那一个服务的参数就是此属性中的字符串。
　　StartMode 枚举型，具体为：
　　vcStartAutomatic 2 服务可以自己启动
　　svcStartManual 3 服务手动启动
　　svcStartDisabled 4 服务不能自启动
　　另外有一个Debug属性，不做讨论。
　　我们要将一个VB程序当作一个NT服务，必须向系统作一些“申请”,而相应的工作VB是无法很好的完成的。所以，NTSVC.ocx提供了相应的方法留作我们想系统传递相关信息。
　　Install ,将当前Vb程序安装成NT服务，在此之前，您必须至少设置DisplayName, ServiceName, ControlsAccepted以及StartMode等属性。除此之外您可能还要设置Account、Password、LoadOrderGroup、Dependencies等。这些信息的设置正确与否，决定您的服务程序能否正常启动运行。
　　Uninstall, 将当前NTSVC.ocx指定的服务从系统注册表中删除。NT服务取决于系统服务注册表的设定，这是一个众所周知的秘密。
　　StartService，将指定的服务启动，如果该服务注册了。
　　StopService，停止服务，如果服务正在运行。
　　LogEvent ,记录服务事件。服务运行中，可能发生错误以及意料不到的事件，这些可以通过此方法记录下来，供管理员通过“事件察看器”察看相关的信息，以最优化服务。此方法有三个参数event, id, message. Event指发生的事件类型，可以设为以下值：
　　svcEventError 1 错误事件
　　svcEventWarning 2 警告事件.
　　svcEventInformation 4 提供参考信息.
　　svcEventAuditSuccess 8 审计成功.
　　svcEventAuditFailure 10 审计失败
　　除了以上方法，可能用户还需要读写注册表，此控件还提供了注册表的访问方法：
　　DeleteSetting (section[, key])
　　GetAllSettings(section)
　　GetSetting(section, key[, default])
　　SaveSetting(section, key, setting).

　　
　　三、编写服务
　　了解以上内容，下面我们开始来设计一个服务，通过例子，让大家理解如何在VB中编写服务.
　　在此之前，我们决定写一个什么样的服务。我参考C++Build中的一个例子，写一个不断报警的服务进程。该进程启动后在后台不断间隔5秒发出Beep叫，这可以让大家更深切知道此服务的存在，虽然有些令人讨厌。服务的名字为VBBeepSVC,在SCM中显示为The VB NT SVC View。
　　跟着我一起来吧！
　　1、创建工程，设定相关使用到的控件。
　　所有的Vb的控件必须有一个Form作为载体，所以，首先我们创建一个标准工程,选择菜单project—>Components…,然后选取（Microsoft NT Service Control）,会在Toolbar中出现NT服务控件。再拖一个Timer控件到Form上。然后保存一下。基本上，创建过程完成。
　　2、设定控件属性。
　　选中NtSvc.ocx实例，在属性栏中设定：DisplayName: The VB NT SVC View,ServiceName: VBBeepSVC,StartMode:3(手动启动服务).其他的就缺省吧。
　　由于我们希望每个5秒就beep一次，所以我们必须依靠一种定时机制来实现，所以我们将timer的Interval设定位5000毫秒。
　　以上属性的设定视您的需要而定，我只是说在我的VBBeepSVC中如此设定足够了。
　　3、编写代码，实现服务逻辑以及服务安装、撤除。
　　因为服务程序实际上是一个Exe文件，并且需要自己解决安装、撤除问题，因此需要在此程序中加入利用NT服务控件来实现安装、撤除问题。那么，应当在什么时候进行了。VB程序启动时正时Form装载的时候，所以，我们需要在窗体的Load事件中加入一些代码：
　　On Error GoTo Err_Load ‘如果出现错误就纪录以供参考
　　Dim strDisplayName As String
　　strDisplayName = NTService1.DisplayName
　　If Command = "-install" Then ‘当启动时带上 –install的参数时
　　NTService1.Interactive = True
　　If NTService1.Install Then
　　Call NTService1.SaveSetting("Parameters", "TimerInterval", "1000") ‘系统参数存储
　　MsgBox strDisplayName & " 安装成功！"
　　Else
　　MsgBox strDisplayName & " 安装失败"
　　End If
　　End ‘终止安装
　　Else
　　If Command = "-uninstall" Then ‘如果启动时带上 撤除参数
　　If NTService1.Uninstall Then
　　MsgBox strDisplayName & " 撤除成功"
　　Else
　　MsgBox strDisplayName & " 撤除失败"
　　End If
　　End ‘终止撤除
　　Else
　　End If
　　End If
　　‘假若不是安装或撤除操作，即为启动服务
　　Timer1.Interval = CInt(NTService1.GetSetting("Parameters", "TimerInterval", "2000"))
　　‘使用Timer控件来模拟服务的线程特性
　　NTService1.ControlsAccepted = svcCtrlPauseContinue ‘接受暂停、停止操作，意味着需要为此编码
　　NTService1.StartService ‘设置好参数后启动服务
　　Err_Load:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description) ‘svcMessageError为NT服务控件的错误值
　　4、添加控制服务的代码。
　　尽管服务的连续线程等特性是依赖Timer实现的，但是服务的控制却是有SCM接口向每一个服务发出的，表现在VB服务程序中为NT服务控件捕获到相关的事件发生，我们就应当在这些事件中根据具体的情况响应，决定能不能、如何控制服务逻辑。当然，具体的逻辑在Timer事件中表现，但是通过改变NT服务控件和Timer控件均支持的全局变量，可以实现控制服务的逻辑实现。具体代码演示：
　　Private Sub NTService1_Control(ByVal EventID As Long)
　　On Error GoTo Err_Control
　　‘在此加入一些自己的处理逻辑，当然也可以如本例一样空缺
　　Err_Control:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description) ‘纪录
　　End Sub
　　Private Sub NTService1_Pause(Success As Boolean)
　　On Error GoTo Err_Pause
　　Timer1.Enabled = False ‘禁止Timer事件，因此也停止了服务的发生
　　Call NTService1.LogEvent(svcEventError, svcMessageError, "Service paused")
　　Success = True ‘返回给SCM命令发出者,表示服务成功停止
　　Err_Pause:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
　　End Sub
　　Private Sub NTService1_Start(Success As Boolean)
　　On Error GoTo Err_Start
　　Success = True
　　Timer1.Enabled = True ‘允许服务逻辑进行
　　Err_Start:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
　　End Sub
　　Private Sub NTService1_Stop()
　　On Error GoTo Err_Stop
　　Unload Me ‘撤除Form,自然Timer也不存在，服务逻辑停止了
　　Err_Stop:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
　　End Sub
　　5、编写服务逻辑。
　　具体就是在Timer事件中，根据约定写一些服务细节。本例中就是发出Been，但是考虑到对SCM命令的响应，所以需要编码为：
　　On Error GoTo Err_Timer
　　Beep ‘此处即具体的服务细节
　　Err_Timer:
　　Call NTService1.LogEvent(svcMessageError, svcEventError, "[" & Err.Number & "] " & Err.Description)
　　End Sub
　　6、编译安装、测试
　　如果以上没有什么错误的话，现在可以编译程序了。假设我们得到的服务程序的文件名为：VBBeepSVC.exe,我们需要通过以下命令进行安装：
　　d:/vbprog/>VBBeepSVC –install
　　如果需要撤除已经安装的服务，则：
　　d:/vbprog/>VBBeepSVC –uninstall
　　安装完后，打开控制面板的“服务”（win2000中在“管理工具”）,好了，看到其中的NT服务列表中包含我们加入的服务，显示为：“The VB NT SVC View”，我们可以类似启动其他任何服务一样启动、停止、暂停此服务。启动服务时，我们会听到服务发出的讨厌的beep声音。我们的测试完成。

　　四、VB编写服务的几个说明：
　　1、首先声明：VB编写服务是一种尝试，技术研究，并非提倡所有服务都要用VB写才对头。同理，也说明了服务非VC写不可。
　　2、VB写的服务仅适合win32服务，不适合NT底层服务。
　　3、VB的优势在ActiveX控件，NT服务中我们可以使用绝大多数控件来完成我们的服务逻辑，譬如涉及数据库操作，我们可以使用ADO组件，这方面，同VC相比，VB具有天然的优势。
　　4、做好服务内部的错误事件记载，只有用好这一点，才能够真正符合服务编写规范，也方便我们的除错。
　　5、最后一点，本文仅供参考，如有错误以及错误引起的后果，本人概不负责.
转载 参考技术A

Microsoft Windows NT(New Technology)是Microsoft在1993年推出的面向工作站、网络服务器和大型计算机的网络操作系统，也可做PC操作系统。它与通信服务紧密集成，基于OS/2 NT基础编制。OS/2由微软和IBM联合研制，分为微软的Microsoft OS/2 NT与IBM的IBM OS/2。协作后来不欢而散，IBM继续向市场提供先前的OS/2版本，微软则把自己的OS/2 NT的名称改为Windows NT，即第一代的Windows NT 3.1。微软公司从数字设备公司（Digital Equipment Corporation）雇佣了一批人员来开发这个新系统。“NT”所指的便是“新技术”（New Technology）之意。“NT”除了可以解释为“新技术”之外，有另一个版本指“NT”是来自微软在i860上开发NT时所使用的模拟器“N10”（N-Ten）。

'=======================================================

' 函数名称：Main

' 函数说明：主程序入口点，内容较长，声明引用dell代码见附件

'=======================================================

Sub Main()

    '处理命令行参数

    Dim szArgv As String

    szArgv = UCase(Trim(Command))

    If Left(szArgv, 1) = "/" Or Left(szArgv, "1") = "-" Then

        szArgv = Mid(szArgv, 2)

    End If

    

    '转换变量本地系统编码

    m_szServiceName = StrConv(SERVICE_NAME, vbUnicode)

    m_szDisplayName = StrConv(SERVICE_NAME, vbUnicode)

     

    '如果有参数，则进行处理

    If Len(szArgv) > 0 Then

        If szArgv = "I" Or szArgv = "INSTALL" Or szArgv = "REGSERVER" Then

            '安装服务

            If Install() Then

                MsgBox vbCrLf & "服务已被成功安装!" & vbCrLf, vbInformation, "提示"

            Else

                MsgBox vbCrLf & "服务安装失败!" & vbCrLf, vbExclamation, "提示"

            End If

            Exit Sub

        ElseIf szArgv = "U" Or szArgv = "UNINSTALL" Or szArgv = "UNREGSERVER" Then

            '卸载服务

            If Uninstall() Then

                MsgBox vbCrLf & "服务已被成功卸载!" & vbCrLf, vbInformation, "提示"

            Else

                MsgBox vbCrLf & "服务卸载失败!" & vbCrLf, vbExclamation, "提示"

            End If

            Exit Sub

        Else

            MsgBox vbCrLf & "不支持的参数，终止运行!", vbCritical, "警告"

            Exit Sub

        End If

    End If

    

    '无参数时，判断服务是否已被安装，否则退出

    If Not IsInstalled Then Exit Sub

    

    '获得主线程ID以备用

    m_dwMainThreadId = GetCurrentThreadId()

     

    '尝试启动服务

    Dim result As Long

    Dim ste As SERVICE_TABLE_ENTRY

    

    ste.lpServiceName = StrPtr(m_szServiceName)

    ste.lpServiceProc = GetFuncAddr(AddressOf ServiceMain)

    result = StartServiceCtrlDispatcher(ste)

    

    '如果服务成功启动，则进入消息循环待

    If result <> 0 Then

        Dim uMsg As MSG

        Do While GetMessage(uMsg, 0, 0, 0)

        Loop

    End If

    

    '等待服务线程结束

    WaitForSingleObject m_hServiceThread, 800

End Sub

'=======================================================

' 函数名称：IsInstalled

' 函数说明：判断服务是否已安装

Public Function IsInstalled() As Boolean

    Dim bSuccess As Long

    Dim hSCM As Long, hService As Long

    hSCM = OpenSCManager(vbNullString, vbNullString, SC_MANAGER_ALL_ACCESS)

    If hSCM <> 0 Then

        hService = OpenService(hSCM, m_szServiceName, SERVICE_QUERY_CONFIG)

        If hService <> 0 Then

            bSuccess = True

            Call CloseServiceHandle(hService)

        End If

        Call CloseServiceHandle(hSCM)

    End If

    IsInstalled = bSuccess

End Function

'=======================================================

' 函数名称：Install

' 函数说明：安装服务

Public Function Install() As Boolean

    Dim bSuccess As Boolean

    Dim hSCM As Long, hService As Long

    Dim szFilePath As String 'UNICODE编码

    If IsInstalled() Then

        bSuccess = True

    Else

        hSCM = OpenSCManager(vbNullString, vbNullString, SC_MANAGER_ALL_ACCESS)

        If hSCM <> 0 Then

            szFilePath = StrConv(App.Path & "/" & App.EXEName & ".EXE", vbUnicode)

            hService = CreateService(hSCM, m_szServiceName, m_szDisplayName, _

                        SERVICE_ALL_ACCESS, SERVICE_WIN32_OWN_PROCESS, _

                        SERVICE_DEMAND_START, SERVICE_ERROR_NORMAL, _

                        szFilePath, vbNullString, ByVal 0&, vbNullString, vbNullString, vbNullString)

            If hService <> 0 Then

                bSuccess = True

                Call CloseServiceHandle(hService)

            End If

            Call CloseServiceHandle(hService)

        End If

    End If

    Install = bSuccess

End Function

'=======================================================

' 函数名称：Uninstall

' 函数说明：卸载服务

Public Function Uninstall() As Boolean

    Dim bSuccess As Boolean

    Dim hSCM As Long, hService As Long

    

    If Not IsInstalled Then

        bSuccess = True

    Else

        hSCM = OpenSCManager(vbNullString, vbNullString, SC_MANAGER_ALL_ACCESS)

        If hSCM <> 0 Then

            hService = OpenService(hSCM, m_szServiceName, SERVICE_STOP Or Delete)

            If hService <> 0 Then

                Dim status As SERVICE_STATUS

                Call ControlService(hService, SERVICE_CONTROL_STOP, status)

                bSuccess = DeleteService(hService)

                Call CloseServiceHandle(hService)

            End If

            Call CloseServiceHandle(hSCM)

        End If

    End If

    Uninstall = bSuccess

End Function

'=======================================================

' 函数名称：ServiceMain

' 函数说明：服务入口线程

Public Sub ServiceMain(ByVal dwArgc As Long, ByVal lpszArgv As Long)

    Dim hr As Long

    Dim uMsg As MSG

    Dim lStartTime As Long

    

    '获得服务线程句柄

    m_hServiceThread = GetCurrentThread()

    

    '获得服务线程ID

    m_dwServiceThreadId = GetCurrentThreadId()

    '向SCM注册SCP回调函数地址

    m_hServiceStatus = RegisterServiceCtrlHandler(StrPtr(m_szServiceName), AddressOf Handler)

    

    '通知SCM服务正在启动

    SendStatusToSCM SERVICE_START_PENDING

    '初始化COM，让线程进入公寓线程模式

    hr = CoInitialize(ByVal 0&)

    

    '通知SCM服务已经运行

    SendStatusToSCM SERVICE_RUNNING

    

    '进入服务消息循环

    lStartTime = GetTickCount()

    Do While True

        Call PeekMessage(uMsg, 0, 0, 0, PM_REMOVE)

        If uMsg.message = WM_QUIT Then Exit Do

        DispatchMessage uMsg

        If GetTickCount() - lStartTime > 1000 Then

            lStartTime = GetTickCount

            MessageBeep -1

        End If

        Sleep 1

    Loop

    

    '取消公寓线程模式

    Call CoUninitialize

    '通知SCM服务已经停止

    SendStatusToSCM SERVICE_STOPPED

    

    '通知主线程结束消息循环

    PostThreadMessage m_dwMainThreadId, WM_QUIT, 0, 0

End Sub

'=======================================================

' 函数名称：Handler

' 函数说明：接收并处理SCP控制消息

Public Sub Handler(ByVal dwOpcode As Long)

    Select Case dwOpcode

        Case SERVICE_CONTROL_STOP                   '当接收到SCP发出的停止控制时

            '通知SCM服务即将停止

            SendStatusToSCM SERVICE_STOP_PENDING

            '通知服务线程结束消息循环

            Call PostThreadMessage(m_dwServiceThreadId, WM_QUIT, 0, 0)

        Case SERVICE_CONTROL_PAUSE

        Case SERVICE_CONTROL_CONTINUE

        Case SERVICE_CONTROL_INTERROGATE

        Case SERVICE_CONTROL_SHUTDOWN               '当接收到SCP发出的关机控制时

            '通知SCM服务即将停止

            SendStatusToSCM SERVICE_STOP_PENDING

            '通知服务线程结束消息循环

            Call PostThreadMessage(m_dwServiceThreadId, WM_QUIT, 0, 0)

        Case Else

    End Select

End Sub

'=======================================================

' 函数名称：SendStatusToSCM

' 函数说明：服务状态设置辅助函数

Public Function SendStatusToSCM(Optional ByVal dwCurrentState As SERVICE_STATE = 0) As Long

    Dim status As SERVICE_STATUS

    

    status.dwServiceType = SERVICE_WIN32_OWN_PROCESS

    If dwCurrentState <> 0 Then

        status.dwCurrentState = dwCurrentState

    End If

    If dwCurrentState = SERVICE_START_PENDING Then

        status.dwControlsAccepted = 0

    Else

        status.dwControlsAccepted = SERVICE_ACCEPT_STOP Or _

                                                SERVICE_ACCEPT_SHUTDOWN '此处决定接收SCP的哪些控制消息

    End If

    SendStatusToSCM = SetServiceStatus(m_hServiceStatus, status)

End Function

'=======================================================

' 函数名称：GetFuncAddr

' 函数说明：获得函数指针辅助函数

Public Function GetFuncAddr(ByVal lFuncAddr As Long) As Long

    GetFuncAddr = lFuncAddr

End Function

如何编写 vb.net 代码来编译 C/C++ 程序？

【中文标题】如何编写 vb.net 代码来编译 C/C++ 程序？

【英文标题】：How to write a vb.net code to compile C/C++ programs?

【发布时间】：2009-05-11 12:24:35

【问题描述】：

我正在尝试制作一个 vb.net 应用程序，它有 2 个文本框、7 个单选按钮和 2 个按钮（一个名为编译，另一个为“运行”）。如何将 C/C++（或任何编程语言）文件的内容加载到第一个文本框中，然后单击编译按钮，我应该能够在第二个文本框中显示错误或 C/C++ 程序。单击运行时，我应该能够在第二个文本框中显示输出。简而言之，我想将第二个文本框用作终端/控制台。单选按钮是 4 选择语言 C 或 C++ 或 python 或 C# 或 java 或 perl 或 vb。 .net 中是否存在所有这些语言的编译器？如果是这样，我该如何称呼他们？

【问题讨论】：

您最近问过这个问题吗，可能是用不同的名字？我们真的不喜欢受骗。

我们也不喜欢“R d”、“dem”或“?????”之类的东西。好吧，至少我会。

【参考方案1】：

查看System.IO 命名空间以获取有关如何将文件内容加载到文本框中的线索。特别是File 类。

System.IO.File Class

查看System.Diagnostics 命名空间以获取有关如何启动进程和捕获输出的线索。特别是 Process 类。

System.Diagnostics.Process Class

这个 SO 页面...

Capturing the Console Output in .NET (C#)

... 将为您提供有关捕获控制台输出的更多信息。

【参考方案2】：

可以通过调用Visual Studio自带的cl.exe来完成编译。当然你也可以用 GCC 代替。