Drools 规则学习

Posted 2020-06-17

Drools 规则学习

在 Drools 当中，一个标准的规则文件就是一个以“.drl”结尾的文本文件，由于它是一
个标准的文本文件，所以可以通过一些记事本工具对其进行打开、查看和编辑。规则是放在
规则文件当中的，一个规则文件可以存放多个规则，除此之外，在规则文件当中还可以存放
用户自定义的函数、数据对象及自定义查询等相关在规则当中可能会用到的一些对象。
文件结构图如下:
package
imports
globals
functions
queries
rules
.....

对于一个规则文件而言，首先声明 package 是必须的，除 package 之外，其它对象在规
则文件中的顺序是任意的，也就是说在规则文件当中必须要有一个 package 声明，同时
package 声明必须要放在规则文件的第一行。一个规则通常包括三个部分：属性部分（attribute） 、条件
部分（LHS）和结果部分（RHS） 一个标准规则的结构如下:
rule "name"
attributes
when
LHS
then
RHS
end

1.在 LHS 当中，可以包含 0~n 个条件，如果 LHS 部分没空的话，那么引擎会自动添加一个 eval(true)的条件，由于该条件总是返回 true，所以 LHS 为空的规则总是返回 true
2.在这两个pattern没有符号连接， 在Drools当中在 pattern 中没有连接符号，那么就用 and 来作为默认连接，所以在该规则的 LHS 部分中两个 pattern 只有都满足了才会返回 true。默认情况下，每行可以用“;”来作为结束符（和Java 的结束一样） ，当然行尾也可以不加“;”结尾。

条件部分
1.约束连接
对于对象内部的多个约束的连接，可以采用“&&” （and） 、 “||”(or)和“,”(and)来实现
示例代码:
rule "rule1"
when
Customer(age>20 || gender==’male’&& city==’sh’)
then
<action>…
End

2.比较操作符
在 Drools当中共提供了十二种类型的比较操作符， 分别是： >、 >=、 <、 <=、 = =、 !=、 contains、 not contains、memberof、not memberof、matches、not matches；在这十二种类型的比较操作符当中，前六个是比较常见也是用的比较多的比较操作符
contains 示例代码:
rule "rule1"
when
$order:Order();
$customer:Customer(age >20, orders contains $order);
then
System.out.println($customer.getName());
end

not contains 示例代码:
rule "rule1"
when
$order:Order(items not contains "手机");
then
System.out.println($order.getName());
end

memberOf(memberOf 是用来判断某个 Fact 对象的某个字段是否在一个集合（Collection/Array）当中) 示例代码:
global String[] orderNames; //定义全局变量
rule "rule1"
when
$order:Order(name memberOf orderNames);
then
System.out.println($order.getName());
end

not memberOf (该操作符与 memberOf 作用洽洽相反) 示例代码:
rule "rule1"
when
$orderList:String[]();
$order:Order(name not memberOf $orderList);
then
System.out.println($order.getName());
end

matches 是用来对某个 Fact 的字段与标准的 Java 正则表达式进行相似匹配，被比较的字符串可以是一个标准的 Java 正则表达式，但有一点需要注意，那就是正则表达式字符串当中不用考虑“\”的转义问题。
示例代码：
rule "rule1"
when
$customer:Customer(name matches "李.*");
then
System.out.println($customer.getName());
end

not matches (该操作符与 matches 作用洽洽相反)

结果部分

我们知道，在规则当中 LHS 就是用来放置条件的，所以在 RHS 当中虽然可以直接编写
Java 代码，但不建议在代码当中有条件判断，如果需要条件判断，那么请重新考虑将其放在
LHS 当中，否则就违背了使用规则的初衷

在 Drools 当中，在 RHS 里面，提供了一些对当前 Working Memory 实现快速操作的宏
宏函数或对象， 比如 insert/insertLogical、 update 和 retract 就可以实现对当前 Working Memory
中的 Fact 对象进行新增、删除或者是修改

1.insert
函数insert的作用与我们在Java类当中调用StatefulKnowledgeSession对象的insert方法的作用相同，都是用来将一个 Fact 对象插入到当前的 Working Memory 当中
需注意：一旦调用 insert 宏函数，那么 Drools 会重新与所有的规则再重新匹配一次， 对于没有设置no-loop 属性为 true 的规则，如果条件满足，不管其之前是否执行过都会再执行一次，这个特性不仅存在于 insert 宏函数上，后面介绍的 update、retract 宏函数同样具有该特性，所以在某些情况下因考虑不周调用 insert、update 或 retract 容易发生死循环
示例代码如下:
rule "rule1"
salience 1 //该属性的作用是通过一个数字来确认规则执行的优先级， 数字越大， 执行越靠前
when
eval(true); //默认成立
then
Customer cus=new Customer();
cus.setName("张三");
insert(cus);
end
rule "rule2"
salience 2
when
$customer:Customer(name =="张三");
then
System.out.println("rule2----"+$customer.getName());
end

