VB中怎样单击按钮出现一个图片

Posted 2023-04-08

command按钮中应该输入什么代码？

用vb编写一个点击按钮随机出现一张图片的软件，例如：窗体上一个picture1和command1的控件。

1、有四张图片，他们的后缀名不相同，用户可以问这样写：

Dim a$(3)

Private Sub Form_Load()

Randomize

a(0) = "D:\\xuexi.gif"

a(1) = "D:\\002.jpg"

a(2) = "D:\\房子.png"

a(3) = "D:\\4.jpg"

End Sub

Private Sub Command1_Click()

Picture1.Picture = LoadPicture(a(Int(Rnd * 3)))

End Sub

2、如果后缀名相同，且图片名称按顺序编号内并在程序目录下，用户可以容这样写：

Private Sub Command1_Click()

Picture1.Picture = LoadPicture(App.Path & "\\" & Int(Rnd * 3) & ".jpg")

End Sub

扩展资料：

CommandButton命令按钮最常用的事件是鼠标点击（Click）事件，当点击按钮时，犹如发出了一道命令，而这也正是“命令按钮”这个说法的由来。

CommandButton 的主要属性列举：

1、Cancel（取消）属性：

当一个按钮的 Cancel 属性设置为 True 时，按 ESC 键与单击此命令按钮的作用相同，因此，这个命令按钮被称为取消按钮。在一个窗体中，只允许一个命令按钮的 Cancel 属性为 True 。

2、Default（默认）属性：

当一个按钮的 Default 属性设置为 True 时，按回车键与单击此命令按钮的作用相同，因此，这个命令按钮被称为默认按钮。 与 Cancel 的设置一样，在一个窗体中，只允许一个命令按钮的 Default 属性设置为 True 。

3、Caption（标题）属性：

跟其他控件的 Caption 属性一样，都用来显示控件标题的属性。这里要强调的是，作为按钮控件，用户可以给按钮控件的 Caption 指定快捷方式。

参考资料来源：百度百科-命令按钮

参考技术A 好的程序来了,自己写的,已经验证OK!!!

Private Sub Command1_Click()
Picture1.Picture = LoadPicture("C:\123.jpg")
End Sub

你在窗体上添加一个Picture控件,一个Command按钮,然后把上面的代码复制进去,运行看结果吧!!!

注意:你首先要把123.jpg这个图片放到C盘下!!!本回答被提问者采纳 参考技术B 本人提供另一种方法
首先在窗体上添加command1按纽和图片框，在图片框的属性中，picture中添加你要加的图片，
其visible为false
。在命令按纽的click事件中介入如下代码
Picture1.visible=true
这样就好了
应该异曲同工吧#

VB里如何改变命令按钮中文字的颜色？

如题

不能直接通过属性框修改按钮中文本的颜色
根本没有foreColor属性
下边是一个参考方法
首先请把要改的按钮的Style设置为1

在工程中添加以下模块(Module):
Module modExtButton.bas

Option Explicit

'==================================================================
' modExtButton.bas
'
' 本模块可让你改变命令按钮的文本颜色。
' 使用方法:
'
' - 在设计时将文本的Style设为Graphical.
'
' - 随意设定背景色和图象属性.
'
' - 在Form_Load中调用 SetButton :
' SetButton Command1.hWnd, vbBlue
' (你可以任意次的调用该过程甚至不必先调用 RemoveButton.)
'
' - 在Form_Unload中调用 RemoveButton :
' RemoveButton Command1.hWnd
'
'==================================================================

Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Private Declare Function GetParent Lib "user32" _
(ByVal hWnd As Long) As Long

Private Declare Function GetWindowLong Lib "user32" Alias _
"GetWindowLongA" (ByVal hWnd As Long, _
ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias _
"SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long
Private Const GWL_WNDPROC = (-4)

Private Declare Function GetProp Lib "user32" Alias "GetPropA" _
(ByVal hWnd As Long, ByVal lpString As String) As Long
Private Declare Function SetProp Lib "user32" Alias "SetPropA" _
(ByVal hWnd As Long, ByVal lpString As String, _
ByVal hData As Long) As Long
Private Declare Function RemoveProp Lib "user32" Alias _
"RemovePropA" (ByVal hWnd As Long, _
ByVal lpString As String) As Long

Private Declare Function CallWindowProc Lib "user32" Alias _
"CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, _
ByVal lParam As Long) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, Source As Any, ByVal Length As Long)

'Owner draw constants
Private Const ODT_BUTTON = 4
Private Const ODS_SELECTED = &H1
'Window messages we're using
Private Const WM_DESTROY = &H2
Private Const WM_DRAWITEM = &H2B

Private Type DRAWITEMSTRUCT
CtlType As Long
CtlID As Long
itemID As Long
itemAction As Long
itemState As Long
hwndItem As Long
hDC As Long
rcItem As RECT
itemData As Long
End Type

Private Declare Function GetWindowText Lib "user32" Alias _
"GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, _
ByVal cch As Long) As Long
'Various GDI painting-related functions
Private Declare Function DrawText Lib "user32" Alias "DrawTextA" _
(ByVal hDC As Long, ByVal lpStr As String, ByVal nCount As Long, _
lpRect As RECT, ByVal wFormat As Long) As Long
Private Declare Function SetTextColor Lib "gdi32" (ByVal hDC As Long, _
ByVal crColor As Long) As Long
Private Declare Function SetBkMode Lib "gdi32" (ByVal hDC As Long, _
ByVal nBkMode As Long) As Long
Private Const TRANSPARENT = 1

