STM32 .ld链接文件分析及一次bug解决过程

Posted 2020-11-23 regressionworldline

目录

• STM32 .ld链接文件分析及一次bug解决过程
  • 问题描述
  • 解决办法
    • ld文件解析
  • 后续

STM32 .ld链接文件分析及一次bug解决过程

问题描述

原子板的代码中含有一个关于使用外部SRAM的功能，由于本人的开发板的SRAM只有512K，因此稍微修改了一下代码，同时使用GCC进行编译，但是这里却报错了，源码如下：

//内存池(4字节对齐)
__align(4) u8 mem1base[MEM1_MAX_SIZE];
__align(4) u8 mem2base[MEM2_MAX_SIZE] __attribute__((at(0x68000000))); //外部SRAM内存池
__align(4) u8 mem3base[MEM3_MAX_SIZE] __attribute__((at(0x10000000))); //内部CMM内存池

这里的__align(4)指的是4字节对齐，这是个MDK的用法，换到GCC只能使用#pragma *pack*(4)，这里还是个小问题，改后的代码如下：

#pragma pack(4)
u8 mem1base[MEM1_MAX_SIZE];
u8 mem2base[MEM2_MAX_SIZE] __attribute__((at(0x68000000))); //外部SRAM内存池
u8 mem3base[MEM3_MAX_SIZE] __attribute__((at(0x10000000))); //内部CMM内存池

麻烦的地方来了，gcc中不支持at直接指定变量位置的写法，因此报错如下：

$ make
./Src/MALLOC/malloc.c:12:1: warning: 'at' attribute directive ignored [-Wattributes]
 u8 mem2base[MEM2_MAX_SIZE] __attribute__((at(0x68000000))); //外部SRAM内存池
 ^
./Src/MALLOC/malloc.c:13:1: warning: 'at' attribute directive ignored [-Wattributes]
 u8 mem3base[MEM3_MAX_SIZE] __attribute__((at(0x10000000))); //内部CMM内存池

这里的意思是at后面的指定地址方式不支持，因此忽略掉了。这个忽略就有大问题了，上面的mem2base和mem3base是分别要放在外部SRAM和内部CMM中的，这一忽略全部放到内部RAM上，空间就不够了：

 Output/obj/out.elf section `.bss' will not fit in region `RAM'
 region `RAM' overflowed by 420320 bytes

解决办法

arm-gcc同样支持指定变量地址，只不过语法是下面这样的：

__attribute__ ((section ("SECTIONNAME")))

换句话说，在link文件中划分一个新的段，将这个变量放到这个段内就可以解决了。与scatter文件不同，由cubemx生成的Makefile工程使用的是ld文件，下面看一下这个ld文件是什么样子的：

ld文件解析

先贴上部分文件内容，之后再说明

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20020000;    /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x200;      /* required amount of heap  */
_Min_Stack_Size = 0x400; /* required amount of stack */

/* Specify the memory areas */
MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 128K
CCMRAM (rw)      : ORIGIN = 0x10000000, LENGTH = 64K
FLASH (rx)      : ORIGIN = 0x8000000, LENGTH = 1024K
MALLOC(rw)     : ORIGIN = 0x68000000, LENGTH = 512K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH

  /* Constant data goes into FLASH */
  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH

  .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  .ARM : {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } >FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* used by the startup to initialize data */
  _sidata = LOADADDR(.data);

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : 
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM AT> FLASH

  _siccmram = LOADADDR(.ccmram);

  /* CCM-RAM section 
  * 
  * IMPORTANT NOTE! 
  * If initialized variables will be placed in this section,
  * the startup code needs to be modified to copy the init-values.  
  */
  .ccmram :
  {
    . = ALIGN(4);
    _sccmram = .;       /* create a global symbol at ccmram start */
    *(.ccmram)
    *(.ccmram*)
    
    . = ALIGN(4);
    _eccmram = .;       /* create a global symbol at ccmram end */
  } >CCMRAM AT> FLASH

  
  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(8);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(8);
  } >RAM

  .malloc :
  {
    . = ALIGN(4);
    __MALLOC_SYMBOLS = .;       /* create a global symbol at ccmram start */
    *(.malloc)
    *(.malloc*)
    
    . = ALIGN(4);
    __EMALLOC_SYMBOLS = .;       /* create a global symbol at ccmram end */
  } >MALLOC AT> FLASH

  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }

  .ARM.attributes 0 : { *(.ARM.attributes) }
}

第一部分

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20020000;    /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x200;      /* required amount of heap  */
_Min_Stack_Size = 0x400; /* required amount of stack */

指定入口地址，RAM的结束地址，可以看到F407的可以被AHB总线访问的ram由于是128k，因此结束地址是0x20020000，后面指定了堆的大小和栈的大小分别为512B和1KB。

第二部分

MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 128K
CCMRAM (rw)      : ORIGIN = 0x10000000, LENGTH = 64K
FLASH (rx)      : ORIGIN = 0x8000000, LENGTH = 1024K
MALLOC(rw)     : ORIGIN = 0x68000000, LENGTH = 512K
}

给出地址的划分区间，这里增加了一个由malloc使用的MALLOC段，放在外部SRAM上，地址0x68000000，大小比原子开发板小一半，只有512K

第四部分

/* Define output sections */
SECTIONS
{
    /*中间跳过*/
  .malloc :
  {
    . = ALIGN(4);
    __MALLOC_SYMBOLS = .;       /* create a global symbol at ccmram start */
    *(.malloc)
    *(.malloc*)
    
    . = ALIGN(4);
    __EMALLOC_SYMBOLS = .;       /* create a global symbol at ccmram end */
  } >MALLOC AT> FLASH
    /*结尾跳过*/
}

这一部分实际上指定了程序的各个内容该如何放置在flash上或者ram上，有几个用法：

• . = ALIGN(4);是指4字节对齐
• .，小数点表示当前的地址位置，例如__MALLOC_SYMBOLS = .;的意思是`__MALLOC_SYMBOLS 的地址就是.malloc段的地址
• 一般的程序中包含常见的几个段：text(存放程序),rodata(存放被初始化的数据),data(表示初始化不为0的变量),bss(表示初始化值为默认的全局变量)
• text,rodata放在flash中，而data中的初始化值作为rodata放在flash中，变量在ram中占有空间，bss占ram空间
• 段可以自定义，如上面写的malloc段，由于编译obj过程中不会生成用户自定义的段，因此在源码中需要指定需要特殊处理的段
• 结尾的>MALLOC指上面花括号内的内容都放在第二部分中定义的MALLOC空间中。如果没有AT> FLASH，那么编译bin文件时地址是连续的

后续

将link文件修改好后，我们得到了一个新的段MALLOC，并且将CMM也利用了起来，在c代码中修改如下：

#pragma pack(4)
u8 mem1base[MEM1_MAX_SIZE];
u8 mem2base[MEM2_MAX_SIZE] __attribute__((section(".malloc"))); //外部SRAM内存池
u8 mem3base[MEM3_MAX_SIZE] __attribute__((section(".ccmram"))); //内部CMM内存池

这样，mem2base和mem3base将被特殊处理，这里ld文件还有一个需要注意的地方，那就是最后结束的地方>MALLOC要加上AT> FLASH，如果不加上的话，bin文件将连续生成，由于我们外部sram的地址在0x68000000，因此，gcc将会把这部分当做flash的地址一部分，也就是说将会生成一个超大的bin文件！！（约1.6G）所以这一句千万不能少。