2.insertLogical
insertLogical 作用与 insert 类似，它的作用也是将一个 Fact 对象插入到当前的 Working Memroy 当中

3.update
update函数意义与其名称一样， 用来实现对当前Working Memory当中的 Fact进行更新，update 宏函数的作用与 StatefulSession 对象的 update 方法的作用基本相同，都是用来告诉当
前的 Working Memory 该 Fact 对象已经发生了变化。它的用法有两种形式，一种是直接更新一个 Fact 对象，另一种为通过指定 FactHandle 来更新与指定 FactHandle 对应的 Fact 对象
第一种 直接更新一个 Fact 对象：
rule "rule1"
salience 2
when
eval(true);
then
Customer cus=new Customer();
cus.setName("张三");
cus.setAge(1);
insert(cus);
end
rule "rule2"
salience 1
when
$customer:Customer(name=="张三",age<10);
then
$customer.setAge($customer.getAge()+1);
update($customer);
System.out.println("----------"+$customer.getName());
end

第二种 可以支持创建一个新的 Fact 对象， 从而把 FactHandle对象指定的 Fact 对象替换掉，从而实现对象的全新更新：
rule "rule1"
salience 2
when
eval(true);
then
Customer cus=new Customer();
cus.setName("张三");
cus.setAge(1);
insert(cus);
end
rule "rule2"
salience 1
when
$customer:Customer(name=="张三",age<10);
then
Customer customer=new Customer();
customer.setName("张三");
customer.setAge($customer.getAge()+1);
update(drools.getWorkingMemory().getFactHandleByIdentity($customer),customer);
System.out.println("----------"+$customer.getName());
end

