powerdesignnavacatER图uml类图时序图

Posted 2021-01-05 老人与JAVA

关于建表和生成实体以及ER图的简便方法

a：用navacat客户端生成简单的ER图，并生成建表sql,执行生成表。

b：用powerdesign连接数据库，反向生成带有注释的ER图。

c：用ideal的Database插件，连接数据库，生成pojo类（带注释）。

d : 用ideal的PlantUML integration 插件创建UML图，时序图，java类图（鼠标先点到一个包目录下，右击new才能创建uml图）

         安装完插件之后，还需要安装支持绘图的软件Graphviz （具体操作参考：https://www.jianshu.com/p/b559dc689b7f?utm_source=oschina-app）

 

相关软件安装包见（https://pan.baidu.com/s/14L37Ai3yVM2ak47VqM3gMA）

1 关于powerdesign的版本（16.5）

powerdesign有view版本，不能创建模型（按钮均为灰色显示），安装的时候注意。安装正式版本，一路next即可。

所有的安装需要的资源地址:

 

2 powerdesign创建物理模型

file ----> new model ---> model types ---> physical data model --->physical diagram --->ok

 

创建模型之后可以创建ER图

 

2 如何将ER图导出为sql

crl +  A 全选中所有的ER图，Database ---> Generate Database----

 

3 powerdesign 连接数据库

DataBase(必须要创建了模型才出现此工具栏) ------>Configure Connections ---> Connection Profiles --->添加数据库连接

 

此处点击Test Connection 测试的时候请注意：

a：只能执行32位系统下的JDK指令。所以需要安装32位的JDK(安装包在压缩文件内)，将环境变量JAVA_HOME指向32的JDK地址。否则会报错：PowerDesigner Could not Initialize JavaVM! 

b：连接的url最好加上?serverTimezone=GMT%2B8否则可能报错： The server time zone value \'Öйú±ê׼ʱ¼ä\' is unrecognized or represents more than one time zone

 

4 利用powerdesign将数据库导的表导入为ER图，并带上注释

选择数据源：

输入密码

选择要生成的表，ok,但是此时一般不会读取注释，想显示字段的注释，请如下操作。

在powerdesign中菜单 Tools——>Display Preference...——>Table——>Advanced...

 

接下来，我们执行脚本，在桌面建立文件powerdesign-name-comment.vbs ，文件名称可随便写，但是必须是vbs文件，名称最好用英文，该文件内容为（详细见压缩包）：

\'******************************************************************************
\'* File:     comment2code.vbs
\'* Purpose: 在PowerDesigner的PDM图形窗口中显示数据列的中文注释
\'* Title:    将字段的comment赋值到字段的code中
\'* Category: 打开物理模型，运行本脚本（Ctrl+Shift+X）
\'* Copyright:[e-mail],2006/07/25 .
\'* Author:   foxzz
\'* Created:
\'* Modified:
\'* Version: 1.0
\'* Comment: 遍历物理模型中的所有表，将字段的comment赋值到字段的code中。
\'            在将code置换为comment过程中，需要考虑的问题
\'            1、code必须唯一，而comment有可能不唯一。
\'               处理办法是如果字段的comment重复，则字段的code=comment+1、2、3...
\'            2、comment值有可能为空，这种情况下对字段的code不处理。
\'               针对oracle数据库,将comment on column 字段名称 is \'\';添加到C:\\pdcomment.txt文件中。
\'               在补充comment完毕后，便于在数据库中执行      
\'******************************************************************************


Option Explicit
ValidationMode = True
InteractiveMode = im_Batch


Dim system, file
Set system = CreateObject("Scripting.FileSystemObject")
Dim ForReading, ForWriting, ForAppending   \'打开文件选项
ForReading   = 1 \' 只读
ForWriting   = 2 \' 可写
ForAppending = 8 \' 可写并追加
\'打开文本文件
Set file = system.OpenTextFile("C:\\pdcomment.txt", ForWriting, true)




\'判断当前model是否物理数据模型
Dim mdl
Set mdl = ActiveModel
If (mdl Is Nothing) Then
   MsgBox "处理对象无模型"
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
   MsgBox "当前模型不是物理数据模型"
Else
   ProcessFolder mdl,file
End If
file.Close




\'******************************************************************************
Private sub ProcessFolder(folder,file)


Dim i,j,k
i=0:j=0:k=0


\'列数组，记录字段里不重复的comment
Dim ColumnComment()
Dim ColumnCommentNumber()
ReDim Preserve ColumnComment(i)
ReDim Preserve ColumnCommentNumber(i)


Dim tbl   \'当前表
Dim col   \'当前字段
dim curComment \'当前字段comment


\'处理模型中的表
for each tbl in folder.tables
    if not tbl.isShortcut then
       if len(trim(tbl.comment))<>0 then
          \'可以在这里显示table的comment
          \'tbl.code = tbl.code+"("+trim(tbl.comment)+")"
       end if 


       \'处理表中的列
       for each col in tbl.columns
           k = 0
           curComment = trim(col.comment)
           if len(curComment)<>0 then
              \'遍历相异的comment数组
              for j = 0 to i
                  if ColumnComment(j) = curComment then
                     \'如果找到相同的comment,则相关计数器加1
                     ColumnCommentNumber(j) = ColumnCommentNumber(j) + 1
                     k = j
                  end if
              Next
              \'如果没有相同的comment,则k=0,此时ColumnCommentNumber(0)也为0
              \'否则ColumnCommentNumber(k)不为0
              if ColumnCommentNumber(k) <> 0 then
                 col.name = curComment & cstr(ColumnCommentNumber(k))
              else
                 col.name = curComment
                 \'ColumnComment(0)、ColumnCommentNumber(0)永远为空
                 \'将相异的comment记录添加到数组中
                 i = i + 1
                 ReDim Preserve ColumnComment(i)
                 ReDim Preserve ColumnCommentNumber(i)
                 ColumnComment(i) = curComment
                 ColumnCommentNumber(i) = 0
              end if
           else
              \'写入文件中
              file.WriteLine "comment on column "+ tbl.code+"."+col.name+" is \'\';"         
           end if
       next
    end if
    \'由于不同表的code允许相同,因此此时重新初始化。
    \'因为ColumnComment(0)、ColumnCommentNumber(0)为空，可以保留
    ReDim Preserve ColumnComment(0)
    ReDim Preserve ColumnCommentNumber(0)
    i=0:j=0:k=0


next


Dim view \'当前视图
for each view in folder.Views
    if not view.isShortcut then
       \'可以在这里显示view的comment
       \'view.code = view.comment
    end if
next


\'对子目录进行递归
Dim subpackage \'folder
For Each subpackage In folder.Packages
    if not subpackage.IsShortcut then
       ProcessFolder subpackage , file
    end if
Next


end sub

\'******************************************************************************

在脚本指定的目录创建pdcomment.txt空文件即可。

 

在powerdesign中菜单Tools——>Excute Commands——>Edit/Run Script...  选择上一步创建的文件，点击执行，然后注释会显示出来。