倍增思想

Posted 2021-01-05 by-w

对于求解区间最大最小值，我们有着多种手段——线段树，分块，各种平衡树（反正我一种都不会），单调队列

以上数据结构均为在线数据结构，当询问次数很大时，基本就没有办法了

那么接下来要介绍的便是一种思想——倍增

它可以做到在O(1)的时间内查询最大最小值，但是它的预处理是稳定的O(Nlgn）（静态）

这是一种神奇的思想，我认为区间倍增和树上倍增都类似与动态规划

那么倍增究竟是什么呢？

我们用f[i,j]表示从i开始的向后2^j的这段区间内的最值（二进制相关）

那f[i,j]这段的最值一定是从长度更小的两段转移过来的

即 f[i,j]:=opt(f[i,j-1],f[i+(1<<j)-(1<<(j-1))][j-1]);（由于最大最小值没有叠加性，所以区间重叠也是没有关系的）

那么下面就是区间倍增代码啦

var
n,m,i,j,ans,k,l,r:longint;
ss,a:array[0..1000000] of longint;
f:array[0..200000,0..100] of longint;
function max(a,b:longint):longint;
begin
  if a>b then exit(a)
  else exit(b);
end;
//预处理lg函数
procedure gg;
var i:longint;
begin
  ss[1]:=0;
  for i:=2 to n do
  if (1<<(ss[i-1]+1)=i) then ss[i]:=ss[i-1]+1
  else ss[i]:=ss[i-1];
end;
begin
  readln(n,m);
  gg;
  for i:=1 to n do 
  begin
    read(a[i]);
    f[i,0]:=a[i];
  end;
//预处理出f数组
  for j:=1 to ss[n] do
  begin
    for i:=1 to n-(1<<j)+1 do
      //这里最容易错，也是倍增的关键
      f[i,j]:=max(f[i,j-1],f[i+(1<<j)-(1<<(j-1))][j-1]); 
  end;
//处理询问
  for i:=1 to m do
  begin
    readln(l,r);
    k:=ss[r-l+1];
    ans:=max(f[l,k],f[r-(1<<k)+1,k]);
    writeln(ans);
  end;
end.