4.retract
retract用来将 Working Memory 当中某个 Fact 对象从 Working Memory 当中删除 示例代码：
rule "rule1"
salience 2
when
eval(true);
then
Customer cus=new Customer();
cus.setName("张三");
cus.setAge(1);
insert(cus);
end
rule "rule2"
salience 1
when
$customer:Customer(name=="张三");
then
retract($customer);
end
5.modify
modify是一个表达式块，它可以快速实现对 Fact 对象多个属性进行修改，修改完成后会自动更新到当前的 Working Memory 当中
rule "rule1"
salience 2
when
$customer:Customer(name=="张三",age==20);
then
System.out.println("modify before customer
id:"+$customer.getId()+";age:"+$customer.getAge());
modify($customer){
setId("super man"),
setAge(30),
setName("黄五")
}
end
rule "rule2"
salience 1
when
$customer:Customer(name=="黄五");
then
System.out.println("modify after customer
id:"+$customer.getId()+";age:"+$customer.getAge());
end


属性部分
1.salience
作用是用来设置规则执行的优先级，salience 属性的值是一个数字，数字越大执行优先级越高，同时它的值可以是一个负数。默认情况下，规则的 salience 默认值为 0，所以如果我们不手动设置规则的 salience 属性，那么它的执行顺序是随机的。
示例代码：
rule "rule1"
salience 1
when
eval(true)
then
System.out.println("rule1");
end
rule "rule2"
salience 2
when
eval(true)
then
System.out.println("rule2");
end

虽然 rule1 位于前面，但因为它的 salience 为 1，而 rule2的 salience 属性为 2，所以 rule2 会先执行，然后 rule1 才会执行。

2.no-loop
作用是用来控制已经执行过的规则在条件再次满足时是否再次执行。no-loop 属性的值是一个布尔型，默认情况下规则的 no-loop属性的值为 false，如果 no-loop 属性值为 true，那么就表示该规则只会被引擎检查一次，
如果满足条件就执行规则的 RHS 部分，如果引擎内部因为对 Fact 更新引起引擎再次启动检查规则，那么它会忽略掉所有的 no-loop 属性设置为 true 的规则。
示例代码：
rule "rule1"
salience 1
no-loop true
when
$customer:Customer(name=="张三")
then
update($customer);
System.out.println("customer name:"+$customer.getName());
End

3.date-effective
作用是用来控制规则只有在到达后才会触发，在规则运行时，引擎会自动拿当前操作系统的时候与 date-effective 设置的时间值进行比对， 只有当系统时间>=date-effective 设置的时间值时，
规则才会触发执行，否则执行将不执行。在没有设置该属性的情况下，规则随时可以触发，没有这种限制。date-effective 的值为一个日期型的字符串，默认情况下，date-effective 可接受的日期格式为“dd-MMM-yyyy”
示例代码：
rule "rule1"
date-effective "2009-09-25" //当前日期不小于2009-09-25时可以执行
when
eval(true);
then
System.out.println("rule1 is execution!");
end
在实际使用的过程当中，如果您不想用这种时间的格式，那么可以在调用的 Java 代码中通过使用 System.setProperty(String key,String value)方法来修改默认的时间格式
在java文件中添加此条命令: System.setProperty("drools.dateformat","yyyy-MM-dd");

4.date-expires
作用是与 date-effective 属性恰恰相反， date-expires 的作用是用来设置规则的有效期，引擎在执行规则的时候，会检查规则有没有 date-expires 属性，如果有的话，那么会将这个属性的值与当前系统时间进行比对，如果大于系统时间，那么规则就执行，否则就不执行。
示例代码：
rule "rule1"
date-effective "2009-09-25" //当前日期不小于2009-09-25时可以执行(含2009-09-25) 注意修改时间格式
date-expires "2009-09-30" //当前日期大于2009-09-30时可以执行(不含2009-09-30) 注意修改时间格式
when
eval(true);
then
System.out.println("rule1 is execution!");
end

5.enabled
作用是用来定义一个规则是否可用的。该属性的值是一个布尔值，默认该属性的值为 true，表示规则是可用的。设置其 enabled 属性值为 false，那么引擎就不会执行该规则

6.dialect
作用是用来定义规则当中要使用的语言类型，目前支持两种类型的语言：mvel 和 java，默认情况下，如果没有手工设置规则的 dialect，那么使用的 java 语言

7.duration
作用是将在该属性指定的值之后在另外一个线程里触发。该属性对应的值为一个长整型，单位是毫秒
示例代码：
rule "rule1"
duration 3000
when
eval(true)
then
System.out.println("rule thread id:"+Thread.currentThread().getId());
end

8.lock-on-active
作用是 no-loop 的增强版属性，它主要作用在使用 ruleflow-group 属性或 agenda-group 属性的时候。lock-on-active 属性默认值为 false。
9.activation-group
作用是将若干个规则划分成一个组，用一个字符串来给这个组命名，这样在执行的时候，具有相同 activation-group 属性的规则中只要有一个会被执行，其它的规则都将不再执行。
也就是说，在一组具有相同 activation-group 属性的规则当中，只有一个规则会被执行，其它规则都将不会被执行。当然对于具有相同 activation-group 属性的规则当中究竟哪一个会先执行，则可以用类似 salience 之类属性来实现。
示例代码：
rule "rule1"
activation-group "test"
when
eval(true)
then
System.out.println("rule1 execute");
end
rule "rule 2"
activation-group "test"
when
eval(true)
then
System.out.println("rule2 execute");
end

10.agenda-group
作用是agenda-group 属性的值也是一个字符串，通过这个字符串，可以将规则分为若干个Agenda Group，默认情况下，引擎在调用这些设置了 agenda-group 属性的规则的时候需要显
示的指定某个 Agenda Group 得到 Focus （焦点） ， 这样位于该 Agenda Group 当中的规则才会触发执行，否则将不执行。
示例代码：
rule "rule1"
agenda-group "001"
when
eval(true)
then
System.out.println("rule1 execute");
end
rule "rule 2"
agenda-group "002"
when
eval(true)
then
System.out.println("rule2 execute");
end
java调用:
StatefulKnowledgeSession statefulSession = knowledgeBase.newStatefulKnowledgeSession();
statefulSession.getAgenda().getAgendaGroup("002").setFocus(); //获得执行焦点
statefulSession.fireAllRules();
statefulSession.dispose();

//了解即可 不常用

11.auto-focus
作用是用来在已设置了 agenda-group 的规则上设置该规则是否可以自动独取 Focus，如果该属性设置为 true，那么在引擎执行时，就不需要显示的为某个 Agenda Group 设置 Focus，否则需要。
12.ruleflow-group
作用是用来将规则划分为一个个的组，然后在规则流当中通过使用 ruleflow-group 属性的值，从而使用对应的规则。