Private Const DT_CENTER = &H1
Public Enum TextVAligns
DT_VCENTER = &H4
DT_BOTTOM = &H8
End Enum
Private Const DT_SINGLELINE = &H20

Private Sub DrawButton(ByVal hWnd As Long, ByVal hDC As Long, _
rct As RECT, ByVal nState As Long)

Dim s As String
Dim va As TextVAligns

va = GetProp(hWnd, "VBTVAlign")

'Prepare DC for drawing
SetBkMode hDC, TRANSPARENT
SetTextColor hDC, GetProp(hWnd, "VBTForeColor")

'Prepare a text buffer
s = String$(255, 0)
'What should we print on the button?
GetWindowText hWnd, s, 255
'Trim off nulls
s = Left$(s, InStr(s, Chr$(0)) - 1)

If va = DT_BOTTOM Then
'Adjust specially for VB's CommandButton control
rct.Bottom = rct.Bottom - 4
End If

If (nState And ODS_SELECTED) = ODS_SELECTED Then
'Button is in down state - offset
'the text
rct.Left = rct.Left + 1
rct.Right = rct.Right + 1
rct.Bottom = rct.Bottom + 1
rct.Top = rct.Top + 1
End If

DrawText hDC, s, Len(s), rct, DT_CENTER Or DT_SINGLELINE _
Or va

End Sub

Public Function ExtButtonProc(ByVal hWnd As Long, _
ByVal wMsg As Long, ByVal wParam As Long, _
ByVal lParam As Long) As Long

Dim lOldProc As Long
Dim di As DRAWITEMSTRUCT

lOldProc = GetProp(hWnd, "ExtBtnProc")

ExtButtonProc = CallWindowProc(lOldProc, hWnd, wMsg, wParam, lParam)

If wMsg = WM_DRAWITEM Then
CopyMemory di, ByVal lParam, Len(di)
If di.CtlType = ODT_BUTTON Then
If GetProp(di.hwndItem, "VBTCustom") = 1 Then
DrawButton di.hwndItem, di.hDC, di.rcItem, _
di.itemState

End If

End If

ElseIf wMsg = WM_DESTROY Then
ExtButtonUnSubclass hWnd

End If

End Function

Public Sub ExtButtonSubclass(hWndForm As Long)

Dim l As Long

l = GetProp(hWndForm, "ExtBtnProc")
If l <> 0 Then
'Already subclassed
Exit Sub
End If

SetProp hWndForm, "ExtBtnProc", _
GetWindowLong(hWndForm, GWL_WNDPROC)
SetWindowLong hWndForm, GWL_WNDPROC, AddressOf ExtButtonProc

End Sub

Public Sub ExtButtonUnSubclass(hWndForm As Long)

Dim l As Long

l = GetProp(hWndForm, "ExtBtnProc")
If l = 0 Then
'Isn't subclassed
Exit Sub
End If

SetWindowLong hWndForm, GWL_WNDPROC, l
RemoveProp hWndForm, "ExtBtnProc"

End Sub

Public Sub SetButton(ByVal hWnd As Long, _
ByVal lForeColor As Long, _
Optional ByVal VAlign As TextVAligns = DT_VCENTER)

Dim hWndParent As Long

hWndParent = GetParent(hWnd)
If GetProp(hWndParent, "ExtBtnProc") = 0 Then
ExtButtonSubclass hWndParent
End If

SetProp hWnd, "VBTCustom", 1
SetProp hWnd, "VBTForeColor", lForeColor
SetProp hWnd, "VBTVAlign", VAlign

End Sub

Public Sub RemoveButton(ByVal hWnd As Long)

RemoveProp hWnd, "VBTCustom"
RemoveProp hWnd, "VBTForeColor"
RemoveProp hWnd, "VBTVAlign"

End Sub

然后回到FORM中：
添加CommandButton，不必更改它们的名称，将它们的Style设为Graphical，给第3个按钮设置一幅图片。
CommandButton也可以放置在一个容器如PictureBox或Frame中，模块会判断，如果需要的话将CommandButton的容器也子类化。

在Form中的代码：
Private Sub Form_Load()

'Initialize each button color.
SetButton Command1.hWnd, vbRed
SetButton Command2.hWnd, &H8000& '深绿色
'Assign this one a DT_BOTTOM alignment because
SetButton Command3.hWnd, vbBlue, DT_BOTTOM '含有图片，将文本放置在按钮底部
SetButton Command4.hWnd, &H8080& '暗棕黄色

End Sub

Private Sub Form_Unload(Cancel As Integer)

'手动解除按钮的子类化
'这并不是必须的
RemoveButton Command1.hWnd
RemoveButton Command2.hWnd
RemoveButton Command3.hWnd
RemoveButton Command4.hWnd

End Sub

For m = 0 To 9
SetButton CmdNum(m).hWnd, vbBlue
Next
For n = 1 To 4
SetButton CmdCal(n).hWnd, vbRed
Next
For l = 2 To 4
SetButton CmdOth(l).hWnd, vbRed
Next

参考资料：www.csdn.net

参考技术A 如果你确实不懂他们说的,教你一招最笨的方法在按钮上面画一个label控件,
设置背景透明
,然后将按钮的文字去掉,在这个label的caption属性里面输入
它的文字
,并设置字体颜色等,然后写单击事件的时候
就写这个label的单击事件
, 参考技术B 点击按钮,右边属性,按分区,最后一项FOUT,设置. 参考技术C 按钮 ... 属性 ... 找 ForeColor ...

修改就可以 ... 参考技术D 只能改变“字体” “大小” “效果” 上面的只能是黑色的，可能要调用API吧
在强的自己些个按钮的类。