如何将参数传递给批处理文件？

Posted 2021-05-03

我需要在运行时将ID和密码传递给批处理文件，而不是将它们硬编码到文件中。

这是命令行的样子：

test.cmd admin P@55w0rd > test-log.txt

答案

另一个有用的提示是使用%*来表示“全部”。例如：

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

当你运行：

test-command admin password foo bar

上面的批处理文件将运行：

fake-command /u admin /p password admin password foo bar

我的语法可能略有错误，但这是一般的想法。

另一答案

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

这将循环播放批处理参数（％*），或者引用它们，然后回显每个参数。

另一答案

我写了一个简单的read_params脚本，可以作为函数（或外部.bat）调用，并将所有变量放入当前环境。它不会修改原始参数，因为该函数正在使用原始参数的副本进行called。

例如，给定以下命令：

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat可以在调用函数后使用变量：

call :read_params %*

echo %random%
echo %greeting%

这是功能：

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

---

限制

• 无法加载没有值的参数，例如-force。您可以使用-force=true，但我想不出一种方法来允许空白值，而不知道提前列出的参数列表没有值。

---

更新日志

• 2016年2月18日 不再需要延迟扩张 现在通过在参数之前查找-来处理其他命令行参数。

另一答案

要在命令行中引用set变量，您需要使用%a%，例如：

set a=100 
echo %a%  
rem output = 100 

注意：这适用于Windows 7专业版。

另一答案

受@Jon的answer elsewhere的启发，我制作了一个更通用的算法来提取命名参数，可选值和开关。

让我们说我们想要实现一个实用程序foobar。它需要一个初始命令。它有一个可选参数--foo，它带有一个可选值（当然不能是另一个参数）;如果缺少值，则默认为default。它还有一个可选参数--bar，它取一个必需的值。最后它可以采取一个标志--baz没有允许值。哦，这些参数可以按任何顺序排列。

换句话说，它看起来像这样：

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

这是一个解决方案：

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

• 使用SETLOCAL以便变量不会进入调用环境。
• 不要忘记初始化变量SET FOO=等，以防有人在调用环境中定义它们。
• 使用%~1删除引号。
• 使用IF "%ARG%" == ""而不是IF [%ARG%] == []，因为[和]根本不会播放以空格结尾的值。
• 即使你在SHIFT区块内的IF，当前的args如%~1也不会更新，因为它们是在解析IF时确定的。你可以在%~1区块内使用%~2和IF，但它会让人感到困惑，因为你有一个SHIFT。为了清楚起见，你可以将SHIFT放在块的末尾，但这可能会丢失和/或混淆人们。因此，在街区外“捕捉”%~1和%~1似乎是最好的。
• 您不希望使用参数代替其他参数的可选值，因此您必须检查IF NOT "%ARG:~0,2%" == "--"。
• 使用其中一个参数时，请注意SHIFT。
• 重复的代码SET FOO=%DEFAULT_FOO%是令人遗憾的，但另一种方法是在IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%区块外添加一个IF NOT "%ARG%" == ""。但是因为它仍然在IF "%PARAM%" == "--foo"块内，所以%FOO%值将在您进入块之前进行评估和设置，因此您永远不会检测到--foo参数都存在以及%FOO%值缺失。
• 请注意，ECHO Missing bar value. 1>&2将错误消息发送给stderr。
• 想要Windows批处理文件中的空白行？你必须使用ECHO:或其中一个变种。

另一答案

创建一个新的批处理文件（例如：openclass.bat）并在文件中写入以下行：

java %~n1

然后将批处理文件放入，比如说system32文件夹，转到Java类文件，右键单击，属性，打开...，然后找到批处理文件，选择它，那就是......

这个对我有用。

PS：关闭Java类时，我无法找到关闭cmd窗口的方法。目前...

另一答案

简单的解决方案（即使问题很旧）

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:TempTest1.bat" pass123

产量

YourLocalPath>call "C:Temp	est.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

WhereLocalPath是当前目录路径。

为了简单起见，将命令参数存储在变量中并使用变量进行比较。

它不仅易于编写，而且易于维护，因此如果以后其他人或您在很长一段时间后阅读您的脚本，它将很容易理解和维护。

编写内联代码：请参阅其他答案。

另一答案

为了使用循环获取所有参数和纯批处理：

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

您的代码已准备好使用所需的参数号进行操作，例如......

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt

另一答案

我是这样做的：

@fake-command /u %1 /p %2

这是命令的样子：

test.cmd admin P@55w0rd > test-log.txt

%1适用于第一个参数%2（这里是棘手的部分）适用于第二个参数。您最多可以以这种方式传递9个参数。

另一答案

如果您想要智能地处理缺失的参数，您可以执行以下操作：

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

另一答案

使用％1，％2，...％9或％*访问批处理参数可以很简单， 但只有内容很简单。

对于像"&"^&这样的复杂内容没有简单的方法，因为在不产生错误的情况下无法访问％1。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

线条扩展到

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

每一行都失败了，因为其中一个&在引号之外。

它可以通过从临时文件中读取参数的标记版本来解决。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

诀窍是启用echo on并在