手眼标定eye-to-hand 示例：handeye_stationarycam_calibration

Posted 2021-01-10 yangmengke2018

世界坐标系就是标定板上的坐标系

*
* This example explains how to use the hand eye calibration for the case where
* the camera is stationary with respect to the robot and the calibration
* object is attached to the robot arm.
*这个示例展示了如何使用手眼标定，这种情形用于相机与机械手基础坐标系位置固定且标定板固定在相机的末端轴上。
* In this case, the goal of the hand eye calibration
* is to determine two unknown poses:
*在这种情况下，手眼标定目标是确定一下两个位置姿态。
* - the pose of the robot base in the coordinate system
* of the camera (BaseInCamPose).
*基于相机坐标系的机械手基础坐标系姿态
* - the pose of the calibration object in the coordinate system of the
* tool (CalObjInToolPose)
*基于相机末端（工具）坐标系的标定板姿态
* Theoretically, as input the method needs at least 3 poses of the
* calibration object in the camera coordinate system and the corresponding
* poses of the robot tool in the coordinate system of the
* robot base. However it is recommended
* to use at least 10 Poses.
* The poses of the calibration object are obtained from images of the
* calibration object recorded with the stationary camera.
* The calibration object is moved by the robot with respect to the camera.
* To obtain good calibration results, it its essential to position
* the calibration object with respect to the camera so that the object appears
* tilted in the image.
* After the hand eye calibration, the computed transformations are
* extracted and used to compute the pose of the calibration object in the
* camera coordinate system.
dev_update_off ()
* Directories with calibration images and data files
ImageNameStart := ‘3d_machine_vision/handeye/stationarycam_calib3cm_‘
DataNameStart := ‘handeye/stationarycam_‘
NumImages := 17
* Read image
read_image (Image, ImageNameStart + ‘00‘)
get_image_size (Image, Width, Height)
* Open window
dev_close_window ()
dev_open_window (0, 0, Width, Height, ‘black‘, WindowHandle)
dev_set_line_width (2)
dev_set_draw (‘margin‘)
dev_display (Image)
* Set font
set_display_font (WindowHandle, 14, ‘mono‘, ‘true‘, ‘false‘)
* Load the calibration plate description file.
* Make sure that the file is in the current directory,
* the HALCONROOT/calib directory, or use an absolut path
CalTabFile := ‘caltab_30mm.descr‘
* Read the initial values for the internal camera parameters
read_cam_par (DataNameStart + ‘start_campar.dat‘, StartCamParam)
* Create the calibration model for the hand eye calibration
create_calib_data (‘hand_eye_stationary_cam‘, 1, 1, CalibDataID)
set_calib_data_cam_param (CalibDataID, 0, ‘area_scan_division‘, StartCamParam)
set_calib_data_calib_object (CalibDataID, 0, CalTabFile)
set_calib_data (CalibDataID, ‘model‘, ‘general‘, ‘optimization_method‘, ‘nonlinear‘)
disp_message (WindowHandle, ‘The calibration data model was created‘, ‘window‘, 12, 12, ‘black‘, ‘true‘)
disp_continue_message (WindowHandle, ‘black‘, ‘true‘)
stop ()
* Start the loop over the calibration images
for I := 0 to NumImages - 1 by 1
read_image (Image, ImageNameStart + I$‘02d‘)
* Search for the calibration plate, extract the marks and the
* pose of it, and store the results in the calibration data model of the
* hand-eye calibration
find_calib_object (Image, CalibDataID, 0, 0, I, [], [])
get_calib_data_observ_contours (Caltab, CalibDataID, ‘caltab‘, 0, 0, I)
get_calib_data_observ_points (CalibDataID, 0, 0, I, RCoord, CCoord, Index, CalObjInCamPose)
* Visualize the extracted calibration marks and the estimated pose (coordinate system)
dev_set_color (‘green‘)
dev_display (Image)
dev_display (Caltab)
dev_set_color (‘yellow‘)
disp_cross (WindowHandle, RCoord, CCoord, 6, 0)
dev_set_colored (3)
disp_3d_coord_system (WindowHandle, StartCamParam, CalObjInCamPose, 0.01)
* Read pose of tool in robot base coordinates (ToolInBasePose)
read_pose (DataNameStart + ‘robot_pose_‘ + I$‘02d‘ + ‘.dat‘, ToolInBasePose)
* Set the pose tool in robot base coordinates in the calibration data model
set_calib_data (CalibDataID, ‘tool‘, I, ‘tool_in_base_pose‘, ToolInBasePose)
* Uncomment to inspect visualization
* disp_message (WindowHandle, ‘Extracting data from calibration image ‘ + (I + 1) + ‘ of ‘ + NumImages, ‘window‘, -1, -1, ‘black‘, ‘true‘)
* disp_continue_message (WindowHandle, ‘black‘, ‘true‘)
* stop ()
endfor
disp_message (WindowHandle, ‘All relevant data has been set in the calibration data model‘, ‘window‘, 12, 12, ‘black‘, ‘true‘)
disp_continue_message (WindowHandle, ‘black‘, ‘true‘)
stop ()
* Perform hand-eye calibration
* Internally before performing the hand-eye calibration the cameras are calibrated
* and the calibrated poses of the calibration object in the camera are used.
dev_display (Image)
disp_message (WindowHandle, ‘Performing the hand-eye calibration‘, ‘window‘, 12, 12, ‘black‘, ‘true‘)
calibrate_hand_eye (CalibDataID, Errors)
* Query the camera parameters and the poses
get_calib_data (CalibDataID, ‘camera‘, 0, ‘params‘, CamParam)
* Get poses computed by the hand eye calibration
get_calib_data (CalibDataID, ‘camera‘, 0, ‘base_in_cam_pose‘, BaseInCamPose)
get_calib_data (CalibDataID, ‘calib_obj‘, 0, ‘obj_in_tool_pose‘, ObjInToolPose)
dev_get_preferences (‘suppress_handled_exceptions_dlg‘, PreferenceValue)
dev_set_preferences (‘suppress_handled_exceptions_dlg‘, ‘true‘)
try
* Store the camera parameters to file
write_cam_par (CamParam, DataNameStart + ‘final_campar.dat‘)
* Save the hand eye calibration results to file
write_pose (BaseInCamPose, DataNameStart + ‘final_pose_cam_base.dat‘)
write_pose (ObjInToolPose, DataNameStart + ‘final_pose_tool_calplate.dat‘)
catch (Exception)
* Do nothing
endtry
dev_set_preferences (‘suppress_handled_exceptions_dlg‘, PreferenceValue)
* Display calibration errors of the hand-eye calibration
Message := ‘Quality of the results: root mean square maximum‘
Message[1] := ‘Translation part in meter: ‘ + Errors[0]$‘6.4f‘ + ‘ ‘ + Errors[2]$‘6.4f‘
Message[2] := ‘Rotation part in degree: ‘ + Errors[1]$‘6.4f‘ + ‘ ‘ + Errors[3]$‘6.4f‘
disp_message (WindowHandle, Message, ‘window‘, 12, 12, ‘black‘, ‘true‘)
disp_continue_message (WindowHandle, ‘black‘, ‘true‘)
stop ()
* For the given camera, get the corresponding pose indices and calibration object indices
query_calib_data_observ_indices (CalibDataID, ‘camera‘, 0, CalibObjIdx, PoseIds)
* Compute the pose of the calibration object in the camera coordinate
* system via calibrated poses and the ToolInBasePose and visualize it.
for I := 0 to NumImages - 1 by 1
read_image (Image, ImageNameStart + I$‘02d‘)
* Obtain the pose of the tool in robot base coordinates used in the calibration.
* The index corresponds to the index of the pose of the observation object.
get_calib_data (CalibDataID, ‘tool‘, PoseIds[I], ‘tool_in_base_pose‘, ToolInBasePose)
dev_display (Image)
* Compute the pose of the calibration plate with respect to the camera
* and visualize it
calc_calplate_pose_stationarycam (ObjInToolPose, BaseInCamPose, ToolInBasePose, CalObjInCamPose)
dev_set_colored (3)
disp_3d_coord_system (WindowHandle, CamParam, CalObjInCamPose, 0.01)
Message := ‘Using the calibration results to display the‘
Message[1] := ‘coordinate system in image ‘ + (I + 1) + ‘ of ‘ + NumImages
disp_message (WindowHandle, Message, ‘window‘, 12, 12, ‘black‘, ‘true‘)
if (I < NumImages - 1)
disp_continue_message (WindowHandle, ‘black‘, ‘true‘)
stop ()
endif
endfor
* Clear the data model
clear_calib_data (CalibDataID)
*
* After the hand-eye calibration the computed pose
* BaseInCamPose can be used in robotic grasping applications.
* If the tool coordinate system is placed at the gripper
* and a object detected at ObjInCamPose shall be grasped,
* the pose of the detected object relative
* to the robot base coordinate system has to be computed.
pose_invert (BaseInCamPose, CamInBasePose)
pose_compose (CamInBasePose, CalObjInCamPose, ObjInBasePose)