clojure for function resetts let

Posted 2021-05-03

我试图在4clojure.com上解决一个问题，我应该在不使用count的情况下计算集合中元素的数量。我尝试了两种使用for和let的方法，我觉得应该可以工作，但似乎for循环不断重置let。

(#(for [x %  :let [y 0]] (inc y)) [1 2 3 4 5])
;; which returns
(1 1 1 1 1)

(#(let [y 0] (for [x %] (inc y))) [1 2 3 4 5])
;; which returns
(1 1 1 1 1)

所以我的问题是为什么会发生这种情况，以及如何让我的“变量”继续为集合中的每个项目增加值。只是说变量这个词让我想知道我是不是想做一些不可能的东西，但我仍觉得这应该有用。

答案

在这两种情况下，你都无法改变y的价值：

在第一种情况下，for在每个循环步骤重新引入y，这就是为什么你不能改变它的价值，即使它是可变的。

第二种情况表明该值是真正不可变的，在每一步都给你(inc y)，但y总是为零。简单的例子：

(let [x 10]
  (inc x)
  x)

;;=> 10 

通常，这种任务通常可以通过以下方法解决：

第一个是简单的递归：

(defn count-rec [data]
  (if (seq data)
    (inc (count-rec (rest data)))
    0))

user> (count-rec [1 2 3 4 5])
;;=> 5

它在某种程度上是有缺陷的，因为它不是尾递归的，并且对于大型集合会失败

第二个是clojure的loop：

(defn count-loop [data]
  (loop [res 0 data data]
    (if (seq data)
      (recur (inc res) (rest data))
      res)))

user> (count-loop [1 2 3 4 5])
;;=> 5

你也可以使用非常相似的显式尾递归：

(defn count-tailrec
  ([data] (count-tailrec 0 data))
  ([c data] (if (seq data)
              (recur (inc c) (rest data))
              c)))

user> (count-tailrec [1 2 3 4 5])
;;=> 5

第三个将使用reduce函数：

(defn count-reduce [data]
  (reduce (fn [res _] (inc res)) 0 data))

user> (count-reduce [1 2 3 4 5])
;;=> 5

只是为了好玩，你也可以使用这种方式（我不会建议它，因为与reduce相比它是一种矫枉过正）：

(defn count-map [data]
  (apply + (map (constantly 1) data)))

user> (count-map [1 2 3 4 5])
;;=> 5

你也可以使用clojure的可变原语，但它不是惯用语，只要它可以是：

(defn count-atom [data]
  (let [c (atom 0)]
    (run! (fn [_] (swap! c inc)) data)
    @c))

user> (count-atom [1 2 3 4 5])
;;=> 5

这是作弊[SPOILER ALERT！]

4clojure阻止了count函数在这个任务中的使用，但是没有阻止java的集合的.size方法，所以它可以用#(.size (seq %))来解决