如何去掉Word自动编号的空格以及编号10以后的空格

Posted 2023-04-17

掉Word自动编号的空格以及编号10以后的空格操作如下：

1、打开Word，选择需要修改的行。

2、单击鼠标右键，选择一项调整列表缩进，弹出对话框。

3、在弹出的对话窗口中，将编号后的选项改为不特别标记。

4、点击确定，就可以看到效果了。

参考技术A

1、首先在电脑中打开word文档，全选文字按“CTRL+A“，如下图所示。

2、然后点击鼠标右键，会弹出一个窗口，选择”调整列表缩进“，如下图所示。

3、接着会弹出一窗口，将”文本缩进“改为”0“，再按确定。

4、这样自动编号后的空格删除了，如下图所示就完成了。

参考技术B 自动编号与后面语句有很大空格，于是调整文字位置（选择所需要改动的部分，点“格式”-“项目符号和编号”-点你需要的编号类型-“自定义”-指定“编号位置”和“文字位置”的缩进值,确定）。
发现10以后的编号仍然有这个问题，于是又到处查找，终于找到原因。在Word中，如果自动编号到10以后时，编号与字符之间自动出现空格，可通过以下方式修改：“格式”--“制表位”--找到“默认制表位”--将其值修改为0字符。修改后确定，10以后的编号后就不会添加多余的空格了。本回答被提问者采纳 参考技术C 1、选中10以后的注释，右键选择“调整列表缩进”，点击“编号之后”下方的“空格”选项，点击确定。
2、现在10变成了从1从新开始，没关系，这时候右键选中后面重新排序的部分，点击右键“项目与编号”，选择“自定义”，起始编号改为“10”即可！！！！！！！！！！！！！！！！！ 参考技术D 单机鼠标左键选中编号→_→打开编号菜单栏→_→自定义编号→_→自定义→_→“编号之后”选择无特别样式→_→确定

Word插入题注优化（自动删除标签与编号前的空格，编号后添加空格）

简介

最近在论文写作时发现，对图或者表右击进行插入题注时格式有点不正确，会在标签和编号之间多一个半角空格，而编号和题注内容之间又缺少一个空格，这也是Word目前对中文支持不太好的地方。我们常规的格式应该是在“图”、“表”等标签与编号之间是没有分隔符的，然后在标签和编号之后与题注具体内容之间有一个空格。当然可以手动删除前面的空格然后在后面补一个，但是在我们写比较长的文章时，每次手动去改就比较麻烦，这里参考网上的一个通过宏的方式自动调整的，调整之后每次只需要像之前一样点击插入题注即可。

步骤

第一步：创建一个宏

点击Word导航栏中“视图”选项卡中的“录制宏”，或者“开发工具”选项卡中的“录制宏”，这里名称随意，勾选“将宏保存在所有文档”，但是要记住这个宏的名字，因为我们要手动找到这个宏并修改其代码。

创建完成后再次在刚刚点击“录制宏”的地方选择停止录制，此时这个没有任何操作步骤的宏就保存下来了。

第二步：修改宏代码

然后，我们点击“查看宏”，可以在最后找到我们创建的这个宏，点击右侧的编辑按钮，打开宏的代码。

看到此时的代码是空的，因为我们没有录制任何操作。

然后，我们将下面这段代码（来源网络）替换现在的代码内容，然后保存并退出，此时这个宏代码就被修改了，如果这时候像之前一样查看宏，那么之前创建的宏已经更名为下图所示，这就代表代码替换成功了。

Sub InsertCaption()  '修改系统插入“题注”命令

   '功能：自动删除标签与编号间的空格（英文除外），并在题注数字后添加一个空格；适用于：Word 2003 - 2013，不兼容WPS文字！
  '真正从原理上协同系统插入题注，无任何前提条件；用户照常插入题注即可，甚至感觉不到程序的存在！
   'Endlesswx于2015年8月4日
   
  '另,如果插入的始终未域代码而不是数字，非程序问题，Alt+F9一次即可
   
   Dim Lab As String, startPt As Long, endPt As Long, myrang As Range
   'On Error Resume Next  '发生错误时让程序继续执行下一句代码
'    Application.ScreenUpdating = False     '关闭屏幕更新，2013在此处关闭更新会导致输入框灰色不可选，故修正在调出对话框之后
   
   startPt = Selection.Start  'startPt标注起始点
      
   '***将if条件隐藏隐藏即可实现----手动替换题注空格***
   If Application.Dialogs(357).Show = -1 Then '插入“题注”对话框秀出来,如果按确定结束时执行以下程序，避免按取消后的空格,357也可换成wdDialogInsertCaption
      
      Application.ScreenUpdating = False     '关闭屏幕更新
      
       Lab = Dialogs(357).label
       endPt = Selection.Start  'endPt标记插入的题注部分终点
      Selection.Start = startPt  '选定插入的整个题注
      
      '删除标签与编号间的空格（英文后的保留）
       With Selection.Find
          .Text = Lab & " "
          .Forward = True   'False=向上查找,(True=向下查找)
          .MatchWildcards = False '不使用通配符
          If Lab Like "*[0-9a-zA-Z.]" Then  '此处判断标签的最后一个字符是否为英文或数字，是则不删除空格
          Else
             .Replacement.Text = Lab
             .Execute Replace:=wdReplaceOne  '替换找到的第一个，此处用作删除空格
             endPt = endPt - 1 '删除空格后，末位减1
             Selection.End = endPt
          End If
       End With
      
      '在题注数字后添加一个空格
      Selection.Fields.ToggleShowCodes  '切换域代码，这样才能用^d查找域
       With Selection.Find
          .Text = "^d"
          .Replacement.Text = "^& "
          .Forward = False   'False=向上查找,(True=向下查找)
          .MatchWildcards = False '不使用通配符
          .Execute Replace:=wdReplaceOne  '替换找到的第一个，此处用作添加空格
       End With
      
      '选定整个插入的题注内容，将域代码切换回来
       endPt = endPt + 1 '增加空格后，末位加1
       With Selection
          .Start = startPt
          .End = endPt
          .Fields.ToggleShowCodes   '切换域代码（切换回来）
       End With
      
      '将光标定位至题注所在段尾处
'       Selection.MoveRight Unit:=wdCharacter, Count:=1  '此句光标返回插入题注前的原始位置，对于已经输好标题的情况并不合适
      '选择段尾回车符
       With Selection.Find
          .Text = "^13"
          .Forward = True   'False=向上查找,(True=向下查找)
          .MatchWildcards = False  '不使用通配符
          .Wrap = wdFindContinue '继续查找
          .Execute
       End With
      Selection.MoveLeft Unit:=wdCharacter, Count:=1  '定位到段尾回车前

   End If
   Application.ScreenUpdating = True          '恢复屏幕更新
   
End Sub

第三步：插入题注

像之前一样右击图片或者表格，选择插入题注，此时输入框如下，和之前是一样的，但是点击“确定”插入之后，就可以看到期待的效果了。

如下图所示，题注的标签和编号之前的空格被删除，标签+编号与题注内容之间有了空格。